Provide a PKGBUILD file for Arch Linux?

[blueyed]

I just came up with the following PKGBUILD file, and thought that it might be useful to have in the repo?!

pkgname=libfprint-anarsoul-git
pkgver=0.6.0r297.79d5a3e
pkgrel=1
pkgdesc="Library for fingerprint readers (anarsoul repo)"
arch=(i686 x86_64)
url="http://www.freedesktop.org/wiki/Software/fprint/libfprint"
license=(LGPL)
depends=(libusb nss pixman)
groups=(fprint)
options=(!emptydirs)
# source=(http://people.freedesktop.org/~hadess/$pkgname-$pkgver.tar.xz)
source=("${pkgname}::git+https://github.com/anarsoul/libfprint.git")
sha256sums=('SKIP')
provides=(libfprint)
conflicts=(libfprint)

pkgver() {
  cd "$pkgname"
  printf "0.6.0r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd "${pkgname}"
  ./autogen.sh
  ./configure --prefix=/usr --sysconfdir=/etc --disable-static --enable-debug-log
  make
}

package() {
  cd "${pkgname}"
  make DESTDIR="$pkgdir" install
}

Reference: https://wiki.archlinux.org/index.php/PKGBUILD

[anarsoul]

Nope, I don't think that there's a need for distro-specific stuff in libfprint repo at the moment (I'm using similar PKGBUILD btw :))

[blueyed]

I'm using similar PKGBUILD btw :)

Do you want to put it on AUR?

I don't know what the state of this fork is - just came here, because the official one did not work for me.

[anarsoul]

I'm using this repo as a staging area before merging changes into "official" git repo. So next release of libfprint should work fine on your laptop.

[blueyed]

Awesome, thanks!