Gradle version 8.7 cannot be applied

[JeanWorldTour2]

Executing Gradle task: eclipse Build info: MCreator 2024.1.18518, forge-1.19.2, 64-bit, 14283 MB, Windows 11, JVM 17.0.10, JAVA_HOME: D:\Program Files\MCreator 2024.1\MCreator\jdk, started on: 2024-05-04-16:02:47

FAILURE: Build failed with an exception.

• Where: Build file 'D:\MCreatorWorkspaces\soul_glowstone\build.gradle' line: 3
• What went wrong: An exception occurred applying plugin request [id: 'net.minecraftforge.gradle', version: '5.1.+']

  Failed to apply plugin 'net.minecraftforge.gradle'. Found Gradle version Gradle 8.7. Versions Gradle 8.0 and newer are not supported. Use ForgeGradle 6 or newer for Gradle 8.0+ support.

• Try:

  Run with --stacktrace option to get the stack trace. Run with --info or --debug option to get more log output. Run with --scan to get full insights. Get more help at https://help.gradle.org. BUILD FAILED in 13s

BUILD FAILED Task completed in 14 seconds

[Spectrall368]

Try creating a new workspace with the same generator, take the build.gradle file, paste it into your workspace and try again

[Spectrall368]

Could you attach the workspace?

[JeanWorldTour2]

wait i will try. it needs a bit of time

[JeanWorldTour2]

https://www.transfernow.net/dl/20240504ifNqZTSG that's the workspace

[Spectrall368]

Try deleting the one written in the build.gradle file and pasting this

plugins {
    id 'eclipse'
    id 'net.minecraftforge.gradle' version '[6.0.16,6.2)'
    id 'org.spongepowered.mixin' version '0.7.+'
}

version = '1.0'
group = 'com.yourname.modid'
archivesBaseName = 'modid'

java.toolchain.languageVersion = JavaLanguageVersion.of(17)

minecraft {
    mappings channel: 'official', version: '1.19.2'

    accessTransformer = file('src/main/resources/META-INF/accesstransformer.cfg')

    copyIdeResources = true

    runs {
        client {
            workingDirectory project.file('run')

            property 'forge.logging.markers', 'REGISTRIES'
            property 'forge.logging.console.level', 'debug'

            mods {
                examplemod {
                    source sourceSets.main
                }
            }
        }

        server {
            workingDirectory project.file('run')

            property 'forge.logging.markers', 'REGISTRIES'
            property 'forge.logging.console.level', 'debug'

            mods {
                examplemod {
                    source sourceSets.main
                }
            }
        }
    }
}

dependencies {
    minecraft 'net.minecraftforge:forge:1.19.2-43.3.13'
    annotationProcessor 'org.spongepowered:mixin:0.8.5:processor'
}

mixin {
    add sourceSets.main, 'mixins.soul_glowstone.refmap.json'

    config 'mixins.soul_glowstone.json'

    debug.verbose = true
    debug.export = true
    dumpTargetOnFailure = true

    quiet
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8' // Use the UTF-8 charset for Java compilation
}

apply from: 'mcreator.gradle'

[Spectrall368]

Your error is caused by this plugin: https://mcreator.net/plugin/104607/forge-mixins-support

[Spectrall368]

Try deleting the one written in the build.gradle file and pasting this

Tell me later if it goes

[JeanWorldTour2]

thanks it worked and i will try to make the plugin compactible