AnimMouse
commented
5 months ago Apparently x265 has changed the way of detecting the system architecture in version 3.6, causing the CPU architecture detection to fail.
Here is the gist of CMakeLists.txt as of version 3.5:
# System architecture detection
string(TOLOWER "${CMAKE_SYSTEM_PROCESSOR}" SYSPROC)
set(X86_ALIASES x86 i386 i686 x86_64 amd64)
set(ARM_ALIASES armv6l armv7l aarch64)
list(FIND X86_ALIASES "${SYSPROC}" X86MATCH)
list(FIND ARM_ALIASES "${SYSPROC}" ARMMATCH)
set(POWER_ALIASES ppc64 ppc64le)
list(FIND POWER_ALIASES "${SYSPROC}" POWERMATCH)
if("${SYSPROC}" STREQUAL "" OR X86MATCH GREATER "-1")
set(X86 1)
add_definitions(-DX265_ARCH_X86=1)
if(CMAKE_CXX_FLAGS STREQUAL "-m32")
message(STATUS "Detected x86 target processor")
elseif("${CMAKE_SIZEOF_VOID_P}" MATCHES 8)
set(X64 1)
add_definitions(-DX86_64=1)
message(STATUS "Detected x86_64 target processor")
endif()
elseif(POWERMATCH GREATER "-1")
message(STATUS "Detected POWER target processor")
set(POWER 1)
add_definitions(-DX265_ARCH_POWER=1)
if("${CMAKE_SIZEOF_VOID_P}" MATCHES 8)
set(PPC64 1)
add_definitions(-DPPC64=1)
message(STATUS "Detected POWER PPC64 target processor")
endif()
elseif(ARMMATCH GREATER "-1")
if(CROSS_COMPILE_ARM)
message(STATUS "Cross compiling for ARM arch")
else()
set(CROSS_COMPILE_ARM 0)
endif()
set(ARM 1)
if("${CMAKE_SIZEOF_VOID_P}" MATCHES 8)
message(STATUS "Detected ARM64 target processor")
set(ARM64 1)
add_definitions(-DX265_ARCH_ARM=1 -DX265_ARCH_ARM64=1 -DHAVE_ARMV6=0)
else()
message(STATUS "Detected ARM target processor")
add_definitions(-DX265_ARCH_ARM=1 -DX265_ARCH_ARM64=0 -DHAVE_ARMV6=1)
endif()
else()
message(STATUS "CMAKE_SYSTEM_PROCESSOR value `${CMAKE_SYSTEM_PROCESSOR}` is unknown")
message(STATUS "Please add this value near ${CMAKE_CURRENT_LIST_FILE}:${CMAKE_CURRENT_LIST_LINE}")
endif()Here is the gist of CMakeLists.txt as of version 3.6:
# System architecture detection
if (APPLE AND CMAKE_OSX_ARCHITECTURES)
string(TOLOWER "${CMAKE_OSX_ARCHITECTURES}" SYSPROC)
else()
string(TOLOWER "${CMAKE_SYSTEM_PROCESSOR}" SYSPROC)
endif()
set(X86_ALIASES x86 i386 i686 x86_64 amd64)
set(ARM_ALIASES armv6l armv7l)
set(ARM64_ALIASES arm64 arm64e aarch64)
list(FIND X86_ALIASES "${SYSPROC}" X86MATCH)
list(FIND ARM_ALIASES "${SYSPROC}" ARMMATCH)
list(FIND ARM64_ALIASES "${SYSPROC}" ARM64MATCH)
set(POWER_ALIASES powerpc64 powerpc64le ppc64 ppc64le)
list(FIND POWER_ALIASES "${SYSPROC}" POWERMATCH)
if(X86MATCH GREATER "-1")
set(X86 1)
add_definitions(-DX265_ARCH_X86=1)
if(CMAKE_CXX_FLAGS STREQUAL "-m32")
message(STATUS "Detected x86 target processor")
elseif("${CMAKE_SIZEOF_VOID_P}" MATCHES 8)
set(X64 1)
add_definitions(-DX86_64=1)
message(STATUS "Detected x86_64 target processor")
endif()
elseif(POWERMATCH GREATER "-1")
message(STATUS "Detected POWER target processor")
set(POWER 1)
add_definitions(-DX265_ARCH_POWER=1)
if("${CMAKE_SIZEOF_VOID_P}" MATCHES 8)
set(PPC64 1)
add_definitions(-DPPC64=1)
message(STATUS "Detected POWER PPC64 target processor")
endif()
elseif(ARMMATCH GREATER "-1")
if(CROSS_COMPILE_ARM)
message(STATUS "Cross compiling for ARM arch")
else()
set(CROSS_COMPILE_ARM 0)
endif()
message(STATUS "Detected ARM target processor")
set(ARM 1)
add_definitions(-DX265_ARCH_ARM=1 -DHAVE_ARMV6=1)
elseif(ARM64MATCH GREATER "-1")
#if(CROSS_COMPILE_ARM64)
#message(STATUS "Cross compiling for ARM64 arch")
#else()
#set(CROSS_COMPILE_ARM64 0)
#endif()
message(STATUS "Detected ARM64 target processor")
set(ARM64 1)
add_definitions(-DX265_ARCH_ARM64=1 -DHAVE_NEON)
else()
message(STATUS "CMAKE_SYSTEM_PROCESSOR value `${CMAKE_SYSTEM_PROCESSOR}` is unknown")
message(STATUS "Please add this value near ${CMAKE_CURRENT_LIST_FILE}:${CMAKE_CURRENT_LIST_LINE}")
endif()
rdp
Hello there, i found an issue. when i use this script build ffmpeg n7.0 win64 with x265 version 3.6, I can't enable x86 asm optimization (like this picture).
when i use this script build ffmpeg n7.0 win64 with x265 version 3.5, I can enable x86 asm optimization (like this picture).
