Chris--A
commented
8 years ago Hi, this issue is quite difficult to find a nice solution.
However I have come up with a basic workaround. Basically, I have a new type: cstr_p instead of an array of char_p.
First though, if you want an array of char_p, all you can do here is specify the string as a list of characters: const char_p my_string[] PROGMEM = {'t', 'e', 's', 't'};. However this is really only practical if you use small strings.
Before I add this next fix to the lib I want to test it thoroughly, so here is some instructions so you can use it now.
Here is the cstr_p object. Add this below the include for PGMWrap.h in your sketch:
template< unsigned N >
struct cstr_p{
char_p *begin() const{ return (char_p*) &pstr[0];}
char_p *end() const{ return (char_p*) &pstr[N]; }
operator __FlashStringHelper*() const{ return ( __FlashStringHelper* ) &pstr; }
char_p &operator [] (int addr) const{ return *(const char_p*) &pstr[addr]; }
const char pstr[N];
};Then to declare a string, you construct it like this:
const cstr_p< 14 > pStr PROGMEM = {"A test String"};Notice the size of the string (including the null) is needed in the template brackets.
And the usage is quite straight forward.
for( auto &c : pStr ) //Ranged loop over whole string (C++11 only, IDE 1.6.2 and above)
Serial.print( c );
for( int i = 0 ; i < sizeof(pStr) ; ++i ){ //Standard for loop
Serial.print( pStr[i] );
}
Serial.write(pStr[0]); //Print single character
Serial.print(pStr); //Print whole stringAnd here is a complete sketch if you would like to test it.
#include <PGMWrap.h>
template< unsigned N >
struct cstr_p{
char_p *begin() const{ return (char_p*) &pstr[0];}
char_p *end() const{ return (char_p*) &pstr[N]; }
operator __FlashStringHelper*() const{ return ( __FlashStringHelper* ) &pstr; }
char_p &operator [] (int addr) const{ return *(const char_p*) &pstr[addr]; }
const char pstr[N];
};
const cstr_p< 14 > pStr PROGMEM = {"A test String"};
void setup() {
Serial.begin(9600);
for( auto &c : pStr ) //Ranged loop over whole string
Serial.print( c );
Serial.write('\n'); //Move to next line
for( int i = 0 ; i < sizeof(pStr) ; ++i ){ //Standard for loop
Serial.print( pStr[i] );
}
Serial.write('\n');
Serial.write(pStr[0]); //Print single character
Serial.write('\n');
Serial.print(pStr); //Print whole string
}
void loop() {}Let me know how you go.
Cheers.
BlackBrix
mandabenjamin
Hi, how can strings be used with a "PGMWrap-like" style ? this will not compile
const char_p my_string[] PROGMEM = "my Text";cause of "invalid conversion from 'char*' to 'const char&" issuethe goal is to be able to use strings from flash like any other string (from RAM):
Serial.print(my_string);