revarbat
commented
5 years ago Polyhedra devel work by @adrianVmariano: Requires Oskar Linde's Hull to work. (#18)
use<BOSL/math.scad>
use<BOSL/transforms.scad>
function is_member(value, list) =
len(list)==0 ? false :
list[0] == value ? true : is_member(value,cdr(list));
function even_permutations(v) = [v, [v[2], v[0], v[1]], [v[1],v[2],v[0]]];
function all_permutations(v) = [v, [v[2], v[0], v[1]], [v[1],v[2],v[0]], [v[1],v[0],v[2]],[v[2],v[1],v[0]],[v[0],v[2],v[1]]];
function listcomp(a,b,n=0) = !is_list(a) && !is_list(b) ? scalarcomp(a,b):
len(a)<=n && len(b)<=n ? 0 :
len(a)<=n ? 1 :
len(b)<=n ? -1 :
a[n] < b[n] ? -1 :
a[n] > b[n] ? 1 :
listcomp(a,b,n+1);
function scalarcomp(a,b) = a<b ? -1 : a>b ? 1 : 0;
function quicksort(arr) =
!(len(arr)>0) ? [] :
let( pivot = arr[floor(len(arr)/2)],
lesser = [ for (y = arr) if (listcomp(y,pivot)==-1) y ],
equal = [ for (y = arr) if (listcomp(y,pivot)==0) y ],
greater = [ for (y = arr) if (listcomp(y,pivot)==1) y ]
)
concat( quicksort(lesser), equal, quicksort(greater) );
function unique(points) = let(sorted=quicksort(points))
[for(i=[0:len(sorted)-1]) if (i==0 || sorted[i]!=sorted[i-1]) sorted[i]];
// sign=="even" means an even number of minus signs (odd number of plus signs)
// sign=="odd" means an odd number of minus signs (even number of plus signs)
function point_ref(points, sign="both") =
unique([ for(i=[-1,1],j=[-1,1],k=[-1,1]) if (sign=="both" || sign=="even" && i*j*k>0 || sign=="odd" && i*j*k<0)
each [for(point=points) vmul(point,[i,j,k])]
]);
function cosh(x) = (exp(x)+exp(-x))/2;
function acosh(x) = ln(x+sqrt(x*x-1));
// Polyhedra data from Wikipedia and http://dmccooey.com/polyhedra/
phi = (1+sqrt(5))/2;
tribonacci=(1+4*cosh(acosh(2+3/8)/3))/3;
pname = 0;
class = 1;
facecount = 2;
edgelen = 3;
in_radius = 4;
mid_radius = 5;
out_radius = 6;
volume = 7;
vertices = 8;
library = [
["tetrahedron", "platonic", 4, 2*sqrt(2), sqrt(6)/12, sqrt(2)/4, sqrt(6)/4, 1/6/sqrt(2),
point_ref([[1,1,1]], sign="even")],
["cube", "platonic", 6, 2, 1/2, 1/sqrt(2), sqrt(3)/2, 1,
point_ref([[1,1,1]])],
["octahedron", "platonic", 8, sqrt(2), sqrt(6)/6, 1/2, sqrt(2)/2, sqrt(2)/3,
point_ref(even_permutations([1,0,0]))],
["dodecahedron", "platonic", 12, 2/phi, sqrt(5/2+11*sqrt(5)/10)/2, (3+sqrt(5))/4, sqrt(3)*phi/2, (15+7*sqrt(5))/4,
point_ref(concat([[1,1,1]],even_permutations([0,phi,1/phi])))],
["icosahedron", "platonic", 20, 2, phi*phi/2/sqrt(3), cos(36), sin(72), 5*(3+sqrt(5))/12,
point_ref(even_permutations([0,1,phi]))],
["truncated tetrahedron", "archimedean", 8, sqrt(8), sqrt(6)/4, 3*sqrt(2)/4, sqrt(11/8), 23*sqrt(2)/12,
point_ref(all_permutations([1,1,3]),sign="even")],
["cuboctahedron", "archimedean", 14, sqrt(2), sqrt(2)/2, sqrt(3)/2, 1, 5*sqrt(2)/3,
point_ref(all_permutations([1,1,0]))],
["truncated cube", "archimedean", 14, 2*(sqrt(2)-1), (1+sqrt(2))/2, 1+sqrt(2)/2, sqrt(7+4*sqrt(2))/2, 7+14*sqrt(2)/3,
point_ref(all_permutations([1,1,sqrt(2)-1]))],
["truncated octahedron", "archimedean", 14, sqrt(2), sqrt(6)/2, 1.5, sqrt(10)/2, 8*sqrt(2),
point_ref(all_permutations([0,1,2]))],
["rhombicuboctahedron", "archimedean", 26, 2, (1+sqrt(2))/2, sqrt(2*(2+sqrt(2)))/2, sqrt(5+2*sqrt(2))/2, 4+10*sqrt(2)/3,
point_ref(even_permutations([1,1,1+sqrt(2)]))],
["truncated cuboctahedron", "archimedean", 26, 2, (1+2*sqrt(2))/2, sqrt(6*(2+sqrt(2)))/2, sqrt(13+6*sqrt(2))/2,
(22+14*sqrt(2)),
point_ref(all_permutations([1,1+sqrt(2), 1+2*sqrt(2)]))],
["snub cube", "archimedean", 38, 1.60972,1.14261350892596209,1.24722316799364325, 1.34371337374460170,
sqrt((613*tribonacci+203)/(9*(35*tribonacci-62))),
concat(point_ref(even_permutations([1,1/tribonacci,tribonacci]), sign="odd"),
point_ref(even_permutations([1,tribonacci,1/tribonacci]), sign="even"))], // changed from odd!
["icosidodecahedron", "archimedean", 32, 1, sqrt(5*(5+2*sqrt(5)))/5,sqrt(5+2*sqrt(5))/2, phi, (14+17*phi)/3,
point_ref(concat(even_permutations([0,0,phi]),even_permutations([1/2,phi/2,phi*phi/2])))],
["truncated dodecahedron", "archimedean", 32, 2*phi-2, sqrt(7+11*phi)/2, (3*phi+1)/2,sqrt(11+phi*15)/2, 5*(99+47*sqrt(5))/12,
point_ref(concat(even_permutations([0,1/phi, 2+phi]),
even_permutations([1/phi,phi,2*phi]),
even_permutations([phi,2,phi+1])))],
["truncated icosahedron", "archimedean", 32, 2, (3*sqrt(3)+sqrt(15))/4, 3*phi/2, sqrt(58+18*sqrt(5))/4, (125+43*sqrt(5))/4,
point_ref(concat(even_permutations([0,1,3*phi]),
even_permutations([1,2+phi,2*phi]),
even_permutations([phi,2,phi*phi*phi])))],
["rhombicosidodecahedron", "archimedean", 62, 2, 3/10*sqrt(15+20*phi), sqrt(3/2+2*phi), sqrt(8*phi+7)/2, (31+58*phi)/3,
point_ref(concat(even_permutations([1,1,phi*phi*phi]),
even_permutations([phi*phi,phi,2*phi]),
even_permutations([2+phi,0,phi*phi])))],
["truncated icosidodecahedron", "archimedean", 62, 2*phi - 2, sqrt(15/4+5*phi),sqrt(9/2+6*phi),sqrt(19/4+6*phi),
95+50*sqrt(5),
point_ref(concat(even_permutations([1/phi,1/phi,3+phi]),
even_permutations([2/phi,phi,1+2*phi]),
even_permutations([1/phi,phi*phi,3*phi-1]),
even_permutations([2*phi-1,2,2+phi]),
even_permutations([phi,3,2*phi])))],
["snub dodecahedron", "archimedean", 92, 1, 1.98091594728184,2.097053835252087,2.155837375115, 37.61664996273336,
concat(point_ref(even_permutations([0.374821658114562,0.330921024729844,2.097053835252088]), sign="odd"),
point_ref(even_permutations([0.192893711352359,1.249503788463027,1.746186440985827]), sign="odd"),
point_ref(even_permutations([1.103156835071754,0.847550046789061,1.646917940690374]), sign="odd"),
point_ref(even_permutations([0.567715369466922,0.643029605914072,1.977838965420219]), sign="even"),
point_ref(even_permutations([1.415265416255982,0.728335176957192,1.454024229338015]), sign="even"))],
["rhombic dodecahedron", "catalan", 12, sqrt(3), sqrt(2/3), 2*sqrt(2)/3, 2/sqrt(3), 16*sqrt(3)/9,
point_ref(concat([[1,1,1]], even_permutations([2,0,0])))],
["triakis tetrahedron","catalan", 12, 9/5, 5*sqrt(22)/44, 5*sqrt(2)/12, 5*sqrt(6)/12, 25*sqrt(2)/36,
concat(point_ref([9*sqrt(2)/20*[1,1,1]],sign="even"),
point_ref([3*sqrt(2)/4*[1,1,1]],sign="odd"))],
["rhombic dodecahedron", "catalan", 12, 1, 2/sqrt(6), 4/3/sqrt(2), 2/sqrt(3), 16/3/sqrt(3),
point_ref(concat([[1,1,1]/sqrt(3)],even_permutations([2/sqrt(3),0,0])))],
["tetrakis hexahedron", "catalan", 24, 1, 2/sqrt(5), 2*sqrt(2)/3, 2/sqrt(3), 32/9,
point_ref(concat([[2/3,2/3,2/3]],even_permutations([1,0,0])))],
["triakis octahedron", "catalan", 24, 2, sqrt(17*(23+16*sqrt(2)))/34, 1/2+sqrt(2)/4,(1+sqrt(2))/2,3/2+sqrt(2),
point_ref(concat([[1,1,1]],even_permutations([1+sqrt(2),0,0])))],
["deltoidal icositetrahedron", "catalan", 24, 2*sqrt(10-sqrt(2))/7, 7*sqrt((7+4*sqrt(2))/(34 * (10-sqrt(2)))),
7*sqrt(2*(2+sqrt(2)))/sqrt(10-sqrt(2))/4, 7*sqrt(2)/sqrt(10-sqrt(2))/2,
(14+21*sqrt(2))/sqrt(10-sqrt(2)),
point_ref(concat(even_permutations([0,1,1]), even_permutations([sqrt(2),0,0]),
even_permutations((4+sqrt(2))/7*[1,1,1])))],
["pentagonal icositetrahedron","catalan",24, 0.593465355971, 1.950681331784, 2.1015938932963, 2.29400105368695,
35.6302020120713,
concat(
point_ref(even_permutations([0.21879664300048044,0.740183741369857,1.0236561781126901]),sign="even"),
point_ref(even_permutations([0.21879664300048044,1.0236561781126901,0.740183741369857]),sign="odd"),//changed from odd
point_ref(even_permutations([1.3614101519264425,0,0])),
point_ref([0.7401837413698572*[1,1,1]]))],
["rhombic triacontahedron", "catalan", 30,1, sqrt(1+2/sqrt(5)), 1+1/sqrt(5), (1+sqrt(5))/2, 4*sqrt(5+2*sqrt(5)),
concat(point_ref(even_permutations([0,sqrt(1+2/sqrt(5)), sqrt((5+sqrt(5))/10)])),
point_ref(even_permutations([0,sqrt(2/(5+sqrt(5))), sqrt(1+2/sqrt(5))])),
point_ref([sqrt((5+sqrt(5))/10)*[1,1,1]]))],
["disdyakis dodecahedron", "catalan", 48, 1,sqrt(249/194+285/194/sqrt(2)) ,(2+3*sqrt(2))/4, sqrt(183/98+213/98/sqrt(2)),
sqrt(6582+4539*sqrt(2))/7,
point_ref(concat(even_permutations([sqrt(183/98+213/98/sqrt(2)),0,0]),
even_permutations(sqrt(3+3/sqrt(2))/2 * [1,1,0]),[7/sqrt(6*(10-sqrt(2)))*[1,1,1]]))],
["pentakis dodecahedron", "catalan", 60, 1,sqrt(477/436+97*sqrt(5)/218), sqrt(5)/4+11/12, sqrt(7/4+sqrt(5)/3),
125*sqrt(5)/36+205/36,
point_ref(concat(even_permutations([0,(5-phi)/6, phi/2+2/3]),
even_permutations([0,(phi+1)/2,phi/2]),[(4*phi-1)/6 * [1,1,1]]))],
["triakis icosahedron", "catalan", 60, 1, sqrt((139+199*phi)/244), (8*phi+1)/10, sqrt(13/8+19/8/sqrt(5)), (13*phi+3)/2,
point_ref(concat(even_permutations([(phi+7)/10, 0, (8*phi+1)/10]),
even_permutations([0, 1/2, (phi+1)/2]),[phi/2*[1,1,1]]))],
["deltoidal hexecontahedron", "catalan", 60, sqrt(5*(85-31*sqrt(5)))/11, sqrt(571/164+1269/164/sqrt(5)), 5/4+13/4/sqrt(5),
sqrt(147+65*sqrt(5))/6, sqrt(29530+13204*sqrt(5))/3,
point_ref(concat(even_permutations([0,0,sqrt(5)]),
even_permutations([0,(15+sqrt(5))/22, (25+9*sqrt(5))/22]),
even_permutations([0,(5+3*sqrt(5))/6, (5+sqrt(5))/6]),
even_permutations([(5-sqrt(5))/4, sqrt(5)/2, (5+sqrt(5))/4]),
[(5+4*sqrt(5))/11*[1,1,1]]))],
["deltoidal hexecontahedron", "catalan", 60,0.58289953474498, 3.499527848905764,3.597624822551189,3.80854772878239,
189.789852066885,
concat(
point_ref(even_permutations([0.192893711352359,0.218483370127321,2.097053835252087]), sign="even"),
point_ref(even_permutations([0,0.7554672605165955,1.9778389654202186])),
point_ref(even_permutations([0,1.888445389283669154,1.1671234364753339])),
point_ref(even_permutations([0.56771536946692131,0.824957552676275846,1.8654013108176956657]),sign="odd"),
point_ref(even_permutations([0.37482165811456229,1.13706613386050418,1.746186440985826345]), sign="even"),
point_ref(even_permutations([0.921228888309550,0.95998770139158,1.6469179406903744]),sign="even"),
point_ref(even_permutations([0.7283351769571914773,1.2720962825758121,1.5277030708585051]),sign="odd"),
point_ref([1.222371704903623092*[1,1,1]]))],
["disdyakis triacontahedron","catalan", 120, sqrt(15*(85-31*sqrt(5)))/11, sqrt(3477/964+7707/964/sqrt(5)), 5/4+13/4/sqrt(5),
sqrt(441+195*sqrt(5))/10,sqrt(17718/5+39612/5/sqrt(5)),
point_ref(concat(even_permutations([0,0,3*(5+4*sqrt(5))/11]),
even_permutations([0,(5-sqrt(5))/2,(5+sqrt(5))/2]),
even_permutations([0,(15+9*sqrt(5))/10,3*(5+sqrt(5))/10]),
even_permutations([3*(15+sqrt(5))/44,3*(5+4*sqrt(5))/22, (75+27*sqrt(5))/44]),
[sqrt(5)*[1,1,1]]))],
];
/* Notes on Kepler-Poinsot Solids
It seems these can be made by adding/subtracting a pyramid from other solids.
It's actually possible to do this generally if we have an attach module, assuming that the normal
to all the faces of a polyhedron is the line from the face center to the origin.
Great dodecahedron: from icosahedron subtract pyramind of height sqrt(5/3-phi)
Great stellated dodecahedron: from icosahedron add pyramids of height sqrt(2/3+phi)
Small stellated dodecahedron: from dodecahedron add pyramids of height sqrt((3+4*phi)/5)
Great icosahedron seems to be complicated, not easily derivable
*/
use<hull.scad>
//regular_polyhedron("pentagonal icositetrahedron");
/*
d=7;
% scale([1/s,1/s,1/s])polyhedron(points=pts, faces=hull(pts));
sphere(r=library[index][in_radius]+.01,$fn=100);
translate([d,0,0]){
%scale([1/s,1/s,1/s])polyhedron(points=pts, faces=hull(pts));
sphere(r=library[index][mid_radius]+.0,$fn=100);
}
translate([2*d,0,0]){
scale([1/s,1/s,1/s])polyhedron(points=pts, faces=hull(pts));
%sphere(r=library[index][out_radius]-.05,$fn=100);
}
translate([d,d,0]){
t = library[index][volume];
%scale([1/s,1/s,1/s])polyhedron(points=pts, faces=hull(pts));
sphere(r=pow(t/PI*3/4,1/3),$fn=100);
}
*/
// specify name
// specify (optional) type and (optional) face count and then index
//
// You can give ir to specify the size of the inscribed sphere, mr to specify the mid scribed sphere radius, or
// or to specify the outer sphere size.
//
// Specify r to round over the polyhedron with the specified radius. Note that especially if $fn is small the dimensions
// might be slightly off.
//
module regular_polyhedron(name=undef,index=undef,type=undef,faces=undef,side=1,ir=undef, mr=undef, or=undef, r=0)
{
libsize = len(library);
argcount = sum([is_def(ir)?1:0, is_def(mr)?1:0, is_def(or)?1:0]);
assert(argcount<=1, "You must specify only one of 'ir', 'mr' and 'or'");
indexlist = [for(i=[0:len(library)-1]) if ((is_undef(name) || library[i][pname]==name)
&& (is_undef(type) || library[i][class]==type)
&& (is_undef(faces) || library[i][facecount]==faces)) i];
echo("indexlist = ",indexlist);
entry = library[is_def(index) ? indexlist[index] : indexlist[0]];
echo("index = ",library[is_def(index) ? indexlist[index] : indexlist[0]]);
scalefactor = (argcount == 0 ? side :
is_def(ir) ? ir/entry[in_radius] :
is_def(mr) ? mr/entry[mid_radius] : or/entry[out_radius]) / entry[edgelen];
if (r==0)
polyhedron(scalefactor*entry[vertices], hull(entry[vertices]));
else {
fn = segs(r);
fixed_r = r/cos(180/fn);
adjusted_scale = scalefactor - fixed_r / entry[in_radius] / entry[edgelen];
hull()
place_copies(adjusted_scale*entry[vertices])
sphere(r=fixed_r, $fn=fn);
}
}
//function is_def(x) = !is_undef(x);
//function is_scalar(x) = !is_list(x);
function all(list,n=0) =
n==len(list) ? true :
!(is_list(list[n])? all(list[n]) : list[n]) ? false :
all(list,n+1);
//regular_polyhedron("pentagonal icositetrahedron", or=5);
//%sphere(r=5-.2, $fn=100);
//regular_polyhedron(index=0, type="catalan");
//regular_polyhedron("disdyakis triacontahedron");
/*
shape = "dodecahedron";
$fn=8;
//top_half(cp=[0,0,.2])
difference(){
regular_polyhedron(shape, r=0);
regular_polyhedron(shape, r=.2);
}
*/
$fn=96;
for(i=[0:len(library)-1]) {
place_copies([[3*i,0,0]]) // Plain polyhedron
regular_polyhedron(index=i, mr=1);
place_copies([[3*i,3.5,0]]){ // Inner radius means sphere touches faces of the polyhedron
sphere(r=1.005); // Sphere is slightly oversized so you can see it poking out from each face
%regular_polyhedron(index=i, ir=1);
}
place_copies([[3*i,7,0]]){ // Mid radius means the sphere touches the center of each edge
sphere(r=1);
%regular_polyhedron(index=i, mr=1);
}
place_copies([[3*i,11,0]]){ // outer radius means points of the polyhedron are on the sphere
%sphere(r=.99); // Slightly undersized sphere means the points poke out a bit
regular_polyhedron(index=i, or=1);
}
}
/* regular_polyhedron(faces=60,index=0); */
// TODO
// Use volume info?
// Are archimedean & catalan solids in the "right" order in the list?
// Add a stellate function
adrianVmariano
As per suggestion from @adrianVmariano, We should have a regular solids libfile. At the least for the platonic solids, and typical dice polyhedra: 4, 6, 8, 10, 12, 20, 30 sides. Maybe some of the Archimedean solids.