Modular Power Suits recipe pass

[Almagnus1]

Modular Powersuits needs recipe clean up, as there are far too many optional recipes.

Modular Powersuits should also use more aluminum, as the resource needs something that can be done with it endgame.

[Almagnus1]

This is underway, unfortunately all of the recipes for the mod have to be reworked to get this completed.

On the upside, the mod will be better integrated with ProjectRed, EnderIO, and Thermal Expansion once the work is done.

Still trying to work out how to smartly include aluminum, alumite, ardite, cobalt, and manyullyn into the final recipes, so there's something else to do with the tinker's metals beyond the Tinker's mods. While the wings getting rolled over to aluminum is an obvious one, I'm on the fence about using aluminum ingots with the armor recipes, as the initial armors are changing to be an upgrade of invar armor (as that seemed like a logical progression).

For reference, here's the script now:

// Reworks the recipes for Modula Power Suits to condense the recipes down to one for each item

val powerArmorTinkerTable = <powersuits:tile.tinkerTable>;
val wiring = <powersuits:powerArmorComponent>;
val powerArmorHelmet = <powersuits:item.powerArmorHelmet>;
val powerArmorChestplate = <powersuits:item.powerArmorChestplate>;
val powerArmorLeggings = <powersuits:item.powerArmorLeggings>;
val powerArmorBoots = <powersuits:item.powerArmorBoots>;
val powerGlove = <powersuits:item.powerFist>;

val limeIllumar = <ProjRed|Core:projectred.core.part:24>;
val emerald = <ore:gemEmerald>;
val TEhardenedMachineFamre = <ThermalExpansion:Frame:1>;
val darkSteelIngot = <ore:ingotDarkSteel>;
val copperCoil = <ProjRed|Core:projectred.core.part:16>;
val rubberBar = <ore:itemRubber>;
val invarIngot = <ore:ingotInvar>;
val invarHelmet = <ThermalFoundation:armor.helmetInvar>;
val hardenedGlass = <ore:blockGlassHardened>;
val invarChestplate = <ThermalFoundation:armor.plateInvar>;
val invarLeggings = <ThermalFoundation:armor.legsInvar>;
val invarBoots = <ThermalFoundation:armor.bootsInvar>;
val RSreceptCoil = <ThermalExpansion:material:3>;
val pulsatingIronIngot = <ore:ingotPhasedIron>;

//////////////////////// Blocks /////////////////////////////////////

// Power Armor Tinker Table
recipes.remove(powerArmorTinkerTable);
recipes.addShaped(
    powerArmorTinkerTable,
    [
        [limeIllumar,       emerald,                limeIllumar],
        [darkSteelIngot,    TEhardenedMachineFamre, darkSteelIngot],
        [null,              darkSteelIngot,         null]
    ]);

//////////////////////// Components /////////////////////////////////////
// wiring
recipes.remove(wiring);
recipes.addShaped(
    wiring * 8,
    [
        [rubberBar,     rubberBar,  rubberBar],
        [copperCoil,    copperCoil, copperCoil],
        [rubberBar,     rubberBar,  rubberBar]
    ]);
recipes.addShaped(
    wiring * 8,
    [
        [rubberBar, copperCoil, rubberBar],
        [rubberBar, copperCoil, rubberBar],
        [rubberBar, copperCoil, rubberBar]
    ]);

/*
Known remaining components
solenoid
Control circuit
servo motor
computer chip
lv capacitor
force field emitter
hv capacitor
mv capacitor
basic plating
advanced plating
artificial muscle
parachute
glider wing
ion thruster
hologram emitter
magnet
liquid nitrogen bucket
insulated rubber hose
*/

//////////////////////// Armor /////////////////////////////////////
// Helmet
recipes.remove(powerArmorHelmet);
recipes.addShaped(
    powerArmorHelmet,
    [
        [invarIngot,    invarHelmet,    invarIngot],
        [wiring,        hardenedGlass,  wiring]
    ]);

// Chestplate
recipes.remove(powerArmorChestplate);
recipes.addShaped(
    powerArmorChestplate,
    [
        [invarIngot,    null,               invarIngot],
        [wiring,        invarChestplate,    wiring],
        [invarIngot,    invarIngot,         invarIngot]
    ]);

// Leggings
recipes.remove(powerArmorLeggings);
recipes.addShaped(
    powerArmorLeggings,
    [
        [invarIngot,    invarLeggings,  invarIngot],
        [wiring,        null,           wiring],
        [invarIngot,    null,           invarIngot]
    ]);

// Boots
recipes.remove(powerArmorBoots);
recipes.addShaped(
    powerArmorBoots,
    [
        [wiring,        null,       wiring],
        [invarIngot,    invarBoots, invarIngot]
    ]);

// Power Glove
recipes.remove(powerGlove);
recipes.addShaped(
    powerGlove,
    [
        [null,      wiring,             null],
        [wiring,    pulsatingIronIngot, null],
        [null,      RSreceptCoil,       wiring]
    ]);

[Almagnus1]

Found out that half of the broken recipes were caused by bad configs, and reverting them has reduced the amount of rebalancing that needs to occur, mostly to bring in other mod items to make the recipes make a bit more sense (like not using rockwool for a rubber hose instead of rubber, for example).

Relevant commit: https://github.com/Almagnus1/IaconConfig/commit/6d35f7fa91a92f58e22411857525777a4e9ffa97

[Almagnus1]

Reworked recipes:

https://github.com/Almagnus1/IaconClient/commit/282c93911687b1d4f8cee0cbbdfaa99b98a416b6