agraef
commented
6 years ago Here's the code of the mysub.dsp program for easier reading:
declare name "mysub";
declare description "saw wave filtered with resonant lowpass";
declare author "Albert Graef";
declare version "1.0";
declare nvoices "16";
import("stdfaust.lib");
// control variables
// master volume and pan
vol = hslider("vol", 0.3, 0, 10, 0.01); // %
pan = hslider("pan", 0.5, 0, 1, 0.01); // %
// ADSR envelop
attack = hslider("attack", 0.01, 0, 1, 0.001); // sec
decay = hslider("decay", 0.3, 0, 1, 0.001); // sec
sustain = hslider("sustain", 0.5, 0, 1, 0.01); // %
release = hslider("release", 0.2, 0, 1, 0.001); // sec
// filter parameters
res = hslider("resonance (dB)", 3, 0, 20, 0.1);
cutoff = hslider("cutoff (harmonic)", 6, 1, 20, 0.1);
// voice parameters
freq = nentry("freq", 440, 20, 20000, 1); // Hz
gain = nentry("gain", 1, 0, 10, 0.01); // %
gate = button("gate"); // 0/1
// resonant lowpass
// This is a tweaked Butterworth filter by David Werner and Patrice Tarrabia,
// see http://www.musicdsp.org and http://www.experimentalscene.com for
// details.
// res = resonance in dB above DC gain
// freq = cutoff frequency
lowpass(res,freq) = f : (+ ~ g) : *(a)
with {
f(x) = a0*x+a1*x'+a2*x'';
g(y) = 0-b1*y-b2*y';
a = 1/ba.db2linear(0.5*res);
c = 1.0/tan(ma.PI*(freq/ma.SR));
c2 = c*c;
r = 1/ba.db2linear(2.0*res);
q = sqrt(2.0)*r;
a0 = 1.0/(1.0+(q*c)+(c2));
a1 = 2.0*a0;
a2 = a0;
b1 = 2.0*a0*(1.0-c2);
b2 = a0*(1.0-q*c+c2);
};
// AG: Try this as a drop-in replacement for en.adsr, it sounds different!!
adsr(a,d,s,r,t) = env ~ (_,_) : (!,_) // the 2 'state' signals are fed back
with {
env (p2,y) =
(t>0) & (p2|(y>=1)), // p2 = decay-sustain phase
(y + p1*u - (p2&(y>s))*v*y - p3*w*y) // y = envelop signal
*((p3==0)|(y>=eps)) // cut off tails to prevent denormals
with {
p1 = (p2==0) & (t>0) & (y<1); // p1 = attack phase
p3 = (t<=0) & (y>0); // p3 = release phase
// #samples in attack, decay, release, must be >0
na = ma.SR*a+(a==0.0); nd = ma.SR*d+(d==0.0); nr = ma.SR*r+(r==0.0);
// correct zero sustain level
z = s+(s==0.0)*ba.db2linear(-60);
// attack, decay and (-60dB) release rates
u = 1/na; v = 1-pow(z, 1/nd); w = 1-1/pow(z*ba.db2linear(60), 1/nr);
// values below this threshold are considered zero in the release phase
eps = ba.db2linear(-120);
};
};
// subtractive synth (saw wave passed through resonant lowpass)
process = os.sawtooth(freq) : ((env,freq,_) : filter) : *(env * gain)
: (*(vol:dezipper(0.99)) : sp.panner(pan:dezipper(0.99)))
with {
env = gate : en.adsr(attack, decay, sustain, release);
filter(env,freq) = lowpass(env*res, ma.fmax(1/cutoff, env)*freq*cutoff);
dezipper(c) = *(1-c) : +~*(c);
};
josmithiii
rmichon
sletz
Hi @rmichon, I'm currently experimenting with (finally) getting some of my Faust examples ported to the new library. Hey, better late than never! :)
However, one issue I've been running into is that your implementations of
en.adsranden.adsredon't work for me. They just seem to trigger release immediately after the decay phase, not after thegatesignal drops to zero. If I drop in Yann's originaladsrimplementation from music.lib, the synth works just fine.I've attached one of my programs, a little subtractive synth, exhibiting this misbehavior. The Pd patch is also included so that you can run this using pd-faust if you've got that installed (run
makebeforehand), but of course you can also run the mysub.dsp program in FaustLive as a polyphonic synth instead.mysub.zip
To reproduce the bug, just hook up a MIDI keyboard, play a note and hold it. It dies out immediately, but I'd expect it to be sustained until the key is released. Modify the mysub.dsp program by changing
en.adsrto justadsr, recompile and run the same test again, now the note is sustained until you release the key.