I2C on PB10 and PB11

[ITstreet1]

GD32F150R8T6

Lib example I2C Scanner

I want to scan I2C device on PB10 and PB11. This can not compile:

    Serial.begin(115200);
    Wire.setSDA(PB11);
    Wire.setSCL(PB10);
    Wire.begin();
    Serial.println("\nI2C Scanner");

'class TwoWire' has no member named 'setSDA'

[maxgerhardt]

We don't provide such dynamic reassignment operations.

If you're using board = genericGD32F150R8 then you have

https://github.com/CommunityGD32Cores/ArduinoCore-GD32/blob/55934353dd9cd1d22d70c78e2222e512e77a89c6/variants/GD32F130R8_GENERIC/variant.h#L111-L128

and you can see PB11 and PB10 are SDA and SCL respectively of the Wire1 object.

You can however compile-time reconfigure the pins since they're all wrapped in #ifndef, meaning you can swap the pins by e.g. adding to the `platformio.ini

build_flags =
  -DPIN_WIRE_SDA=PB11
  -DPIN_WIRE_SCL=PB10
  -DPIN_WIRE1_SDA=PB7
  -DPIN_WIRE1_SCL=PB6

[ITstreet1]

This is the example from the lib:

// --------------------------------------
// i2c_scanner
//
// Version 1
//    This program (or code that looks like it)
//    can be found in many places.
//    For example on the Arduino.cc forum.
//    The original author is not know.
// Version 2, Juni 2012, Using Arduino 1.0.1
//     Adapted to be as simple as possible by Arduino.cc user Krodal
// Version 3, Feb 26  2013
//    V3 by louarnold
// Version 4, March 3, 2013, Using Arduino 1.0.3
//    by Arduino.cc user Krodal.
//    Changes by louarnold removed.
//    Scanning addresses changed from 0...127 to 1...119,
//    according to the i2c scanner by Nick Gammon
//    http://www.gammon.com.au/forum/?id=10896
// Version 5, March 28, 2013
//    As version 4, but address scans now to 127.
//    A sensor seems to use address 120.
//
// This sketch tests the standard 7-bit addresses
// Devices with higher bit address might not be seen properly.
//

/* Example pinmap for Bluepill I2Cs (by Testato)

 I2C-1 standard pins: PB7(sda) PB6(scl)
 Use it by "Wire" without pin declaration
  Wire.begin();

 I2C-1 alternative pins: PB9(sda) PB8(scl)
 Remap the first I2C before call begin()
  Wire.setSDA(PB9);
  Wire.setSCL(PB8);
  Wire.begin();

 I2C-2: PB11(sda) PB10(scl)
 Remap the second I2C before call begin()
  Wire.setSDA(PB11);
  Wire.setSCL(PB10);
  Wire.begin();

 If you want to use the two I2Cs simultaneously, create a new instance for the second I2C
  TwoWire Wire2(PB11,PB10);
  Wire2.begin();

*/

#include <Wire.h>

void setup()
{

    Serial.begin(115200);
    Wire.begin();
    Serial.println("\nI2C Scanner");
}

void loop()
{
    byte error, address;
    int nDevices;

    Serial.println("Scanning...");

    nDevices = 0;
    for(address = 1; address < 127; address++) {
        // The i2c_scanner uses the return value of
        // the Write.endTransmisstion to see if
        // a device did acknowledge to the address.

        Wire.beginTransmission(address);
        error = Wire.endTransmission();

        if(error == 0) {
            Serial.print("I2C device found at address 0x");
            if (address < 16)
              Serial.print("0");
            Serial.println(address, HEX);

            nDevices++;
        }
        else if (error == 4) {
        Serial.print("Unknown error at address 0x");
        if (address < 16)
          Serial.print("0");
        Serial.println(address, HEX);
        }
    }
    if (nDevices == 0)
    Serial.println("No I2C devices found");
    else
    Serial.println("done");

    delay(1000);           // wait 5 seconds for next scan
}

[maxgerhardt]

I fully understand that this works on the Bluepill with the STM32Duino core, but we don't support this API at the moment in this core. Still, you can compile-time reconfigure it in PlatformIO or replace Wire with Wire1 in the sketch.

[ITstreet1]

I see.

With:

Serial.begin(115200);
    Wire1.begin();
    Serial.println("\nI2C Scanner");

and SDA on PB11, adn SCL on PB10 I don't get - No I2C devices found. And the device is there. Should I have to change anything else also?

[maxgerhardt]

That's not the only place where Wire is used, no? The two usages of Wire inside the loop should also be replaced with Wire1.

[ITstreet1]

Oh, man... When you are tired, you should just take a break. Thank you.