systemd service drop-ins

[devurandom]

Description

NixOS allows defining foo.service.d drop in files using systemd.user.services.<name>.overrideStrategy. How do I do the same with home-manager?

I tried various things, but do not get the result I would expect, a ~/.config/systemd/user/foo.service.d/override.conf file containing:

[Service]
EnvironmentFile=.../env

---

  systemd.user.services = {
    foo = {
      # https://nixos.org/manual/nixos/unstable/options#opt-systemd.user.services._name_.overrideStrategy
      overrideStrategy = "asDropin";
      # https://nixos.org/manual/nixos/unstable/options#opt-systemd.user.services._name_.serviceConfig
      serviceConfig = {
        EnvironmentFile = ".../env";
      };
    };
  };

causes:

error: A definition for option `home-manager.users.[REDACTED].systemd.user.services.foo.overrideStrategy' is not of type `attribute set of (boolean or signed integer or string or path or list of (boolean or signed integer or string or path))'.

---

  systemd.user.services = {
    foo = {
      # https://nixos.org/manual/nixos/unstable/options#opt-systemd.user.services._name_.serviceConfig
      serviceConfig = {
        EnvironmentFile = ".../env";
      };
    };
  };

creates ~/.config/systemd/user/foo.service:

[serviceConfig]
EnvironmentFile=.../env

which overrides the whole foo.service installed by NixOS.

---

  systemd.user.services = {
    foo = {
      Service = {
        EnvironmentFile = ".../env";
      };
    };
  };

creates ~/.config/systemd/user/foo.service:

[Service]
EnvironmentFile=.../env

which again overrides the whole foo.service installed by NixOS.

---

  systemd.user."services.d" = {
    foo = {
      Service = {
        EnvironmentFile = ".../env";
      };
    };
  };

causes:

error: The option `home-manager.users.[REDACTED].systemd.user."services.d"' does not exist.

---

I also skimmed through https://github.com/nix-community/home-manager/blob/44677a1c96810a8e8c4ffaeaad10c842402647c1/modules/systemd.nix but could not figure out how systemd service drop-ins are supposed to work.

---

My flake.nix:

{
  inputs = {
    nixpkgs.url = github:NixOS/nixpkgs/nixos-unstable;
    home-manager = {
      url = flake:home-manager;
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { self, nixpkgs, home-manager, ... }@inputs: {
      nixosConfigurations.system = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        specialArgs = inputs;
        modules = [
          ./hardware-configuration.nix
          ./configuration.nix
          home-manager.nixosModules.home-manager {
            home-manager.useGlobalPkgs = true;
            home-manager.useUserPackages = true;
            home-manager.users.[REDACTED] = import ./home/[REDACTED].nix;
          }
        ];
      };
    };
}

[jackwilsdon]

It seems like HM doesn't have built-in support for drop-in files, so I've been creating them like this:

xdg.configFile."systemd/user/my.service.d/overrides.conf".text = ''
  [Service]
  EnvironmentFile=.../env
'';

[devurandom]

Thanks! It worked:

  xdg.configFile."systemd/user/my.service.d/99-env.conf" = let
    envFile = pkgs.writeTextDir "override.env" ''
      VAR_A=1
      VAR_B=2
    '';
  in {
    text = ''
      [Service]
      EnvironmentFile=${envFile}/override.env
    '';
  };

[stale[bot]]

Thank you for your contribution! I marked this issue as stale due to inactivity. Please be considerate of people watching this issue and receiving notifications before commenting 'I have this issue too'. We welcome additional information that will help resolve this issue. Please read the relevant sections below before commenting.

If you are the original author of the issue

* If this is resolved, please consider closing it so that the maintainers know not to focus on this. * If this might still be an issue, but you are not interested in promoting its resolution, please consider closing it while encouraging others to take over and reopen an issue if they care enough. * If you know how to solve the issue, please consider submitting a Pull Request that addresses this issue.

If you are not the original author of the issue

* If you are also experiencing this issue, please add details of your situation to help with the debugging process. * If you know how to solve the issue, please consider submitting a Pull Request that addresses this issue.

Memorandum on closing issues

Don't be afraid to manually close an issue, even if it holds valuable information. Closed issues stay in the system for people to search, read, cross-reference, or even reopen – nothing is lost! Closing obsolete issues is an important way to help maintainers focus their time and effort.