WiFiClientSecure doesn't connect to HTTPS sites when a static IP is set

[andresrcs]

Basic Infos

• [x] This issue complies with the issue POLICY doc.
• [x] I have read the documentation at readthedocs and the issue is not addressed there.
• [x] I have tested that the issue is present in current master branch (aka latest git).
• [x] I have searched the issue tracker for a similar issue.
• [x] If there is a stack dump, I have decoded it.
• [x] I have filled out all fields below.

Platform

• Hardware: Lolin D1 mini Pro
• Core Version: 2.6.3
• Development Env: Arduino IDE
• Operating System: Windows

Settings in IDE

• Module: Lolin (Wemos) D1 mini Pro
• Flash Size: 16MB
• lwip Variant: v2 Lower Memory
• CPU Frequency: 80Mhz
• Upload Using: SERIAL
• Upload Speed: 115200

Problem Description

I have a problem with WiFiClientSecure it can't make a connection to HTTPS sites when a static IP is set withWiFi.config(IP, gateway, subnet); but if I let the DHCP server to assign the IP it works as expected.

MCVE Sketch

#include <ESP8266WiFi.h>
#include <WiFiClientSecure.h>

// Network Configurations
#define WLAN_SSID     "YOUR_WIRELESS_SSID"
#define WLAN_PASSWORD "YOUR_PASSWORD"

//Connection to HTTPS sites doesn't work with static IP
IPAddress ip(192,168,0,102);
IPAddress gateway(192,168,0,1);
IPAddress subnet(255,255,255,0);

void setup() {
  Serial.begin(115200);
  delay(10);

  // Connect to WiFi network
  Serial.println(); Serial.println();
  Serial.print("Connecting to ");
  Serial.println(WLAN_SSID);

  WiFi.config(ip, gateway, subnet);
  WiFi.mode(WIFI_STA);
  WiFi.begin(WLAN_SSID, WLAN_PASSWORD);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println();
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

  // connect to HTTPS site
  WiFiClientSecure client;
  client.setInsecure();
  if (client.connect("maker.ifttt.com", 443))
  {
    Serial.println("Connected To Maker");
  }
  else Serial.println("Failed To Connect To Maker!");
}

void loop() {
}

[earlephilhower]

You haven't set a DNS server. Add dns1 and dns2 params (can be the same) to WiFi.config and it runs fine.

WiFi.config(ip, gateway, subnet, gateway, gateway); , for example