lopsided98
commented
2 years ago I can't reproduce this. nix shell .#rosPackages.humble.ros2cli is not valid, but nix shell .#humble.ros2cli builds successfully.
Closed kjeremy closed 1 year ago
lopsided98
commented
2 years ago I can't reproduce this. nix shell .#rosPackages.humble.ros2cli is not valid, but nix shell .#humble.ros2cli builds successfully.
kjeremy
commented
2 years ago This is a bug on our end. We split catkin packages outputs into out and dev to save space:
# Overlaid buildRosPackage, with automatic support for splitting packages into
# multiple outputs for build- versus runtime components.
{ lib, buildSingleOutputRosPackage }:
let
# Deep Nix magic: extraRuntimePackages needs to be kept consistent with
# propagatedBuildInputs, unless it is explicitly overridden. To do
# that, override overrideAttrs using overrideAttrs such that this
# function's overrides are applied after other overrides.
consistentExtraRuntimePackages = drv: fn:
let
overridden = drv.overrideAttrs fn;
in
overridden.overrideAttrs (o: {
extraRuntimePackages = o.extraRuntimePackages or (lib.packaging.onlyInstalledOutputs o.propagatedBuildInputs or [ ]);
# Only apply our override once after all other overrideAttrs have
# been applied. To do this, we apply the caller's overrides, then
# reapply our own overlay to it.
passthru = o.passthru or { } // {
overrideAttrs = consistentExtraRuntimePackages overridden;
# XXX also overrideDerivation?
};
});
# Split a package into "out" and "dev" outputs. Because the generated
# cmake scripts contain references to other development packages in the
# nix store, we don't want them in the final closure. Concretely,
# splitting packages requires:
# - Moving the cmake and message definition files over
# - Copying package.xml since catkin gets confused when it can't find it
# at both build- and runtime
# - Add a propagated-build-inputs file to the "out" output which
# propagates only the runtime paths for each propagated package.
# nix-ros-overlay's buildEnv abuses propagation to collect runtime
# dependencies, so we need to tell it which dependencies to collect.
# - Rewrite some relative paths in cmake scripts so that e.g. genmsg can
# find its scripts. Catkin packages often assume that they are
# contained in a single directory, but we violate that assumption.
# This uses a simple heuristic that might not be entirely reliable:
# CATKIN_PACKAGE_BIN_DIR or similar in the source script means it's
# looking for a script or something in the root of the ROS workspace;
# in Nix, that's effectively $out).
splitPackageOutputs = o: {
outputs = lib.unique (o.outputs or [ "out" ] ++ [ "dev" ]);
outputDev = "dev";
postPatch = o.postPatch or "" + ''
for f in cmake/*-extras.cmake.em; do
p="$(sed 's:cmake/\(.*\)-extras\.cmake\.em:\1:' <<<"$f")";
sed -i '/CATKIN_\(PACKAGE\|GLOBAL\)_[A-Z]*_DESTINATION/s:''${'"$p"'_DIR}[/.]*:'"$out"/: $f
done
'';
postFixupHooks = o.postFixupHooks or [ ] ++ [
''
mkdir -p $dev
if [[ -d $out/share ]]; then
pushd $out/share
for d in */cmake */msg; do
mkdir -p $dev/share/"$(dirname "$d")"
mv $d $dev/share/"$(dirname "$d")"
done
for p in */package.xml; do
mkdir -p $dev/share/"$(dirname "$p")"
cp $p $dev/share/"$(dirname "$p")"
done
popd
fi
if [[ -e $dev/nix-support/propagated-build-inputs && -z "$dontPropagateToOut" ]]; then
mkdir -p $out/nix-support
echo "$extraRuntimePackages" >$out/nix-support/propagated-build-inputs
fi
''
];
};
# More deep Nix magic: we're overriding buildRosPackage with a
# function, but want buildRosPackage.overlay to continue to work. Use
# makeOverridable to convert our function to an overridable functor,
# then propagate any overridden arguments into the buildRosPackage that
# we're overriding. Finally, actually call the overridden
# buildRosPackage and apply our overrides to the resulting derivation.
buildSplitRosPackage = lib.makeOverridable
(args: attrs: lib.pipe attrs [
(buildSingleOutputRosPackage.override args)
(drv: consistentExtraRuntimePackages drv splitPackageOutputs)
])
{ };
in
buildSplitRosPackage
This works pretty well for ROS1 but ROS2 has problems with the location of ament_index and finding the lib if the index and cmake files are in the dev output.
It fails with
Package 'rcutils' exports the library 'rcutils' which couldn't be found