Here is a PKGBUILD for the Arch Linux AUR

[MountainX]

I hope someone will submit this PKGBUILD to the Arch Linux AUR. I believe this PKGBUILD meets all the guidelines and is ready to go. https://wiki.archlinux.org/index.php/AUR_submission_guidelines

# Maintainer: morpheusthewhite <zffromGerace@hotmail.it>

pkgname=nordpy-plasmoid
pkgver=r10.ec6491c
pkgrel=1
pkgdesc="Plasma widget to control NordPy; it uses the last server type used within the application to establish the VPN connection."
arch=('x86_64')
url="https://github.com/morpheusthewhite/nordpy-plasmoid.git"
license=('GPL3')
depends=('polkit' 'nordpy' 'qt5-base' 'qt5-declarative' 'plasma-framework') 
makedepends=('git' 'extra-cmake-modules')
source=("git+https://github.com/morpheusthewhite/nordpy-plasmoid.git")
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/${pkgname}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  # "Building and installing plugin"
  qmake $pkgname/plugin -o build-plugin/Makefile
  make -C build-plugin

  # "Building and installing plasmoid"
  cmake -B build $pkgname
  make -C build
}

package() {
  make -C build-plugin INSTALL_ROOT="$pkgdir" install
  make -C build DESTDIR="$pkgdir" install
}

[morpheusthewhite]

Thank you so much, I just published it on the AUR

[MountainX]

Thank you for publishing it to the AUR. I tested it. Because you changed the name from "nordpy-plasmoid" to "nordpy-plasmoid-git" (which is the proper name), some changes are needed in the PKGBUILD. I made the changes below and tested them. Please update the PKGBUILD on the AUR.

pkgname=nordpy-plasmoid-git
pkgver=r10.ec6491c
pkgrel=1
pkgdesc="Plasma widget to control NordPy; it uses the last server type used within nordpy to establish the VPN connection."
arch=('x86_64')
url="https://github.com/morpheusthewhite/nordpy-plasmoid.git"
license=('GPL3')
groups=()
depends=('polkit' 'nordpy' 'qt5-base' 'qt5-declarative' 'plasma-framework') 
makedepends=('git' 'extra-cmake-modules')
source=("git+https://github.com/morpheusthewhite/nordpy-plasmoid.git")
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/${pkgname%-git}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  # "Building and installing plugin"
  qmake ${pkgname%-git}/plugin -o build-plugin/Makefile
  make -C build-plugin

  # "Building and installing plasmoid"
  cmake -B build ${pkgname%-git}
  make -C build
}

package() {
  make -C build-plugin INSTALL_ROOT="$pkgdir" install
  make -C build DESTDIR="$pkgdir" install
}

[morpheusthewhite]

Thank you again for the fix (I tried to build it before publishing and it actually worked)