INCLUDEPATH issue with QTCreator Clang Code Model: errors in editor, compilation is fine

[jim-bcom]

HOW TO REPRODUCE Open a SolAR project, for example this one (the following examples are not from this project).

EXPECTED BEHAVIOR

• compiles without error
• 0 issues in editor

OBSERVED BEHAVIOR

• compiles without error
• there are errors in the code editor. As opposed to "real" errors happening at compilation time as well which are noted with red dots, these editor only errors are noted with red circles.

This makes QtCreator barely usable as we lose all completion and code navigation for our project dependencies.

SOME LEADS INCLUDEPATH is built in packagedependencies-parser.pri.

for (var, LIST_CFLAGVAR) {
    first2char = $$str_member($$eval($${var}), 0, 1)
    equals (first2char, "-I") {
        #manage path with space
        # TODO check with a real path with space
        INCLUDEPATH += $$shell_quote($$replace($$eval(var), -I,))
    } else {
        QMAKE_CXXFLAGS += $$eval($${var})
    }
}

I've tried several things. For example, with a missing reference to xpcf library:

• add hard coded path INCLUDEPATH += /home/user/.remaken/packages/linux-gcc/xpcf/2.5.0/interfaces before and after the loop: it works, errors are gone
• add same line within the loop: errors remain
• put the same content $$shell_quote($$replace($$eval(var), -I,)) in a variable FOO and assign FOO to INCLUDEPATH after the loop: does not work
• print FOO on the console, cut'n paste the output and assign it to INCLUDEPATH before or after the loop: errors are gone.

I thought that some kind of special character might have been inserted by the loop in the list, so I've checked that every entry of that list is an existing file

for (incFile, INCLUDEPATH) {
    exists($${incFile}) {
        message("include file $${incFile} exists")
    }
}

All files do exist, all right:

Project MESSAGE: include file /home/user/.remaken/packages/linux-gcc/SolARBuild/SolARFramework/0.10.0/interfaces exists
Project MESSAGE: include file /home/user/.remaken/packages/linux-gcc/thirdParties/spdlog/0.14.0/interfaces exists
Project MESSAGE: include file /home/user/.remaken/packages/linux-gcc/xpcf/2.5.0/interfaces exists
Project MESSAGE: include file /home/user/.remaken/packages/linux-gcc/grpc/1.37.1/interfaces exists

So I tried to include those path to INCLUDEPATH:

for (incFile, INCLUDEPATH) {
    exists($${incFile}) {
        message("include file $${incFile} exists")
        INCLUDEPATH += $${incFile}
    }
}

Does not work.

I've tried to add the hard-coded path in the loop

for (incFile, INCLUDEPATH) {
    exists($${incFile}) {
        message("include file $${incFile} exists")
        INCLUDEPATH += /home/user/.remaken/packages/linux-gcc/xpcf/2.5.0/interfaces
    }
}

Does not work.

But if I add a hard-coded path after the loop, it works:

for (incFile, INCLUDEPATH) {
    exists($${incFile}) {
        message("include file $${incFile} exists")
        INCLUDEPATH += /home/user/.remaken/packages/linux-gcc/xpcf/2.5.0/interfaces
    }
}
INCLUDEPATH += /home/user/.remaken/packages/linux-gcc/xpcf/2.5.0/interfaces

It seems to behave as if the the concatenation in a for loop does not work.

CONFIGURATION OS: Windows 10 / gnu-Linux-Ubuntu 18.04 QtCreator 4.14.0 Qt: 5.15.2 MSVC 2019

QtCreator is an old version. I keep it to avoid regression issues I already encountered by upgrading. But this might be fixed in latest releases, I haven't tested it.

[stefled]

bug reproduced with :

• Windows 10
• Qt Creator 10.0.2 (currently last version)
• Qt 5.14.2
• MSVC 2017
• SolarFramework and SolarModuleTools
• builddefs/qmake 4.9.5

The next release of builddefs-qmake 4.10.0 apparently no longer has this problem.

Management of INCLUDEPATH/QMAKE_CXXFLAGS has changed in packagedependencies-parser.pri. Generic separation of INCLUDE_PATH and QMAKE_CXXFLAGS has bee replaced by new pkgconfig commands for getting only concerned parameters :

PKGCFG_INCLUDE_PATH = $$system(pkg-config --cflags-only-I $$pkgCfgVars $$pkgCfgFilePath)
# disable external/system warnings
contains(DEPENDENCIESCONFIG,externaldeps)|contains(CONFIG,externaldeps)|contains(REMAKENCONFIG,externaldeps) {
  win32{
    QMAKE_CXXFLAGS += $$replace(PKGCFG_INCLUDE_PATH, -I," /external:I ")
  } else {
    QMAKE_CXXFLAGS += $$replace(PKGCFG_INCLUDE_PATH, -I, -isystem)
  }
} else {
  INCLUDEPATH += $$replace(PKGCFG_INCLUDE_PATH, -I, "")
}
QMAKE_CXXFLAGS += $$system(pkg-config --cflags-only-other $$pkgCfgVars $$pkgCfgFilePath)

NB : this code also handles removing warnings from external libraries with externaldeps config flag

I advise to delete the build folder so that the project is reindexed entirely with clang.

fix will be available in builddefs/qmake 4.10.0

[stefled]

available in release 4.10.0

[stefled]

external Deps is incompatible with removing clangd errors when indexing on Windows Ok on Linux

tested with SolarFramework branch develop