License / Publishing to AUR

[natrow]

Hello, I'm interested in publishing this as a package on the AUR. I have a draft PKGBUILD which seems to work:

# Maintainer: Nathan Rowan <rvanathanrowan@gmail.com>
pkgname=libfprint-2-tod1-synatudor-git
pkgrel=1
pkgver=r199.a528a7d
pkgdesc="Synaptics Tudor Driver Relinking Project"
arch=(x86_64)
url="https://github.com/Popax21/synaTudor"
license=(unknown)
depends=(libfprint-tod openssl libusb libgusb glib2 libseccomp libcap glibc)
makedepends=(git meson innoextract wget)
checkdepends=()
optdepends=()
provides=()
conflicts=()
groups=()
source=("libfprint-2-tod1-synatudor::git+https://github.com/Popax21/synaTudor.git")
sha256sums=('SKIP')

pkgver() {
    cd "$srcdir/${pkgname%-git}"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
    cd "$srcdir/${pkgname%-git}"
    # cli is for debug usage only
    rm -rf cli/
    sed '/cli/d' meson.build -i
    # INSTALL_DIR has a hardcoded reference to /sbin
    sed 's|/sbin|/usr/bin|' meson.build -i
}

build() {
    arch-meson "$srcdir/${pkgname%-git}" build
    meson compile -C build
}

check() {
    meson test -C build --print-errorlogs
}

package() {
    meson install -C build --destdir "$pkgdir/"
}

However I didn't see any license in the repository. I wanted to add the correct license before submitting to the AUR.

[Popax21]

Hi, thanks for reaching out! It seems like some people already created the libfprint-tudor AUR package - I am not sure if it is functional, but it might be worth checking out. They indicated that the package is licensed under the LGPL, which is fine with me, even though I didn't specify a license so far (mostly because I didn't think about this topic too much till now .-.). I might push a proper license file soon though, as it seems like it has become relevant/needed for the repo.

EDIT: As a quick side note, I really appreciate you reaching out before trying to submit your PKGBUILD - while I don't have any issues with the work of the creators of libfprint-tudor or the particular license they chose, it did initially rub me the wrong way that they just chose one on their own without making sure I'm OK with it (even though I actually am), so I just wanted to say thank you for taking the time to do things "properly" :)

[natrow]

Thanks! I didn't realize that the other package was actually for this project. I've added a comment on that package with some suggestions based on my PKGBUILD. Also I just wanted to ask since it wasn't clear to me, does the systemd service need to be started in order for the driver to work?

[Popax21]

Thanks! I didn't realize that the other package was actually for this project. I've added a comment on that package with some suggestions based on my PKGBUILD. Also I just wanted to ask since it wasn't clear to me, does the systemd service need to be started in order for the driver to work?

The service must be running, but it should be automatically started when the dbus service is used. I also uploaded a license file now (I went for the LGPL to prevent possible conflicts with libfprint's license).

[natrow]

Thanks! I've contacted the owner of the original AUR package and they've transferred ownership to me - I'm going to rename the package to libfprint-2-tod1-synatudor-git and add a few other changes.