Парсиваль. Редкий диалог

[Kor-Angar]

Играл за мага и совершенно случайно в игре узнал про такую фичу :-)

instance DIA_Parcival_BRAVE(C_Info)
{
    npc = PAL_252_Parcival;
    nr = 8;
    condition = DIA_Parcival_BRAVE_Condition;
    information = DIA_Parcival_BRAVE_Info;
    important = TRUE;
    permanent = TRUE;
};

func int DIA_Parcival_BRAVE_Condition()
{
    if(Npc_IsInState(self,ZS_Talk) && Npc_KnowsInfo(hero,DIA_Parcival_DRAGONS) && (Kapitel < 3) && (Parcival_BRAVE_LaberCount <= 6))
    {
        return TRUE;
    };
};

var int Parcival_BRAVE_LaberCount;

func void DIA_Parcival_BRAVE_Info()
{
    var int randy;
    if(Parcival_BRAVE_LaberCount < 6)
    {
        randy = Hlp_Random(3);
        if(randy == 0)
        {
            AI_Output(self,other,"DIA_Parcival_BRAVE_13_00");   //Пока все спокойно. Но все может быстро перемениться.
        };
        if(randy == 1)
        {
            AI_Output(self,other,"DIA_Parcival_BRAVE_13_01");   //Мы будем держаться, сколько сможем.
        };
        if(randy == 2)
        {
            AI_Output(self,other,"DIA_Parcival_BRAVE_13_02");   //Иннос поможет нам. Его свет озаряет наши сердца!
        };
    }
    else
    {
        AI_Output(self,other,"DIA_Parcival_BRAVE_13_03");   //Эй! Тебе что, нечего больше делать, как болтать со мной? Проваливай!
        B_GivePlayerXP(XP_AmbientKap2);
    };
    Parcival_BRAVE_LaberCount += 1;
};

не разу про неё не слышал и не видел. а в следующей главе отсылка есть :-)

instance DIA_Parcival_ALLESKLAR(C_Info)
{
    npc = PAL_252_Parcival;
    nr = 31;
    condition = DIA_Parcival_ALLESKLAR_Condition;
    information = DIA_Parcival_ALLESKLAR_Info;
    permanent = TRUE;
    description = "Все в порядке?";
};

func int DIA_Parcival_ALLESKLAR_Condition()
{
    if((Kapitel == 3) && (DIA_Parcival_ALLESKLAR_NervCounter < 3) && Npc_KnowsInfo(other,DIA_Parcival_DRAGON))
    {
        return TRUE;
    };
};

var int DIA_Parcival_ALLESKLAR_NervCounter;

func void DIA_Parcival_ALLESKLAR_Info()
{
    AI_Output(other,self,"DIA_Parcival_ALLESKLAR_15_00");   //Все в порядке?
    if(DIA_Parcival_ALLESKLAR_NervCounter == 0)
    {
        AI_Output(self,other,"DIA_Parcival_ALLESKLAR_13_01");   //Пока да!
    }
    else if(DIA_Parcival_ALLESKLAR_NervCounter == 1)
    {
        AI_Output(self,other,"DIA_Parcival_ALLESKLAR_13_02");   //Да, черт тебя побери.
    }
    else if(Parcival_BRAVE_LaberCount > 6)
    {
        AI_Output(self,other,"DIA_Parcival_ALLESKLAR_13_03");   //(смеется) Ах. Теперь я понимаю, что ты задумал. Нет, дружок. Не на этот раз.
    }
    else
    {
        AI_Output(self,other,"DIA_Parcival_ALLESKLAR_13_04");   //Не отвлекай меня.
    };
    DIA_Parcival_ALLESKLAR_NervCounter += 1;
};

[dosinabox]

Похожая редкая штука:

instance DIA_Addon_BL_BDT_13_Gold(C_Info)
{
    nr = 5;
    condition = DIA_Addon_BL_BDT_13_Gold_Condition;
    information = DIA_Addon_BL_BDT_13_Gold_Info;
    permanent = TRUE;
    description = "Как мне достать много золота и побыстрее?";
};

func int DIA_Addon_BL_BDT_13_Gold_Condition()
{
    if((MIS_Send_Buddler != LOG_Running) && (MIS_Send_Buddler != LOG_SUCCESS))
    {
        return TRUE;
    };
};

func void DIA_Addon_BL_BDT_13_Gold_Info()
{
    BDT_13_Nerver += 1;
    AI_Output(other,self,"DIA_Addon_BL_BDT_13_Gold_15_00"); //Как мне достать много золота и побыстрее?
    if(BDT_13_Nerver <= 2)
    {
        AI_Output(self,other,"DIA_Addon_BL_BDT_13_Gold_13_01"); //Хороший вопрос. Разве мы все не за этим здесь?
        AI_Output(self,other,"DIA_Addon_BL_BDT_13_Gold_13_02"); //Тебе нужно взять у Торуса красный камень, тогда ты сможешь войти в шахту.
    }
    else if(BDT_13_Kill == FALSE)
    {
        BDT_13_Nerver = 0;
        BDT_13_Kill = TRUE;
        AI_Output(self,other,"DIA_Addon_BL_BDT_13_Gold_13_03"); //Эй, что ты вертишься вокруг меня? Пошел вон!
        AI_StopProcessInfos(self);
    }
    else
    {
        BDT_13_Nerver = 0;
        AI_Output(self,other,"DIA_Addon_BL_BDT_13_Gold_13_04"); //Кончились игры и веселье!
        AI_StopProcessInfos(self);
        B_Attack(self,other,AR_NONE,1);
    };
};

[Kor-Angar]

крутая штука. за такие диалоги надо в дневник записывать подарочные ключи на Готику из Стима :-)