Why set 34 in OCR1C

[janbobis]

Couple of questions/clarifications from me.

• You used 16Mhz resonator as your clock source, CS1[3:0] = 0001 meaning clock selection is PCK (no division whatsoever). The question then is why set 34 in OCR1C if this generates 470.58Khz carrier signal? Why not use 35 instead as this is more closer with 457.14Khz?

Also, in your code, you have the following:

// It'd be best for you to read the datasheet carefully. And then read it again.

TCCR1 &= 0; // Is this register not zeroed by default? TCCR1 |= (1<<CTC1) | (1<<PWM1A) | (1<<CS10) | (1<<COM1A1); // set registers

OCR1A = 18; // Results in 455KHz w/ 51% duty cycle. good enough. OCR1C = 34; // however, glitches occur every 128us, or 2048 cycles. IDK why this occurs.

• What's the reason for setting OCR1A to 18? Can you please elaborate or at least give us a hint? From what i understood, PWM1A being set (one) enables PWM mode based on comparator OCR1A and the counter is reset back after a compare match with OCR1C with value 34, thus 16Mhz/34 = ~470Khz.
• You also have this line in your code:

pinMode(1, OUTPUT); // Set output pin for OCR2B

Not sure about OCR2B, but do you mean OC1A for PB1 instead?

[janbobis]

By the way, instead of logically ANDing the carrier frequency and the data through hardware (using MOSFETs), you can implement this through software using Fast PWM with Pin 4 of the MCU. You can see from the fork of the IRremote which was done by SeeJayDee (see link below), the carrier signal was at about 36-40Khz but may be set to 455Khz with a little prescaler and output comparator modification. Data to transmission is the same as how it was implemented except that headers, marks, and space needs to be modified. I'll try to do an implementation using yours and his approach and will get back to you once done.

https://gist.github.com/SeeJayDee/caa9b5cc29246df44e45b8e7d1b1cdc5

[EdwardDimaguila]

Nice to see you here Jan Bobis. Please share your changes here!

[janbobis]

Nice to see you here to Sir Edward.

[Aether4E0A]

Nice observations Janbobis. This implementation with the ATTiny85 has many possible improvements. I placed it on github for others to use or improve on, even though I am going no further with developing this board.

• FastPWM uses the specified value (34) plus one cycle. This means that, in order to have the 457KHz, we need to specify 35-1 = 34.
• For the value of 18, it is close to being half of 35. This is done to produce a signal roughly 50% in duty cycle. To the best of my knowledge, fastPWM was the only way to produce a high frequency this close to 455KHz. The other oscillators did not have the ability to use the clock source without division. A quirk of using fastPWM is that we need to treat it as PWM, specifying a duty cycle. Ideally, this would be exactly 50%.
• I think I commented incorrectly about OCR2B. I think that should be OC1A. I'll look closer later and make sure. This comment may be an artifact from experimenting with the other oscillators.
• This design can certainly be optimized. Using bits to turn fastPWM on and off according to the UART signal would be ideal. I have a single MOSFET design made for another implementation, but with a non-Atmel microcontroller.

I have spare boards if you would like to have a few. Message me at aetheraristotle@gmail.com if interested.

Another improvement could be the usage of a 14.xxx MHz resontator; the timings may more cleanly align than with 16MHz.

[janbobis]

Just wanted to share my iLaps transponder code here. The code below makes use of ATTiny85's internal 8MHz clock. No prescaler has been selected and divide counter was set to 17 resulting to ~470KHz Fast PWM output to PIN4 (by enabling PWM1B in GTCCR). Toggling was done using a 26uS delay causing a 38KHz data mixing with the carrier signal (enabling and disabling the Fast PWM)

#include <avr/io.h>
#include <avr/interrupt.h>

#define MARK 16     // This was supposed to be 26 but due to inaccuracy and some delays using 
                    // internal clock, the value was adjusted to achieve desired output
#define SPACE 26

void setup() {
  pinMode(4, OUTPUT);
  digitalWrite(4, HIGH);
  TCCR1 = _BV(CTC1) | _BV(CS10);
  GTCCR = _BV(PWM1B);
  OCR1C = 17;
  OCR1B = 7;  // 41% duty cycle

}

void loop() {
  // send code 1234567 (equivalent to 0E AD DC BA 98)
  sendByte(0x0E);
  sendByte(0xAD);
  sendByte(0xDC);
  sendByte(0xBA);
  sendByte(0x98);
  sendByte(0xD6);
  delay(5);
}

void sendByte(unsigned long data){
  for (int i = 0; i<8; i++){
    if (i==0) space(SPACE);

    if (data & 1) {
      mark(MARK);
    } else {
      space(SPACE);
    }

    if(i==7) mark(MARK);
    data>>=1;
  }
}

void mark(int time){
  GTCCR &= ~(_BV(COM1B1));
  digitalWrite(4, HIGH);
  delayMicroseconds(time);

}

void space(int time){
  GTCCR |= _BV(COM1B1);
  delayMicroseconds(time-2);  
}

[Aether4E0A]

Nice job!

I've decided to make a version 2 of this transponder. I've uploaded some of the work here: https://github.com/Aether4E0A/IR-Transponder-ATTiny85-v2

[janbobis]

Your code looks nice and simplified! Will test this out in my simulator later to see the output and compare this with your previous work. I will post my findings on the v2 github page