Home page charts Mitigation and Adaptation

[peterfrenchons]

Mitigation chart - using https://beta.gss-data.org.uk/cube/explore?uri=http%3A%2F%2Fgss-data.org.uk%2Fdata%2Fclimate-change%2Fbeis-energy-trends-table-1-2-extract-2021%2Finland-energy-consumption-primary-fuel-input-basis-2021%23dataset-catalog-entry?

Adaptation chart - using https://beta.gss-data.org.uk/cube/explore?uri=http%3A%2F%2Fgss-data.org.uk%2Fdata%2Fclimate-change%2Fforestry-research-forestry-statistics-2022-new-planting%2Fforestry-statistics-2022-new-planting%23dataset-catalog-entry?

[Shannon95]

Adaptation chart updated sparql query : Found under Home/Overview Data with the name Tile; SparkLine; New planting of UK woodlands, thousand hectares, 1976 to 2022 : 2022-10-25 or click here

Sparql query posted below also :

PREFIX qb: <http://purl.org/linked-data/cube#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX meas: <http://gss-data.org.uk/def/climate-change/measure/>
PREFIX data: <http://gss-data.org.uk/data/climate-change/forestry-research-forestry-statistics-2022-new-planting/forestry-statistics-2022-new-planting#>
PREFIX dim: <http://gss-data.org.uk/data/climate-change/forestry-research-forestry-statistics-2022-new-planting/forestry-statistics-2022-new-planting#dimension/>
PREFIX def: <http://gss-data.org.uk/def/climate-change/property/dimension/>

SELECT (?year AS ?x) (?value AS ?y)
WHERE {
    ?obs qb:dataSet data:dataset ;
        dim:year [ rdfs:label ?year ] ;
        meas:total-new ?value ;
}
ORDER BY ?year

[Shannon95]

Mitigation chart updated query

Found under Home/Overview Data with the name Tile; Bar; Renewable energy share in total energy consumption, UK, 2021 : 2022-10-25 or click here

Sparql query posted below also :

PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX qb: <http://purl.org/linked-data/cube#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX void: <http://rdfs.org/ns/void#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

PREFIX data:<http://gss-data.org.uk/data/climate-change/beis-energy-trends-table-1-2-extract-2021/inland-energy-consumption-primary-fuel-input-basis-2021#dataset>
PREFIX period: <http://purl.org/linked-data/sdmx/2009/dimension#refPeriod>
PREFIX measure: <http://gss-data.org.uk/data/climate-change/beis-energy-trends-table-1-2-extract-2021/inland-energy-consumption-primary-fuel-input-basis-2021#measure/energy-consumption>
PREFIX fuel: <http://gss-data.org.uk/def/energy/property/dimension/fuel>

SELECT ?timePeriod ?label ?total
    {
   {
    SELECT (SUM(ROUND((?consumption / ?total_consumption) * 100 * 100)) / 100 AS ?total)
    (GROUP_CONCAT(DISTINCT ?fuelEdit; separator = ",") AS ?label)
    (GROUP_CONCAT(DISTINCT ?year; separator = ",") AS ?timePeriod)
    WHERE {
        {
             SELECT * {
                          ?obs qb:dataSet data: .
                          ?obs period: [ rdfs:label ?year] .
                          ?obs fuel: [ rdfs:label ?fuel] .
                          ?obs measure: ?consumption .  
                          FILTER((?fuel != 'Net Imports' && ?fuel != 'Nuclear') && ?year = '2021') .
                          BIND(
                                  REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(?fuel,'Coal','Non-renewable energy'), 'Petroleum', 'Non-renewable energy'), 'Natural Gas', 'Non-renewable energy'), "Bioenergy","Renewable energy"), "Wind Solar and Hydro", "Renewable energy")  AS ?fuelEdit) .
            }
        }   
        {
            SELECT (SUM(?consumption) AS ?total_consumption)
                        {
                          ?obs qb:dataSet data: .
                          ?obs period: [ rdfs:label ?year] .
                          ?obs fuel: [ rdfs:label ?fuel] .
                          ?obs measure: ?consumption .  
                          FILTER((?fuel != 'Net Imports' && ?fuel != 'Nuclear') && ?year = '2021') .
                          BIND(
                                  REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(?fuel,'Coal','Non-renewable energy'), 'Petroleum', 'Non-renewable energy'), 'Natural Gas', 'Non-renewable energy'), "Bioenergy","Renewable energy"), "Wind Solar and Hydro", "Renewable energy")  AS ?fuelEdit) .
            }
        }
    }
    GROUP BY ?fuelEdit ?year
    ORDER BY ?year  
  }
}

[peterfrenchons]

26/10 09:25 Mitigation SPARQL being checked