search

jez / as-tree

Print a list of paths as a tree of paths 🌳
Other
457 stars 20 forks source link

AUR package #7

Open Trollwut opened 4 years ago

Trollwut commented 4 years ago

Hey folks!

I like this package. It can be pretty useful sometimes. Are there any plans on creating an AUR package?

jez commented 4 years ago

Hey, I don’t use Arch and I’ve never packaged anything for AUR. If you create a package I’d be happy to mention it in the README.

donbex commented 3 years ago

@Trollwut You can use the PKGBUILD below. I don't want to maintain an AUR package, however, because I'm not using as-tree since tree satisfies my needs (see #11).

# Contributor: donbex <ap dot m at runbox dot com>
pkgname=as-tree
pkgver=0.12.0
pkgrel=1
pkgdesc="Print a list of paths as a tree of paths"
arch=('x86_64')
url="https://github.com/jez/as-tree"
license=('custom:BOML')
depends=('gcc-libs')
makedepends=('cargo')
#checkdepends=()
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/jez/${pkgname}/archive/${pkgver}.tar.gz")
md5sums=('77cf5584fced10b16c53ccb4c25224f7')

prepare() {
  cd "$pkgname-$pkgver"
  # Update the lock file. Shouldn't be needed with releases after v0.12.0.
  sed -i "s/version = \"0.11.1\"/version = \"${pkgver}\"/" Cargo.lock
}

build() {
  cd "$pkgname-$pkgver"
  cargo build --release --locked --all-features --target-dir=target
}

package() {
  cd "$pkgname-$pkgver"
  install -Dm 755 target/release/${pkgname} -t "${pkgdir}/usr/bin"
  install -Dm 644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE.md"
}
sharkdp commented 3 years ago

as-tree is available on the AUR (https://aur.archlinux.org/packages/as-tree/), so I think this ticket can be closed.