Improved PKGBUILD

[yochananmarqos]

The prefix in the Makefile should be /usr, not /usr/local. I wasn't able to use make install as it lacks a DESTDIR variable.

pkgname=yup-git
pkgver=v0.1.8.beta.r0.g2899650
pkgrel=1
pkgdesc="Ncurses based AUR Helper with improved searching and sorting"
arch=('any')
url="https://github.com/ericm/yup"
license=('GPL3')
depends=('pacman>=5.1' 'git' 'ncurses' 'sudo')
makedepends=('go')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/ericm/yup.git')
sha256sums=('SKIP')

pkgver() {
    cd "$srcdir/${pkgname%-git}"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "$srcdir/${pkgname%-git}"
    make prefix=/usr
}

package() {
    cd "$srcdir/${pkgname%-git}"
    install -Dm755 "${pkgname%-git}" "$pkgdir/usr/bin/${pkgname%-git}"
    install -Dm755 completions/zsh \
        "$pkgdir/usr/share/zsh/site-functions/completions/_${pkgname%-git}"
}

[Atemu]

I pushed a slightly modified version of your PKGBUILD for the -git package, thanks!

Though you should probably report AUR related issues in the AUR instead in the future.