Dependencies

[gllmhyt]

I'm the one who's maintaining the PKGBUILD for Arch Linux of Parlatype (AUR) and the Parlatype LibreOffice Extension (AUR), and I had some questions about the dependencies of the two.

Can you please check them? depends=() are packages that must be installed for the software to build and run ; makedepends=() the packages that are only required to build the software ; and optdepends=() are packages that are not needed for the software to function, but provide additional features.

Parlatype (PKGBUILD)

depends=('gtk3' 'gst-plugins-good' 'sphinxbase' 'pocketsphinx' 'python-atspi')
makedepends=('appstream' 'appstream-glib' 'meson' 'gettext' 'gobject-introspection' 'yelp-tools' 'desktop-file-utils')
optdepends=('parlatype-libreoffice-extension: LibreOffice macros' 'gst-plugins-ugly: Play MP3 files')

Parlatype LibreOffice Extension (PKGBUILD)

depends=('libreoffice' 'parlatype=2.0')
makedepends=('meson' 'gettext' 'appstream' 'appstream-glib')

Thank you.

[gkarsay]

I hope this helps, if you have build failures or other questions, please ask again :)

Parlatype

I'm not really satisfied with the status of automatic speech recognition (ASR) in current Parlatype and recommend to turn it off for now. I hope to improve it in the near future. You can turn it off at build time and you did so for your package with -Dasr=false. In this case you can skip these packages: sphinxbase, pocketsphinx, python-atspi (not sure if you really need the last one anyway).

• depends: I'm missing gstreamer itself (but it's pulled in by gst-plugins-good or maybe by gtk3) and gst-plugins-base (maybe pulled in by gstreamer)

• makedepends: looks good

• optdepends: you can skip gst-plugins-ugly, mp3 is now supported in gst-plugins-good

LibreOffice extension

Looks good. I understand that Arch Linux has a LibreOffice package with everything included (on Debian and Fedora scripting support is in separate packages). I guess that a python interpreter is also included in the LibreOffice package; if not, you need additionally python.

Next release

I plan to release version 2.1 in 2 or 3 weeks. Dependencies will stay the same.

[gllmhyt]

Thanks for the hints! Here's what I made then: added the gstreamer bits in the dependencies, no matter if one is pulled by another, disabled automatic speech recognition and removed sphinx.

pkgname=parlatype
pkgver=2.0
pkgrel=4
pkgdesc="GNOME audio player for transcription"
arch=('any')
url="https://github.com/gkarsay/parlatype"
license=('GPL3')
depends=('gtk3' 'gstreamer' 'gst-plugins-base' 'gst-plugins-good')
makedepends=('appstream' 'appstream-glib' 'meson' 'gettext' 'gobject-introspection' 'yelp-tools' 'desktop-file-utils')
optdepends=('parlatype-libreoffice-extension: LibreOffice macros')
source=("https://github.com/gkarsay/$pkgname/releases/download/v$pkgver/$pkgname-$pkgver.tar.gz")
sha256sums=('f9833d244f8744f7a9983d680005462d02d062c2538423cb443279da2cc5e2d1')

build() {
    cd "$pkgname-$pkgver"
    meson build --prefix=/usr -Dasr=false -Dgir=true
    cd build
    ninja
}

package() {
    cd "$pkgname-$pkgver"/build
    DESTDIR="$pkgdir/" ninja install
}

As for the python interpreter in LibreOffice, it is indeed provided by either libreoffice-still or libreoffice-fresh with the file /usr/lib/libreoffice/program/uno.py as I understend correctly. Therefore, I didn't change the following PKGBUILD.

pkgname=parlatype-libreoffice-extension
pkgver=2.0
pkgrel=3
pkgdesc="Parlatype LibreOffice Extension"
arch=('any')
url="https://github.com/gkarsay/parlatype-libreoffice-extension"
license=('GPL3')
depends=('libreoffice' 'parlatype=2.0')
makedepends=('meson' 'gettext' 'appstream' 'appstream-glib')
source=("https://github.com/gkarsay/$pkgname/releases/download/v$pkgver/$pkgname-$pkgver.tar.gz")
sha256sums=('a91944b9c307e92a16b87475160c9496179f7bce036621988d3ec3fb81ce3d9a')

build() {
    cd "$pkgname-$pkgver"
    meson build --prefix=/usr -Dbundled=true
    cd build
    ninja
}

package() {
    cd "$pkgname-$pkgver"/build
    DESTDIR="$pkgdir/" ninja install
}

[gkarsay]

Looks good to me :+1: