Look into neural commitment at the cellular versus network level and how they might interact

[Daniel-Mietchen]

I set up cell-level neural commitment (Q107352306) and network-level neural commitment (Q107355712) to get started

[Daniel-Mietchen]

I also worked a bit on the Scholia profiles for both:

Looks like there is no current overlap between the two topics in terms of people, venue, citations or co-occurring topics, since this query currently yields no results:

SELECT * WHERE {
  VALUES ?p {wdt:P50 wdt:P2093 wdt:P921 wdt:P2860 }
  ?item1 wdt:P921 wd:Q107355712 ;
         ?p ?o .
  ?item2 wdt:P921 wd:Q107352306 ;
         ?p ?o .
}

I tested the validity of the query via a similar one that looks at Spondweni virus and Ebola virus:

[Daniel-Mietchen]

Actually, forgot to include the venue — so here comes a new version of the query with that included:

SELECT * WHERE {
  VALUES ?p {wdt:P50 wdt:P2093 wdt:P921 wdt:P2860 wdt:P1433 }
  ?item1 wdt:P921 wd:Q107355712 ;
         ?p ?o .
  ?item2 wdt:P921 wd:Q107352306 ;
         ?p ?o .
}

[Daniel-Mietchen]

Still no results though.

By comparison, the Sondweni/ Ebola query finds a number of venues, e.g. Cell Reports (Q5058165) and Journal of Virological Methods (Q15749961).

[Daniel-Mietchen]

Next step: Look into the other topics that authors of works on network-level neural commitment have published about (try the query):

# tool: scholia
#defaultView:Table
SELECT ?count ?author ?authorLabel ?topic1 ?topic1Label
WITH {
  SELECT (count(?work) as ?count) ?author WHERE {
    { ?work wdt:P921/wdt:P31*/wdt:P279* wd:Q107355712 . }
    union { ?work wdt:P921/wdt:P361+ wd:Q107355712 . }
    union { ?work wdt:P921/wdt:P1269+ wd:Q107355712 . }
    ?work wdt:P50 ?author .
  }
  GROUP BY ?author
} AS %result
WHERE {
  INCLUDE %result

  ?work1 wdt:P50 ?author .
  ?work1 wdt:P921 ?topic1 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . } 
}
ORDER BY DESC(?count)

[Daniel-Mietchen]

This gives a number of hits that seem promising, so let's see whether any of these topics overlap with cell-level neural commitment. For the authors that form part of the above query, the overlap should still be zero, and this query confirms that.

Now let's explore other works (i.e. by other authors) that may have been published on those related topics (try it):

# tool: scholia
#defaultView:Table
SELECT ?work2
WITH {
  SELECT (count(?work) as ?count) ?author WHERE {
    { ?work wdt:P921/wdt:P31*/wdt:P279* wd:Q107355712 . }
    union { ?work wdt:P921/wdt:P361+ wd:Q107355712 . }
    union { ?work wdt:P921/wdt:P1269+ wd:Q107355712 . }
    ?work wdt:P50 ?author .
  }
  GROUP BY ?author
} AS %result
WHERE {
  INCLUDE %result

  ?work1 wdt:P50 ?author .
  ?work1 wdt:P921 ?topic1 .
  ?work2 wdt:P921 ?topic1 .
  ?work2 wdt:P921 wd:Q107352306 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . } 
}
ORDER BY DESC(?count)

Unfortunately, still no results. So perhaps let's look at those ?topic1 results more closely.

[Daniel-Mietchen]

This gives the following (try it):

# tool: scholia
#defaultView:Table
SELECT (count(DISTINCT ?work1) as ?count) ?topic1 ?topic1Label
WITH {
  SELECT  ?author WHERE {
    { ?work wdt:P921/wdt:P31*/wdt:P279* wd:Q107355712 . }
    union { ?work wdt:P921/wdt:P361+ wd:Q107355712 . }
    union { ?work wdt:P921/wdt:P1269+ wd:Q107355712 . }
    ?work wdt:P50 ?author .
  }
  GROUP BY ?author
} AS %result
WHERE {
  INCLUDE %result

  ?work1 wdt:P50 ?author .
  ?work1 wdt:P921 ?topic1 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . } 
}
GROUP BY ?count ?topic1 ?topic1Label
ORDER BY DESC(?count)

and hence

[Daniel-Mietchen]

At this point, it is worth remembering that the topic tagging of articles in Wikidata is still very patchy, so let's explore whether we get any hits for "neural commitment" and some of the more popular of these other topics.

Let's start with "attention" and see what PubMed has:

• https://pubmed.ncbi.nlm.nih.gov/?term=((%22neural+commitment%22%5Btiab%5D)+)+AND+attention+AND+attention)

[Daniel-Mietchen]

This gives three hits, of which Language learning as a function of infant directed speech (IDS) in Spanish: Testing neural commitment using the positive-MMR speaks of higher attentional processes, the other two of research attention to the topic of neural commitment. I tagged it accordingly.

[Daniel-Mietchen]

One of the papers (Infants show a facilitation effect for native language phonetic perception between 6 and 12 months) also states We argue that neural commitment to native-language phonetic properties explains the pattern of developmental change in the first year., so I tagged it as being about network-level neural commitment.

[Daniel-Mietchen]

Now let's see what PMC has for "neural commitment" and "attention":

• https://www.ncbi.nlm.nih.gov/pmc/?term=((%22neural+commitment%22%5Bti%5D)+OR+(%22neural+commitment%22%5Bab%5D)+)+AND+attention+AND+attention)

[Daniel-Mietchen]

This currently yields 8 hits. Of these, three had not been tagged in Wikidata as being about either of the two levels of neural commitment, so I just tagged them.

[Daniel-Mietchen]

Now onto the other topics associated with network-level neural commitment (from 2-10 in that ranking):

• magnetoencephalography
  • PMC: 3 hits+AND+magnetoencephalography), all already tagged with either of the two forms of "neural commitment"
  • PubMed: 1 hit+AND+magnetoencephalography), already tagged
• electrophysiology
  • PMC: 3 hits+AND+electrophysiology), which I tagged
  • PubMed: 1 hit+AND+electrophysiology), which I tagged
• automation
  • PMC: 0 hits+AND+automation)
  • PubMed: 1 hit+AND+automation), already tagged
• autism
  • PMC: 4 hits+AND+autism), all already tagged. They also all mention autism only in passing, so I did not add it. Of note, "functional connectivity" occurred as a connected term that seems worth exploring further in this neural commitment context
  • PubMed: 1 hit+AND+autism), already tagged
• dyslexia
  • PMC: 5 hits+AND+dyslexia), four already tagged; I tagged the fifth one too, including with dyslexia
  • PubMed: 2 hits+AND+dyslexia), both already tagged
• schizophrenia
  • PMC: 2 hits+AND+schizophrenia), already tagged; the mentions of schizophrenia were in passing, so did not add that tag
  • PubMed: 1 hit+AND+schizophrenia), already tagged
• neurophysiology
  • PMC: 0 hits+AND+neurophysiology)
  • PubMed: 1 hit+AND+neurophysiology), already tagged
• Asperger syndrome
  • PMC: 0 hits+AND+Asperger)
  • PubMed: 0 hits+AND+Asperger)
• cochlear implant
  • PMC: 0 hits+AND+%22cochlear+implant%22)
  • PubMed: 0 hits+AND+%22cochlear+implant%22)

[Daniel-Mietchen]

The above query for the intersection between both neural commitment levels now times out, so here is a version that does not:

#defaultView:Table
SELECT ?work2
WHERE {
  ?work1 wdt:P921 wd:Q107355712 .
  ?work1 wdt:P50 ?author .
  ?work1 wdt:P921 ?topic1 .
  ?work2 wdt:P921 ?topic1 .
  ?work2 wdt:P921 wd:Q107352306 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,da,de,es,fr,jp,nl,no,ru,sv,zh" . } 
}