CommitBehavior only checks explicit commits. Implicit Commits are still performed without throwing errors!

Please include the following with each issue:

1. Describe the bug With [CommitBehavior(CommitBehavior::Error)] or [CommitBehavior(CommitBehavior::Ignore)] we should be able to avoid commits. But unfortunately implicit commits are still executed and therefore you can't trust it right now.

2. To Reproduce Steps to reproduce the behavior:

Execute the current code.

pageextension 50115 CustomerListExt extends "Customer List"
{
    actions
    {
        addfirst(processing)
        {
            action(TestTransaction)
            {
                Caption = 'Test Transaction';
                ApplicationArea = All;
                trigger OnAction()
                var
                    DataInTransaction: Record DataInTransaction;
                begin
                    DataInTransaction.DeleteAll();
                    Commit();

                    StartTransaction();
                end;
            }
        }
    }

    [CommitBehavior(CommitBehavior::Error)]
    local procedure StartTransaction()
    var
        DataInTransaction: Record DataInTransaction;
        StartTransactionWithRollback: Codeunit StartTransactionWithRollback;
        Count: Integer;
    begin
        StartTransactionWithRollback.DoImplicitCommit(false);
        if StartTransactionWithRollback.Run() then;
        Count := DataInTransaction.Count(); // returns 0 as data was rolled back.

        StartTransactionWithRollback.DoImplicitCommit(true);
        if StartTransactionWithRollback.Run() then;
        Count := DataInTransaction.Count(); // returns 1 as data was committed and the Error('') just could roll back to the last commit
    end;
}
codeunit 50116 StartTransactionWithRollback
{
    trigger OnRun()
    var
        InsertData: Codeunit InsertData;
    begin
        if ImplicitCommit then begin
            if InsertData.Run() then;
            //no error was thrown - Data was commited!
        end else begin
            InsertData.Run();
            Commit(); //throws error: Commit is prohibited in the current scope. The operation cannot continue. Contact your system administrator.
        end;
        Error('');
    end;

    var
        ImplicitCommit: Boolean;

    procedure DoImplicitCommit(ImplicitCommit2: Boolean)
    begin
        ImplicitCommit := ImplicitCommit2;
    end;
}
codeunit 50115 InsertData
{
    trigger OnRun()
    var
        DataInTransaction: Record DataInTransaction;
    begin
        DataInTransaction.Code := 'Test';
        DataInTransaction.Insert();
    end;
}
table 50115 DataInTransaction
{
    fields
    {
        field(1; Code; Code[20])
        {
            Caption = 'Test';
        }
    }
}

3. Expected behavior Implicit commits can't be done as well. Otherwise you can't trust the CommitBehavior.

4. Actual behavior Implicit Commits, e.g. when working with the return value of Codeunit.Run, are still performed which is quite scary.

5. Versions:

AL Language: v12.1.887908
Visual Studio Code: 1.82.3
Business Central: 23.0.12034.12676
List of Visual Studio Code extensions that you have installed: a few, but that won't have impact.

Final Checklist

Please remember to do the following:

[x] Search the issue repository to ensure you are reporting a new issue
[x] Reproduce the issue after disabling all extensions except the AL Language extension
[x] Simplify your code around the issue to better isolate the problem

microsoft / AL

CommitBehavior only checks explicit commits. Implicit Commits are still performed without throwing errors! #7589

Final Checklist