Neharvestuje sa položka dct:description katalógu - príprava query

[miroslavliska]

V SPARQL Construct DPU chýba položka dct:description. Opravený dotaz je nižšie.

[miroslavliska]

PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX vcard: <http://www.w3.org/2006/vcard/ns#>

CONSTRUCT {
  ?catalog a dcat:Catalog, ?type ;
    dcat:endpointURL ?catalog_endpoint ;
    dcterms:title ?title ;
    dcterms:description ?description ;
    dcat:contactPoint ?cp ;
    foaf:homepage ?homepage ;
    dcterms:publisher ?publisher .

  ?cp a ?cptype ;
    vcard:fn ?cpfn ;
    vcard:hasEmail ?cpemail .
}
WHERE {
  ?catalog a dcat:Catalog, ?type ;
    dcat:endpointURL ?catalog_endpoint ;
    dcterms:title ?title ;
    dcterms:description ?description ;
    dcterms:publisher ?publisher ;
    dcat:contactPoint ?cp .
  ?cp a ?cptype ;
    vcard:fn ?cpfn ;
    vcard:hasEmail ?cpemail .
  OPTIONAL { ?catalog foaf:homepage ?homepage . }
  FILTER ( ?type != dcat:Catalog)
}