Select with empty else block hangs all fibers, and compiler does not give error

[DougEverly]

The empty else block will hang all fibers and will not give a compile error.

    select
    when x = chan.receive
      puts x
    else
    end

An empty when block works as expected.

Example:

% crystal --version
Crystal 1.4.1 (2022-04-22)

LLVM: 13.0.1
Default target: aarch64-apple-darwin21.5.0

Works as expected:

chan = Channel(Bool).new
chan1 = Channel(Bool).new

# extra fiber to demonstrate hang across fibers
spawn do
  loop do
    puts "hey"
    sleep 1
  end
end

spawn do
  loop do
    select
    when x = chan1.receive
      # no code here, but ok
    when x = chan.receive
      puts x
    end
  end
end

loop do
  chan.send(true)
  sleep 1
end

Unexpectedly hangs all fibers, and without compiler error:

chan = Channel(Bool).new
chan1 = Channel(Bool).new

# extra fiber to demonstrate hang across fibers
spawn do
  loop do
    puts "hey"
    sleep 1
  end
end

spawn do
  loop do
    select
    when x = chan1.receive
      # no code here, but ok
    when x = chan.receive
      puts x
    else
      # no code here, but hangs
    end
  end
end

loop do
  chan.send(true)
  sleep 1
end

[Blacksmoke16]

I think what's going on is that it's not the fact that it's empty causing it to hang, but more so there is no blocking operation that allows it to switch to another fiber. For example, in your working flow:

• the two fibers are spawned
• execution hits the loop do a part of the main fiber, send chan a value, and sleep 1 causes execution to switch to first spawned fiber
• first spawned fiber prints hey
  • sleep 1 causes execution to switch to second spawned fiber
• second spawned fiber hits the select, receives the sent value and prints true, skipping chan1 since there is no value waiting
  • Upon the second iteration of the loop do, there is no value waiting again on either channel, so the select blocks, causing execution to switch back to the main fiber
• The main fiber sends another value, which prints hey again, which repeats all this ad infinitum

Once you introduce the else block, the second iteration won't block execution, thus never allowing the main fiber to run which essentially traps the program in the infinite loop of the second spawned fiber.

In short, I'm fairly certain this is working by design.

EDIT: You can prove this by adding sleep 0 causes it to work, but something like puts "else" does not, but does make it more clear what's going on.

[straight-shoota]

In short, I'm fairly certain this is working by design.

Yes, I agree. Your else branch short circuits the fiber in a tight loop. There is no escape 🧟

We're missing documentation on select (https://github.com/crystal-lang/crystal-book/issues/208). There this could be mentioned as a possible trap.