Consultas de ejemplo arregladas

[mikel-egana-aranguren]

¿En qué localidad se encuentra Lehendakaritza?

Habia problemas con los prefijos HTTP/HTTPS.

# Prefijos problematicos por haber cambiado HTTP/HTTPS
PREFIX dir: <https://id.euskadi.eus/def/directory#>
PREFIX callejero: <https://vocab.linkeddata.es/datosabiertos/def/urbanismo-infraestructuras/callejero#>
PREFIX gn: <https://www.geonames.org/ontology#>

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <https://schema.org/>
PREFIX nora: <https://id.euskadi.eus/def/nora#>

SELECT *
WHERE { 
    GRAPH <https://id.euskadi.eus/graph/Directorio> {
        ?equipment dir:equipmentOf ?organization .
        ?equipment schema:location ?portal .
        ?portal callejero:via ?street .
        ?organization rdfs:label ?org_label .
        FILTER CONTAINS(?org_label, "Lehendakaritza") .
    }
    GRAPH <https://id.euskadi.eus/graph/NORA> {
        ?street nora:localidad ?localidad .
        ?localidad gn:officialname ?localidad_name .
    }
}

Consulta transitiva

Esta consulta aprovecha el razonamineto automático para conseguir entidades que no están directamente relacionadas entre sí.

Para que esta consulta funcione hay que cargar los archivos nora.ttl y territorio.owl en el grafo NORA-vocabs. Además el repo GraphDB NORA tiene que tener la inferencia activada, por ejemplo con la opción "OWL-Horst (Optimized)".

PREFIX geosparql: <http://www.opengis.net/ont/geosparql#>
SELECT ?country
WHERE { 
   <http://id.euskadi.eus/public-sector/urbanism-territory/province/48> geosparql:sfWithin ?country .
}

Contar los municipios de Araba

Hay que poner el GRAPH.

PREFIX esadm: <https://vocab.linkeddata.es/datosabiertos/def/sector-publico/territorio#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT  (COUNT(?municipioAraba) as ?count) 
WHERE { 
    GRAPH <https://id.euskadi.eus/graph/NORA>{  
        ?municipioAraba esadm:provincia ?provincia .
        ?provincia rdfs:label "Araba"@eu .
    }
}