[Enhancement]: aws_codepipeline V2 does not support referencing pipeline level variable into stage

[SleepingTalent]

Description

Hi,

I'm trying out the V2 flavour of codepipeline that was released as part of the AWS 5.41.0 provider.

I cant seem to find a way to reference my variable defined at the codepipline level into the any of the stage actions.

I assumed I could reference the pipeline variable using #{codepipeline.ROLE_NAME}

Affected Resource(s) and/or Data Source(s)

No response

Potential Terraform Configuration

resource "aws_codepipeline" "code_pipeline" {
  name     = var.pipeline_name
  pipeline_type = var.pipeline_type
  role_arn = aws_iam_role.code_pipeline_service_role.arn
  variable {
    name = "ROLE_NAME"
  }
  artifact_store {
    location = aws_s3_bucket.code_pipeline_artifacts_bucket.bucket
    type     = "S3"
  }
  stage {
    name = "Source"
    action {
      category         = "Source"
      name             = "SourceAction"
      owner            = "AWS"
      provider         = "CodeCommit"
      version          = "1"
      output_artifacts = ["SourceArtifact"]

      configuration = {
        PollForSourceChanges = false
        RepositoryName = var.source_repository
        BranchName     = var.source_repository_branch
      }
    }
  }

  stage {
    name = "CESharedServices"
    action {
      category        = "Build"
      name            = "GeneratePlan"
      owner           = "AWS"
      provider        = "CodeBuild"
      input_artifacts = ["SourceArtifact"]
      version         = "1"
      run_order       = 1
      role_arn        = module.ce_shared_services_plan.codebuild_role_arn

      configuration = {
        ProjectName = module.ce_shared_services_plan.codebuild_name
        EnvironmentVariables = jsonencode([
          {
            name  = "ROLE_NAME"
            value = "#{codepipeline.ROLE_NAME}"
            type  = "PLAINTEXT"
          }
        ])
      }
    }
    action {
      name      = "ApproveDeployment"
      category  = "Approval"
      owner     = "AWS"
      provider  = "Manual"
      version   = "1"
      run_order = 2
    }
    action {
      category        = "Build"
      name            = "Deploy"
      owner           = "AWS"
      provider        = "CodeBuild"
      input_artifacts = ["SourceArtifact"]
      version         = "1"
      run_order       = 3
      role_arn        = module.ce_shared_services_apply.codebuild_role_arn

      configuration = {
        ProjectName = module.ce_shared_services_apply.codebuild_name
        EnvironmentVariables = jsonencode([
          {
            name  = "ROLE_NAME"
            value = "#{codepipeline.ROLE_NAME}"
            type  = "PLAINTEXT"
          }
        ])
      }
    }
  }
}

References

https://registry.terraform.io/providers/hashicorp/aws/latest/docs/resources/codepipeline

Would you like to implement a fix?

None

[github-actions[bot]]

Community Note

Voting for Prioritization

• Please vote on this issue by adding a 👍 reaction to the original post to help the community and maintainers prioritize this request.
• Please see our prioritization guide for information on how we prioritize.
• Please do not leave "+1" or other comments that do not add relevant new information or questions, they generate extra noise for issue followers and do not help prioritize the request.

Volunteering to Work on This Issue

• If you are interested in working on this issue, please leave a comment.
• If this would be your first contribution, please review the contribution guide.

[sgreathouse-rgare]

@SleepingTalent I got this to work. You are calling the reserved codepipeline namespace instead of the shared variables namespace.
value = "#{codepipeline.ROLE_NAME}" should be value = "#{variables.ROLE_NAME}"