IPL 제작2(디스크 읽기)

[KIMBIBLE]

초반 OS 제작 과정 자체에서 많은부분 Makefile을 활용한 툴 사용이 중점적으로 이루어져 제작 과정에 사용하는 툴들을 관리하기 위한 디렉토리 z_tools 추가를 통해 Makefile에서 툴 경로 설정 용이하게 만듬 (아니면 Makefile 수정해야 할 부분이 너무 많아짐)

[KIMBIBLE]

INTRO

이전에 제작한 IPL은 실제로 프로그램을 로드하지 않았음. 해당 장에서는 실제로 프로그램을 로드하는 부분까지 진행 할 예정.

[KIMBIBLE]

이전 ipl과의 차이

helloos5 까지의 ipl과 bbkimos_00a 부터의 ipl의 차이

1. helloos5 : 단순히 비디오 BIOS 호출을 통해 화면에 문자 출력하는 기능
2. bbkimos_00a : 디스크 읽고 이를 에러 발생 시 결과 화면에 출력하는 기능

• 디스크 읽기

  ; 디스크를 읽는다

    MOV     AX,0x0820
    MOV     ES,AX
    MOV     CH, 0           ; 실린더 0
    MOV     DH, 0           ; 헤드 0
    MOV     CL, 2           ; 섹터 2
  
    MOV     AH, 0x02        ; AH=0x02 : 디스크 read
    MOV     AL, 1           ; 1섹터
    MOV     BX,0
    MOV     DL, 0x00        ; A드라이브
    INT     0x13            ; 디스크 BIOS 호출
    JC      error

• 에러 처리

error:

  MOV     AX,0
  MOV     ES,AX
  MOV     SI,msg

• 에러 메시지

msg:

  DB      0x0a, 0x0a      ; 개행을 2개
  DB      "load error"
  DB      0x0a            ; 개행
  DB      0

  RESB    0x7dfe-$            ; 0x7dfe까지를 0x00로 채우는 명령

  DB      0x55, 0xaa

[KIMBIBLE]

일반적인 BIOS 인터럽트 목록

• 몇가지 경우를 비교해 본 결과 같은 인터럽트 클래스를 갖는 듯
• 일부 바이오스(오래된 것들)은 조금 다른 형태의 인터럽트 클래스를 갖는다고 한다.

https://ko.wikipedia.org/wiki/%EB%B0%94%EC%9D%B4%EC%98%A4%EC%8A%A4%EC%9D%B8%ED%84%B0%EB%9F%BD%ED%8A%B8%ED%98%B8%EC%B6%9C

[KIMBIBLE]

img 파일 생성 과정 정리

• ipl.bin 파일 offset을 확인해 보니 0x0000 ~ 0x01FF 까지 총 512 바이트가 만들어 진 것 확인!
• (그냥 속성에서 확인하니 512 바이트라고 바로 나오네;;)
• img 파일은 아래와 같은 과정을 통해 생성됨
  1. nask 어셈블러를 통해 .nas 파일에서 .bin파일 만든다.
  2. 부트 섹터에 해당되는 ***.bin 파일에서 디스크 이미지 관리 툴을 이용해 나머지 이미지를 만든다.

[KIMBIBLE]

실행 결과(bbkimos_00a)

배치 파일을 알맞게 수정하고 make run 을 입력하여 실행하게 되면 플로피 디스크에서 이미지를 읽어올 때 오류가 발생하기 않았기 때문에 기본 QEMU 출력 문자를 제외한 아무런 문자 출력이 없는 화면 상태로 정상적으로 동작하는 것을 확인할 수 있다.

[KIMBIBLE]

디스크 읽기 코드 분석

바이오스 인터럽트 호출

• 개념

  바이오스 인터럽트 호출(영어: BIOS interrupt call)은 도스용 프로그램과, 부트 로더와 같은 일부 기타 소프트웨어가 IBM PC 호환기종의 컴퓨터에 위치한 바이오스의 기능을 불러내는데 이용하는 방식이다. 일부 운영 체제 또한 초기 시동 단계에서 바이오스를 이용하여 하드웨어 자원을 탐지하고 초기화할 수 있다.

https://ko.wikipedia.org/wiki/%EB%B0%94%EC%9D%B4%EC%98%A4%EC%8A%A4%EC%9D%B8%ED%84%B0%EB%9F%BD%ED%8A%B8%ED%98%B8%EC%B6%9C

• INT 13h : 디스크 서비스 낮은 수준의 디스크 서비스

AH 설명 00h >>> 디스크 드라이브 초기화 01h >>> 드라이브 상태 검사 02h >>> 섹터 읽기 03h >>> 섹터 쓰기 04h >>> 섹터 유효 여부 확인 05h >>> 트랙 포맷 08h >>> 드라이브 변수 가져오기 09h >>> 고정 드라이브 변수 초기화 0Ch >>> 지정된 트랙으로 찾기 0Dh >>> 고정 디스크 컨트롤러 초기화 15h >>> 드라이브 종류 가져오기 16h >>> 플로피 드라이브 미디어 변경 상태 가져오기 17h >>> 디스크 종류 설정 18h >>> 플로피 드라이브 미디어 종류 설정 41h >>> 확장 디스크 드라이브 (EDO) 설치 검사 42h >>> 섹터 확장 읽기 43h >>> 섹터 확장 쓰기 44h >>> 섹터 확장 유효 여부 확인 45h >>> 드라이브 잠금/잠금 해제 46h >>> 미디어 꺼내기 47h >>> 확장 찾기 48h >>> 드라이브 변수 확장 가져오기 49h >>> 미디어 변경 상태 확장 가져오기 4Eh >>> 하드웨어 구성 확장 설정

디스크 읽기 코드 분석

• 디스크 읽기

  ; 디스크를 읽는다

    MOV     AX,0x0820
    MOV     ES,AX
    MOV     CH, 0           ; 실린더 0
    MOV     DH, 0           ; 헤드 0
    MOV     CL, 2           ; 섹터 2
  
    MOV     AH, 0x02        ; AH=0x02 : 디스크 read
    MOV     AL, 1           ; 1섹터
    MOV     BX,0
    MOV     DL, 0x00        ; A드라이브
    INT     0x13            ; 디스크 BIOS 호출
    JC      error

1. ES 레지스터 : BX레지스터와 함께 사용 디스크에서 읽은 데이터를 메모리의 어디에 저장할지 나타내는 주소 값. 계산 : ES * 16 + BX (최대 1MB정도)

  MOV     AX,0x0820
  MOV     ES,AX

  MOV     BX,0

위 코드에 따르면 ES : 0x0820, BX: 0x00 이므로 0x8200 + 0x00인 0x8200이 디스크에서 읽은 데이터를 저장할 메모리의 위치가 된다. 0x8000이후의 메모리를 사용한 이유는 AT 메모리 맵에 의하면 사용하지 않고 있는 메모리 영역이기 때문,

2. CHS 방식으로 디스크를 읽을 부분 레지스터에 설정.

  MOV     CH, 0           ; 실린더 0
  MOV     DH, 0           ; 헤드 0
  MOV     CL, 2           ; 섹터 2 (MBR 1번 섹터 이후의 섹터)

실린더 번호 : 디스크 바깥(외부)부터 세어 몇 번째 트랙인지. (한면에 0 ~ 79 : 80개) 섹터 번호 : 트랙 안의 몇 번째 블록인가. (각 실린더 내에 1 ~ 18번 : 18개) 헤드 번호 : 헤드0(위), 헤드(아래)

3. 디스크 동작 레지스터에 설정

  MOV     AH, 0x02        ; AH=0x02 : 디스크 read
  MOV     AL, 1           ; 1섹터
  MOV     BX,0
  MOV     DL, 0x00        ; A드라이브

AH레지스터에 0x02를 저장해 디스크 읽기 방식을 설정하고 읽을 디스크의 단위를 1섹터로 설정한 후 (BX레지스터는 버퍼 어드레스로 위에 설명) DL레지스터에 드라이버 번호를 설정(드라이브를 1개만 사용중이므로 0x00 설정)

4. INT 0x13 명령 실행

  INT     0x13            ; 디스크 BIOS 호출
  JC      error

위에서 설정한 레지스터를 토대로 인터럽트 INT 0x13을 호출해 디스크 BIOS를 호출한다. 디스크 READ 에러 발생 시 CF 레지스터에 1이 저장된다. INT 13 호출 결과 CF 레지스터의 값은 아래의 값이 리턴된다. 에러 발생 시 : 1 정상 동작 시 : 0

INT 0x13 호출 결과 CF 레지스터에 리턴되는 에러 코드를 통해 정상 동작 시 JC error 이후 부분을 실행하고 에러 발생 시 error 레이블로 점프한다.

• INT 13h AH=02h: Read Sectors From Drive

Parameters: AH >>> 02h AL >>> Sectors To Read Count CH >>> Cylinder CL >>> Sector DH >>> Head DL >>> Drive ES:BX >>> Buffer Address Pointer

Results: CF >>> Set On Error, Clear If No Error AH >>> Return Code AL >>> Actual Sectors Read Count

https://en.wikipedia.org/wiki/INT_13H

[KIMBIBLE]

디스크 정리

• https://ko.wikipedia.org/wiki/%ED%95%98%EB%93%9C%EB%94%94%EC%8A%A4%ED%81%AC%EB%93%9C%EB%9D%BC%EC%9D%B4%EB%B8%8C

• http://kcats.tistory.com/153

• http://webdir.tistory.com/160

하드 디스크의 두 가지 접근 방식(Addressing Mode)

CHS-Adressierung(Cylinder, Header, Sector)

• 고전적 방식. 실습 내용은 이 방식에 따라 디스크를 읽음.
• 데이터를 Read/Write 할 하나의 섹터의 위치를 정하기 위해 실린더 번호, 헤드 번호, 섹터 번호를 정하는 방식.

  실린더 번호 : 디스크 바깥(외부)부터 세어 몇 번째 트랙인지. (한면에 0 ~ 79 : 80개) 섹터 번호 : 트랙 안의 몇 번째 블록인가. (각 실린더 내에 1 ~ 18번 : 18개) 헤드 번호 : 헤드0(위), 헤드(아래)

• Linux의 경우 디바이스 드라이버가 CHS 값을 계산하여 디스크 장치와 데이터 간의 정보 교환을 실행하므로 유저가 CHS를 신경 쓸 필요는 없으나, 현재 OS 실습 단계에서는 아직 디바이스 드라이버를 만든 상태가 아니기 때문에 디스크 장치와 데이터 간의 정보 교환에서 CHS 값을 계산해주어야 함.(디스크 읽기 부분 코드는 이 계산 부분을 다루고 있음) Linux에서는 fdisk -l 옵션을 이용하여 실린더 번호 정보 확인 가능
• 운영체제 입장에서 디스크에 접근하기 위해 BIOS를 통해야 하고, 하드디스크는 ATA라는 나름의 인터페이스를 규정하여 사용한다. 따라서 BIOS인터페이스와 ATA의 인터페이스를 모두 맞춰주어야 하는 불편한 상황이 CHS에서 발생하기 때문에 현재는 대부분 LBS 주소지정방식을 사용한다.
• 표현 가능 데이터 : 실린더 수 헤드 수 섹터 수 섹터 크기 `2^10(실린더 수) 2^4(헤드 수) (2^6 -1)(섹터 수) 512(섹터 크기) = 504MB`

LBA-Adressierung (Logical Block Addressing)

• 현재 대부분의 하드디스크에서 사용하는 주소 지정방식.
• 섹터들을 일차원 배열처럼 순서대로 번호를 설정하여 주소를 지정하는 방식. (하드디스크의 전체 섹터에 0부터 인덱스를 붙여 주소를 지정하는 방식)
• 사용자가 원하는 섹터의 논리 주소를 찾아 접근하면 해당 디스크 컨트롤러가 해당 주소를 물리적 주소로 변환하여 접근가능하게 해주는 방식.

변환

CHS -> LBA

LBA = ( ( CYLINDER heads per cylinder + HEAD ) sectors per track ) + SECTOR – 1

LBA -> CHS

CYLINDER = LBA / ( heads per cylinder * sectors per track ) HEAD = ( LBA / sectors per track ) % heads per cylinder SECTOR = ( LBA % sectors per track ) + 1

[KIMBIBLE]

에러 발생 시 재 동작 처리

• 디스크의 데이터를 한번에 못 읽을 경우 재 동작 처리.
• 디스크 불량 시 무한루프 방지를 위해 5회만 반복.

코드 분석

; 디스크를 읽는다 MOV AX,0x0820 MOV ES,AX MOV CH, 0 ; 실린더 0 MOV DH, 0 ; 헤드 0 MOV CL, 2 ; 섹터 2 MOV SI, 0 ; 실패 회수를 세는 레지스터 retry: MOV AH, 0x02 ; AH=0x02 : 디스크 read MOV AL, 1 ; 1섹터 MOV BX,0 MOV DL, 0x00 ; A드라이브 INT 0x13 ; 디스크 BIOS 호출 JNC fin ; 에러가 일어나지 않으면 fin에 ADD SI, 1 ; SI에 1을 더한다 CMP SI, 5 ; SI와 5를 비교 JAE error ; SI >= 5이면 error에 MOV AH,0x00 MOV DL, 0x00 ; A드라이브 INT 0x13 ; 드라이브의 리셋트 JMP retry

1. 실패 횟수 카운트

     MOV     SI, 0           ; 실패 회수를 세는 레지스터

   SI 레지스터를 0으로 초기화하여 실패 횟수를 카운트합니다. 에러 발생 시 5회 반복을 하기 위해 이후 CMP SI, 5 명령을 통해 실패 횟수를 체크합니다.

2. retry 레이블

   retry: retry 레이블을 정의해 조건에 만족하지 않을 경우(에러 발생 && 에러 발생 횟수<5) 마지막의 JMP retry를 통해 retry 레이블로 점프해 다시 명령을 수행하도록 합니다.

retry 레이블에서 조건을 통해 반복을 제어하는 부분은 아래와 같습니다.

  JNC     fin         ; 에러가 일어나지 않으면 fin에
  ADD     SI, 1           ; SI에 1을 더한다
  CMP SI, 5           ; SI와 5를 비교
  JAE     error           ; SI >= 5이면 error에

위 명령을 통해 에러가 5회 미만 발생할 경우 다시 retry 레이블로 점프하여 다시 반복을 수행하고 반복 결과 에러가 5회 이상 발생할 경우 error 레이블로 점프, 정상 수행 시 fin레이블로 점프 동작을 하게 됩니다.

3. 드라이브 리셋

  MOV     AH,0x00
  MOV     DL, 0x00        ; A드라이브
  INT     0x13            ; 드라이브의 리셋트

위와 같이 AH 레지스터와 DL 레지스터를 0으로 초기화하여 INT 0x13 인터럽트를 호출하면 드라이브가 리셋되어 처음부터 다시 시작할 수 있습니다. (AT-BIOS에서 시스템 리셋)

[KIMBIBLE]

디스크를 18섹터까지 읽기

• 이전까지의 IPL은 2섹터까지 디스크를 읽는 기능만 존재.
• 이전과 마찬가지로 디스크 읽기 실패 카운트가 5이면 종료.

retry: MOV AH, 0x02 ; AH=0x02 : 디스크 read MOV AL, 1 ; 1섹터 MOV BX,0 MOV DL, 0x00 ; A드라이브 INT 0x13 ; 디스크 BIOS 호출 JNC next ; 에러가 일어나지 않으면 next에 ADD SI, 1 ; SI에 1을 더한다 CMP SI, 5 ; SI와 5를 비교 JAE error ; SI >= 5 이면 error에 MOV AH,0x00 MOV DL, 0x00 ; A드라이브 INT 0x13 ; 드라이브의 리셋트 JMP retry next:

• 이전 IPL과 마찬가지로 위의 부분은 오류 발생을 카운트하며 디스크를 읽는 동작이다.
• 추가된 부분은 정상적으로 읽을 시 next 레이블로 점프 해 읽기 동작을 진행하는 것이다.

  MOV     AX, ES          ; 주소를 0x200 진행한다
  ADD     AX,0x0020
  MOV     ES, AX          ; ADD ES, 0x020라고 하는 명령이 없기 때문에 이렇게 하고 있다
  ADD     CL, 1           ; CL에 1을 더한다
  CMP     CL, 18          ; CL와 18을 비교
  JBE     readloop        ; CL <= 18 이라면 readloop에

; 다 읽었지만 우선 할일이 없기 때문에 sleeve

• 디스크의 한 섹터는 512 Byte이기 때문에 한 섹터를 메모리 상에 매핑시키게 되면 메모리의 512바이트를 사용하여야한다. 여기서 십진수 512바이트는 0x200을 뜻하며, 읽은 디스크 데이터만큼(섹터) 메모리 주소의 위치를 증가시키기 위해 ES 세그먼트 레지스터에 0x20을 더해 ES(0x20) * 0x10(1자리 증가) + BX(0)인 0x200이 되도록 ES 레지스터를 증가시킨다.

• 디스크를 읽을 때 섹터번호에 해당하는 CL레지스터의 값 또한 증가시켜 CL이 18이 될 때(CL : 0~17까지 동작, 18회) 읽은 섹터가 18섹터가 되므로 디스크 읽기를 멈추게 된다.

이렇게 섹터의 수를 증가시키는 방법으로 디스크의 모든 섹터를 다 읽을 수 있을까?

• CHS Addressing Mode에서 디스크는 실린더, 헤드, 섹터 단위로 표현되며, 각각의 요소을 조합해 디스크의 영역을 나타내는 방식이기 때문에 각각의 요소들에는 넘버링을 할 수 있는 한계가 존재한다. 예를들어, 섹터의 갯수인 18개를 다 읽었다면 더이상 섹터 넘버를 증가시키는 방식으로 읽을 수 없기에 실린더나 헤드의 번호를 증가시키는 방식으로 디스크 읽기 과정을 진행하여야한다.

한번에 여러 섹터를 읽을 수 없을까??

• INT 0x13 호출 전에 AL 레지스터에 저장되어 있는 값이 한번에 읽을 섹터를 의미한다. 이 값을 17로 바꿔주면 2~17 섹터의 내용을 한번에 읽을 수는 있지만, 복수의 트랙에 걸쳐있는 데이터를 다룰 때 한 섹터씩 반복하여 읽는 방법이 더 안전하다고 한다.(Disk의 BIOS Read Function에서 설명) AL 레지스터에 저장될 수 있는 값(0x00제외)인 0x01 ~0xff 이 한번에 읽을 수 있는 디스크의 범위가 된다.

[KIMBIBLE]

디스크를 10 실린더만큼 읽어보기

• 디스크의 읽기 단위는 섹터 -> 헤드 -> 실린더 순으로 증가한다. C0-H0-S18 -> C0-H1-S1
• 이를 적절히 증가시켜 디스크의 모든 부분을 읽을 수 있다.

코드 추가

아래는 이와 같은 동작을 수행하도록 코드를 변경한 부분이다.

CYLS EQU 10 ; 어디까지 Read할까

  ORG     0x7c00          ; 이 프로그램이 어디에 Read되는가

먼저 EQU 명령을 통해 literal 상수 10를 CYLS라는 이름으로 사용할 것을 명시한다.

next: MOV AX, ES ; 주소를 0x200 진행한다 ADD AX,0x0020 MOV ES, AX ; ADD ES, 0x020 라고 하는 명령이 없기 때문에 이렇게 하고 있다 ADD CL, 1 ; CL에 1을 더한다 CMP CL, 18 ; CL와 18을 비교 JBE readloop ; CL <= 18 이라면 readloop에 MOV CL,1 ADD DH,1 CMP DH,2 JB readloop ; DH < 2 라면 readloop에 MOV DH,0 ADD CH,1 CMP CH,CYLS JB readloop ; CH < CYLS 라면 readloop에 ; 다 읽었지만 우선 할일이 없기 때문에 sleeve

• readloop 레이블은 디스크 읽기 동작을 시작하는 부분으로 정의하였다.
• 이 동작을 통해 실린더 크기가 CYLS로 정의된 값인 10일 때까지 읽기 동작이 반복된다.

[KIMBIBLE]

어셈블리 조건 점프 명령들 정리

• Unsigned 계열(부호가 없는 값)

  je: jump equal - 비교 결과가 같을 때 점프 jne: jump not equal - 비교 결과가 다를 때 점프 jz: jump zero - 결과가 0일 때 점프, je와 같음(cmp 명령에서 결과가 같으면 0을 출력합니다). jnz: jump not zero - 결과가 0이 아닐 때 점프

  ja: jump above - cmp a, b에서 a가 클 때 점프 jae: jump above or equal - 크거나 같을 때 점프 jna: jump not above - 크지 않을 때 점프 jnae: jump not above or equal - 크지 않거나 같지 않을 때 점프

  jb: jump below - cmp a, b에서 a가 작을 때 점프 jbe: jump below or equal - 작거나 같을 때 점프 jnb: jump not below - 작지 않을 때 점프 jnbe: jump not below or equal - 작지 않거나 같지 않을 때 점프

  jc: jump carry - 캐리 플래그가 1일 때 점프 jnc: jump not carry - 캐리 플래그가 0일 때 점프

  jnp/jpo: jump not parity / parity odd - 패리티 플래그가 0일 때 / 홀수일 때 점프 jp/jpe: jump parity / parity even - 패리티 플래그가 1일 때 / 짝수일 때 점프

  jecxz: jump ecx zero - ecx 레지스터가 0일때 점프

• Signed 계열(부호가 있는 값)

  jg: jump greater - cmp a, b에서 a가 클 때 점프 jge: jump greater or equal - 크거나 같을 때 점프 jng: jump not greater - 크지 않을 때 점프 jnge: jump not greater or equal - 크지 않거나 같지 않을 때 점프

  jl: jump less - cmp a, b에서 a가 작을 때 점프 jle: jump less or equal - 작거나 같을 때 점프 jnl: jump not less - 작지 않을 때 점프 jnle: jump not less or equal - 작지 않거나 같지 않을 때 점프

  jo/jno: jump overflow / not overflow - 오버플로 플래그가 1일 때 / 0일 때 점프 js/jns: jump sign / not sign - 사인(부호) 플래그가 1일 때(음수) / 0일 때(양수) 점프

• 위의 조건 점프 명령을 결합해 다양한 조건문을 구현할 수 있다.

http://pyrasis.com/blog/entry/ReverseEngineeringForNewbieAssemblyOperation