AlanSimmons
commented
1 year ago The endpoint requires one parameterized, correlated subquery in Cypher
Following is an example that returns codes for child concepts of HUBMAP C000402 from the ordered list of SABs ['HUSAT','SNOMEDCT_US'].
//Correlated subquery:
//Reference: neo4j Operations manual/Managing Databases/Composite Databases/Querying - Example 7 (Correlated subqueries)
//1. Find the child concepts with an isa relationship with the parent HUBMAP concept (identified by code).
//2. Order the child concepts based on the positions of the SABs for their codes in a list (as opposed to an alphabetic order).
//3. Identify the code from the SAB that is the earliest in the list. For example, if codes from SNOMEDCT_US are preferred to those from NCI, the list would include [...,'SNOMEDCT_US','NCI',...].
CALL
{
MATCH (codeChild:Code)<-[:CODE]-(conceptChild:Concept)-[:isa]->(conceptParent:Concept)-[:CODE]->(codeParent:Code)
WHERE codeParent.SAB='HUBMAP' AND codeParent.CODE='C000530' AND codeChild.SAB IN ['HUSAT','SNOMEDCT_US']
RETURN conceptChild.CUI AS conceptChildCUI, min(CASE codeChild.SAB WHEN 'HUSAT' THEN 1 WHEN 'SNOMEDCT_US' THEN 2 END) as minSAB
ORDER BY conceptChildCUI
}
//4. Filter to the code for the child concepts with the "earliest" SAB. The "earliest" SAB will be different for each child concept. Limit to 1 to account for multiple cross-references (e.g., UMLS C0026018, which maps to 2 NCI codes)
CALL
{
WITH conceptChildCUI,minSAB
MATCH (codeChild:Code)<-[:CODE]-(conceptChild:Concept)
WHERE conceptChild.CUI = conceptChildCUI
AND CASE codeChild.SAB WHEN 'HUSAT' THEN 1 WHEN 'SNOMEDCT_US' THEN 2 END= minSAB
RETURN codeChild
ORDER BY codeChild.CODE
LIMIT 1
}
//5. Get the term associated with the child concept code with the earliest SAB
WITH codeChild
MATCH (termChild:Term)<-[:PT]-(codeChild:Code)
RETURN termChild.name, codeChild.CODE,codeChild.SAB
yuanzhou
Issue
CEDAR metadata templates contain questions with categorical responses. The available responses are identified with concepts from standard biomedical ontologies such as UO and UBERON. Membership in the subset of concepts used as responses for a particular question is determined by business logic: i.e., while all units of measure concepts from UO are potential members of the set of concepts for responses to a question, only a few are actually available.
We describe as a valueset the set of concepts associated with concepts that encode responses to a particular categorical question.
CEDAR valuesets are either defined manually (e.g., by explicit declaration) or from the response to an API endpoint. CEDAR currently interacts with a REST API provided by NCBO BioPortal.
Solution
We need to provide similar functionality for HuBMAP.
The HuBMAP application ontology cross-references concepts in standard biomedical ontologies. By means of bi-directional ontological assertions, it is possible to define a set of concepts in other ontologies that share a relationship to a HuBMAP concept. The relationship can be hierarchical (e.g., all concepts with an _inverseis relationship with the HuBMAP concept) or non-hierarchical (e.g., all concepts that have a _derivesfrom relationship with a HuBMAP concept).
When a HuBMAP concept cross-references a UMLS CUI, concepts from multiple standard biomedical ontologies are possible. For example, HUBMAP C000411 (methanol) maps to UMLS:C0001963, which corresponds to concepts in a number of other ontologies. It will be necessary to specify an order of precedence for concepts available via cross-reference.
Requirements
It should be possible to call a RESTful endpoint that:
Example
CEDAR question: preparation medium