khoih-prog
commented
3 years ago You have to give the servers different names, such as server and wifiServer
Try the following sketch for ESP32 and see both Ethernet and WiFi can coexist, and one is still working if the other fails
#if !(ESP32)
#error This code is for ESP32 only
#endif
#define USE_ETHERNET true
#include <WiFi.h>
#include <WebServer.h>
#include <SPI.h>
#include <Ethernet.h>
const char* ssid = "your-ssid";
const char* password = "your-password";
// Enter a MAC address and IP address for your controller below.
byte mac[] =
{
0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED
};
// Select the IP address according to your local network
IPAddress ip(192, 168, 2, 100);
EthernetServer server(80);
WiFiServer wifiServer(80);
const int led = 13;
void setup(void)
{
// Open serial communications and wait for port to open:
Serial.begin(115200);
delay(1000);
Serial.println("\nStarting HelloServer on " + String(ARDUINO_BOARD));
//////////////////////////////////////////////
Serial.print("Connecting to ");
Serial.println(ssid);
WiFi.begin(ssid, password);
while (WiFi.status() != WL_CONNECTED)
{
delay(500);
Serial.print(".");
}
Serial.println("");
Serial.println("WiFi connected");
Serial.println("IP address: ");
Serial.println(WiFi.localIP());
/////////////////////////////////////////////
#if defined(ESP32)
// Use the correct pin for ESP32
#define USE_THIS_SS_PIN 27
#if ( USE_ETHERNET || USE_ETHERNET_LARGE || USE_ETHERNET2 || USE_ETHERNET_ENC )
// Must use library patch for Ethernet, EthernetLarge libraries
// ESP32 => GPIO2,4,5,13,15,21,22 OK with Ethernet, Ethernet2, EthernetLarge
// ESP32 => GPIO2,4,5,15,21,22 OK with Ethernet3
//Ethernet.setCsPin (USE_THIS_SS_PIN);
Ethernet.init (USE_THIS_SS_PIN);
#endif
#endif
// start the ethernet connection and the server:
//Ethernet.begin(mac, ip);
Ethernet.begin(mac);
server.begin();
Serial.print(F("HTTP EthernetWebServer is @ IP : "));
Serial.println(Ethernet.localIP());
//////////////////////////////////
wifiServer.begin();
Serial.print(F("HTTP WiFiWebServer is @ IP : "));
Serial.println(WiFi.localIP());
}
void processClient(Client &client, bool fromWiFi = false)
{
if (client)
{
if (fromWiFi)
Serial.println("New WiFi client");
else
Serial.println("New Ethernet client");
// an http request ends with a blank line
boolean currentLineIsBlank = true;
while (client.connected())
{
if (client.available())
{
char c = client.read();
Serial.write(c);
// if you've gotten to the end of the line (received a newline
// character) and the line is blank, the http request has ended,
// so you can send a reply
if (c == '\n' && currentLineIsBlank)
{
// send a standard http response header
client.println("HTTP/1.1 200 OK");
client.println("Content-Type: text/html");
client.println("Connection: close"); // the connection will be closed after completion of the response
client.println("Refresh: 5"); // refresh the page automatically every 5 sec
client.println();
client.println("<!DOCTYPE HTML>");
client.println("<html>");
if (fromWiFi)
client.println("<h1>Hello to WiFi client</h1>");
else
client.println("<h1>Hello to Ethernet client</h1>");
// output the value of each analog input pin
for (int analogChannel = 0; analogChannel < 6; analogChannel++)
{
int sensorReading = analogRead(analogChannel);
client.print("analog input ");
client.print(analogChannel);
client.print(" is ");
client.print(sensorReading);
client.println("<br />");
}
client.println("</html>");
break;
}
if (c == '\n')
{
// you're starting a new line
currentLineIsBlank = true;
} else if (c != '\r') {
// you've gotten a character on the current line
currentLineIsBlank = false;
}
}
}
// give the web browser time to receive the data
delay(1);
// close the connection:
client.stop();
Serial.println("client disconnected");
}
}
void loop()
{
// listen for incoming clients
EthernetClient client = server.available();
processClient(client, false);
// listen for incoming clients
WiFiClient wifiClient = wifiServer.available();
processClient(wifiClient, true);
}But to use the high level EthernetWebServer and ESP32 WebServer is currently not ready, unless the library is modified to avoid conflicts.
I don't think I'll spend time to modify the library as this use case is not popular.
HWEDK
sdrshnptl
elektroboard
Perhaps I'm missing this ability as an inherent part of the base libraries, but I cannot seem to get Wi-Fi and Ethernet servers to operate in one program. The intent is to connect one or the other based on if Ethernet is physically connected, or default to Wi-Fi if Ethernet isn't connected at startup. Removing Ethernet would start the Wi-Fi AP and server. Both listen for clients after switching.
I have not been able to successfully split the startup functions and declarations based on input feedback. I can compile a logic tree that starts one or the other, but there seems to be a problem with the class when trying to connect. It appears to me that the items to consider are as follows:
EthernetServer server( ); Ethernet.begin( ); EthernetClient client = server.available( );
WiFiServer server( ); WiFi.softAP( ); server.begin ( ); WiFiClient = server.available( );
Is it possible to merge these two functionally without major changes?