Query idea: Nobel Prize candidates

[Daniel-Mietchen]

The idea is to query for prizes frequently awarded to future Nobel laureates, and then to check awardees of such prizes as to whether they

• have received a Nobel prize already
• are still alive

Some further filtering might be necessary, e.g. whether they have worked on a topic that has received a Nobel prize already.

[Daniel-Mietchen]

Here is an example:

#defaultView:BubbleChart
SELECT DISTINCT  ?item  ?itemLabel ?count
WITH {
  SELECT DISTINCT ?award  (COUNT (DISTINCT ?recipient) AS ?recipientcount)
                  WHERE {
                    ?recipient wdt:P166 wd:Q80061 .
                    ?recipient wdt:P166 ?award .
                    FILTER (?award != wd:Q752297)
                  }
  GROUP BY ?award
           HAVING (?recipientcount > 19)
} AS %awards
WITH {
  SELECT DISTINCT  ?item (COUNT (DISTINCT ?award) AS ?count) WHERE {
    INCLUDE %awards
            ?item wdt:P166 ?award .
    FILTER NOT EXISTS { ?item wdt:P570 ?dod}
    FILTER NOT EXISTS { ?item wdt:P166 wd:Q80061}
    FILTER NOT EXISTS { ?item wdt:P166 wd:Q44585}
    FILTER NOT EXISTS { ?item wdt:P166 wd:Q38104}
  } 
  GROUP BY ?item
  HAVING (?count > 3)
} AS %people
WHERE {
  INCLUDE %people
          INCLUDE %awards
          SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,da,de,es,fr,jp,no,ru,sv,zh" . }  
}
GROUP BY  ?count  ?item  ?itemLabel # ?awards
ORDER BY DESC (?count)

Varying the cutoff values (19 and 3) can be instructive.