Package request: wmic (substitute -bin)

[flandweber]

wmic is available as wmic-bin but should be built from source. Additionally the wrong license is given

Metadata

• homepage URL: https://www.openvas.org/
• source URL: https://github.com/greenbone/openvas-smb
• license: GPL-2.0 license
• platforms:

@peterhoeg

[TomaSajt]

I think I made a working derivation, however, I don't really know how to test it. I'll leave it here, if anyone wants to open a PR and maintain it:

{ lib
, stdenv
, fetchFromGitHub
, fetchpatch

, cmake
, pkg-config
, perl

, gnutls
, libtasn1
, libidn2
, p11-kit
, zlib
, libunistring
, heimdal
, popt
}:

stdenv.mkDerivation (finalAttrs: {
  pname = "openvas-smb";
  version = "22.5.3";

  src = fetchFromGitHub {
    owner = "greenbone";
    repo = "openvas-smb";
    rev = "refs/tags/v${finalAttrs.version}";
    hash = "sha256-mOzDRqaLEwmpIybG35KKjwbpLYNPK4B2wjANoyiYQbc=";
  };

  outputs = [ "out" "dev" "man" ];

  nativeBuildInputs = [
    cmake
    pkg-config
    perl
  ];

  patches = [
    (fetchpatch {
      name = "fix-missing-includes-path.patch";
      url = "https://git.alpinelinux.org/aports/plain/community/openvas-smb/fix-missing-includes-path.patch?id=ca03fab7136ee26819e5b9f16d255c3e65ad9917";
      hash = "sha256-xanMP3fHUsLbJD3u4pD7yltBv96fdVFHwGnLW6kRjS4=";
    })
  ];

  buildInputs = [
    gnutls
    libtasn1
    libidn2
    p11-kit
    libunistring
    zlib
    heimdal
    popt
  ];

  meta = {
    description = "SMB module for the OpenVAS Scanner";
    homepage = "https://github.com/greenbone/openvas-smb";
    license = lib.licenses.gpl2Only;
    mainProgram = "wmic";
    maintainers = with lib.maintainers; [ ];
    platforms = lib.platforms.unix;
  };
})

[peterhoeg]

I'm not using wmic (and haven't been for a long time), so I unfortunately have no way to test this out. We also don't add new packages without maintainers, just FYI.