“Deprecation” message: <content> gets 1 and only 1 child

[sydb]

Here is what I did:

• Created Schematron constraint, as a separate file for easy testing
• Ran it on all .xml, .tei, .odd, and .plodd files in the ATOP repository (there are a lot of ODD files there to be used as tests)
• Found that it seemed to work perfectly — it found lots of cases of 2+ children of <content> that were either all TEI elements or all RELAX NG elements; also found 2 cases in which there was a mix. I spot-checked 2–3 of each of the former cases and the 2 mixes, too.
• Moved the Schematron into P5/Sourece/Specs/content.xml in <constraintSpec ident="only_1_child_of_content">.
• That constraint needs the RELAX NG annotation namespace to be declared, so added an <sch:ns> to TEI.xml (in "c2"), binding the namespace to the prefix “rna:”.
• Built the Guidelines with make clean validate html-web test exemplars in the Docker environment.
• Found 1 failure — 2 examples in USE had 2+ children of <content>.
• Fixed those errors. (Also tweaked some whitespace in sp.xml while I was at it.)
• Built again, no errors.

Here is what the warning messages look like (whitespace altered for readability) …

2+ TEI children:

In the near future the <content> element will be limited to 1 and
only 1 child element. This <content> element is in an elementSpec
with an @ident of "constraintSpec" and has 2 children, which
could be wrapped in a <sequence> element.

2+ RELAX NG children:

In the near future the <content> element will be limited to 1 and
only 1 child element. This <content> element is in a moduleRef
with a @url of "http://www.w3.org/Math/RelaxNG/mathml3/mathml3.rng"
and has 2 children, which could be wrapped in an <rng:div> element.

2+ children, not all TEI, not all RELAX NG:

In the near future the <content> element will be limited to 1 and
only 1 child element. This <content> element is in an elementSpec
with an @ident of "publicationStmt" and has 3 children, but those
children are neither all TEI elements nor all RELAX NG elements,
and thus this <content> is invalid and can not be easily rectified.

What I did not do was use role="warning" on the <sch:assert> and <sch:report> elements. I probably should have, and may well fix that and commit shortly.

[sydb]

More:

• Added role="warning"
• Improved XSLT to fix — added error checking so it only works iff all children are either TEI or RELAX NG (see below)
• Ran that XSLT on all the files I used for testing, above, expecting error msgs for the mixed two, and got them
  • Note: I flattened the hierarchy, so due to name collisions only 413 of the 644 files actually used
• Spot-checked 4 of the output files, they seemed correct
• Validated all those fixed files with the Schematron — I should only get errors where the content of <content> was mixed, and that’s what I got

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns="http://www.tei-c.org/ns/1.0"
  xmlns:tei="http://www.tei-c.org/ns/1.0"
  xmlns:rng="http://relaxng.org/ns/structure/1.0"
  xmlns:rna="http://relaxng.org/ns/compatibility/annotations/1.0"
  xpath-default-namespace="http://www.tei-c.org/ns/1.0"
  exclude-result-prefixes="#all"
  version="3.0">

  <xsl:output method="xml" indent="yes"/>
  <xsl:mode on-no-match="shallow-copy"/>

  <xsl:template match="content[ *[2] ]" as="element(content)">
    <xsl:variable name="wrapperGI">
      <xsl:choose>
        <xsl:when test="tei:* and not( rng:* | rna:* )">sequence</xsl:when>
        <xsl:when test="( rng:* | rna:* ) and not( tei:* )">rng:div</xsl:when>
        <xsl:otherwise>
          <xsl:sequence select="'HUMAN_FIX_THIS'"/>
          <xsl:message>ERROR: content element with children that are neither all TEI nor all RELAX NG; contents will be wrapped in an invalid &lt;HUMAN_FIX_THIS> element.</xsl:message>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:variable>
    <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:element name="{$wrapperGI}">
        <xsl:apply-templates select="node()"/>
      </xsl:element>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>