rodneyknaap
commented
1 year ago Hi 640KB,
Thanks for your interest and getting in touch, that's very kind of you. I also responded on the dosreloaded.de forum.
I am also interested in your BIOS. I really hope the GLaBIOS could work on my system because I love the work and I saw many customizations in the source code. That kind of work is really modern and I feel it matches with my hardware.
About my design, it basically uses the same keyboard circuits as the original IBM 5160 and Turbo XT clones made in Taiwan. There is no keyboard controller, it's all done in the 8255 PIO chip and the 74LS322 just as in the IBM designs. The keyboard I use is a Cherry G80-1000 with the dipswitch in "XT" mode.
I am not sure why the TOGGLE.COM causes the strange configuration of the keyboard to input numbers on the prompt instead of the arrow key function. It almost seems as it's confusing scancodes of the arrow keys with the number keys in the numerical section of the keyboard. TOGGLE.COM only changes the typing mode to CAPS and enables the numerical keys by default. On the XT I did notice before that TOGGLE.COM works in a strange way with the phatcode BIOS too, because it does turn on CAPs typing and numlock, however the LEDs do not turn on. I guess doing that requires an actual keyboard controller on the mainboard, I am not sure.
After taking TOGGLE.COM out of my AUTOEXEC.BAT, I could see that DOSKEY functioned normally to recall previous DOS commands instead of showing numbers on arrow presses. So TOGGLE.COM seems to confuse the keyboard routines somehow.
About my UMB memory, it is very simple, it's enabled with two jumpers in my memory decoder. The jumpers are on which means that the memory is accessible in the D0000 and E0000 memory regions. CLEARMEM.SYS zeroes out the area and USE_UMBS.SYS initializes it for usage as UMB RAM. The commands are as follows:
DEVICE=C:\DOS62\CLEARMEM.SYS D000 2000 clears the area starting at D0000h for a 20000h section of RAM.
DEVICE=USE_UMBS.SYS initializes the UMB blocks. This driver works best when initializing an entire 128KB block.
I am not sure how the driver works, but I did find the source code, which might help you understand what happens:
;-------------------------------------------------------------------
;
; PROGRAM Use!UMBs.sys - UMB manager for PC/XT/ATs
;
; PURPOSE This program creates a device driver that will handle
; calls for Upper Memory Blocks. In doing so, it gives
; you the possibility to save conventional memory by
; storing device drivers and resident programs in the
; UMBs and hence save conventional memory.
;
; REQUIRES It will work on any PC/XT/AT or higher, either with or
; without extended memory. What you obviously *must* have
; are UMBs, and MS-DOS Version 5.0.
;
; AUTHOR Marco van Zwetselaar Phone: **-31-30-313128
; Oorsprongpark 5 FidoNet: Marco van.Zwetselaar
; 3581 ES Utrecht NetMail 2:281/701
; The Netherlands Utrecht, 7 Nov 1991
;
;-------------------------------------------------------------------
;
; IMPORTANT NOTE to the programmer
;
; I am only a beginner in assembly language, and haven't found out
; as yet how to create a .com file. When you recompile this program,
; take care you do that as a com file, and then rename it to a .sys
; file.
;
; I used an alternative method that you may use as well: I compiled
; it to .exe format and then removed the first (half?) sector. In
; fact, the first bytes in the final file should be:
;
; FF FF FF FF 00 E0 ...
;
; which are the bytes that start at nextDev. (Almost any device
; driver file should start with the first two words being FFFF (-1)).
;
;====================================================================
;
; THE ACTUAL ASSEMBLY CODE
;
;---------------------------------------------
; This is the structure of the request header; not stored in file
;
rh segment at 0
org 02h
rh_cmd db ? ;command-code
rh_status dw ? ;return-code
org 0Eh
rh0_brk_ofs dw ? ;end of driver offset
rh0_brk_seg dw ? ;end of driver segment
rh ends
;
;--------------------------------------------
; The driverheader
org 0h
zwetsUMB segment public
assume cs:zwetsumb, es:rh, ds:nothing
; any device driver will start with the following info:
next_dev dd -1
attribute dw 0E000h
strategy dw strat
interrupt dw intr
dev_name db 'I_LOVE_M'
;--------------------------------------------
; Storage space for pointer to Request Header
hdrptr label word
dw ?,?
;--------------------------------------------
; Strategy: store pointer to Request Header:
strat proc far
mov [hdrptr],bx
mov [hdrptr]+2,es
retf
strat endp
;--------------------------------------------
; Interrupt: The routine that fires the installrequest
intr proc far
push ax
push bx
push es
pushf
les bx, dword ptr [hdrptr] ;point es:bx to ReqHeader
mov [bx].rh0_brk_seg, cs ;and already return the seg
; Remember that the device will only answer the init-request
; which is called by dos as it installs the driver.
; Any later calls will be ignored - they are not needed anyway.
mov al, es:[bx].rh_cmd ;commandcode into al
or al, al ;is it 0 (=init)?
jnz other ; no => get off
jmp inst ; yes => install
other: cmp al, 10h ;is it legal call?
jbe short dos ; yes => "Sorry"
mov ax, 8003h ; no => "Unknown command"
jmp short exit
dos: xor ax, ax ;"Sorry - not implememented"
exit: or ax, 0100h ;Set done bit
mov es:[bx].rh_status, ax ;set return code
popf
pop es
pop bx
pop ax
retf ; back to dos
intr endp
;------------------------------------------------------
; Storage space for the addresses of free umb blocks
umb struc
start dw ?
len dw ?
umb ends
;you can add to the following list, as long as the last one is 0,0
free umb <0D000h, 1FFFh> ;my only block (at d000, length 1fff)
umb <0, 0> ;space for extra block
umb <0, 0> ;and another block
umb <0, 0> ;The end of the blocks is marked
; with 0,0 DON'T REMOVE THIS!!!!!
;------------------------------------------------------
; This is the code for the actual UMB memory provider
umbreq proc near
push ds
push si
push cx
push bx
push cs
pop ds
mov si, offset free
xor cx, cx ;clear dx and use it to compare
xchg dx, cx ;to largest found as yet - cx=size
search: lodsw ;read startsegment into ax
or ax, ax ;is it 0
jz fini ; then buzz off
mov bx, ax ; otherwise store into bx
lodsw ;read length in ax
cmp bx, 0FFFFh ;is startsegm=ffff=given away
je search ; yes: then find next block
cmp dx, ax ; no: larger than largest upto now?
jae szchk ; no: check size
mov dx, ax ; yes: mark as largest
szchk: cmp cx, ax ;will it fit?
ja search ; no: search next
; YEAH! Found a block
mov [si-4], 0FFFFh ; mark as used
mov dx, ax ; put blocksize in dx
mov ax, 1 ;say Succes
pop cx ;still had bx on stack
jmp short return
fini: xor ax, ax ;no fitting UMB
or dx, dx ;is dx=0?, so largest found=0
jnz sizerr ; if not: problem with size
pop bx ; if yes: BH should stay intact
mov bl, 0B1h ; and BL signals: out of UMBs
jmp short return
sizerr: pop bx ;BH remains intact
mov bl, 0B0h ;BL signals: there are smaller ones
return: pop cx
pop si
pop ds
popf
retf
umbreq endp
;------------------------------------------------------
; Storage space for old XMS-handler. The first byte stores WHETHER there
; was an XMS handler already (that didn't provide UMB services).
; The next two words specify its location.
isoldx db 00h
oldxms label word
dw ?,?
;------------------------------------------------------
; This is the small XMS manager that we install. It will only react
; to requests for UMBs (so when AH=10h). If not, it *should* pass
; control to the existing XMS manager - provided there is one. Or
; otherwise inform the caller that there is no eXt memory.
assume es:nothing, ds:nothing
umbctrlr:
jmp short hookch ;MUST be a *short* jmp
nop ; The nops are there because
nop ; a himem handler always start
nop ; with 5 special bytes.
hookch: pushf
cmp ah, 10h ;is it a UMB request?
je umbreq ; yes: execute it
cmp [isoldx], 0h ; no: is there an XMS-handler?
jz Xreq1 ; no: give response like it
popf ; yes: jump to old handler
jmp dword ptr cs:[oldxms]
; Below is the code that will respond to non-UMB (and thus XMS-)
; requests when no XMS-manager is present. To nearly all requests
; (there are 11h) it will answer with AX=0000, meaning failure
; and BL=80, which gives the errormessage: not implemented.
; Only fns 00h and 08h are treated specially (as well as fn 10h, but
; that has been filtered out above - it's the UMB-request).
Xreq1: cmp ah, 0h ;req 00h = get XMS version
jnz Xreq2
mov bx, 0h ; ->internal revision nr=0
mov dx, 0h ; ->HMA not present
jmp short byebye
Xreq2: cmp ah, 08h ;req 08h = query extended mem
jnz Xreq3
mov dx, 0h ; ->0k extended memory
Xreq3: mov bl, 80h ; ->error: not implemented
byebye: mov ax, 00h ; ->failure (always the case)
popf
retf
;------------------------------------------------------
; Storage space for old interrupt vector 2f
old2f label word
dw ?,?
;-------------------------------------------------------
; This is the code that is chained to the front of interrupt 2f.
; It will handle requests nrs. 4300 and 4310, and leave all others
; to the existing code.
handl: pushf
cmp ah, 43h ;is request for HIMEM?
jne not4me ; no: pass on
cmp al, 10h ; is request: where is handler?
jne mustbe ; if not, then must be al=00
mov bx, offset umbctrlr ; put handler's ofs in bx
push cs ; and its segment
pop es ; in es
jmp short getout
mustbe: mov al, 80h ;al <>10 so must be 00, so request
;is: is there handler? Yes => 80h
getout: popf
iret
not4me: popf ;request wasn't for me
jmp dword ptr cs:[old2f] ;so give back to old handl
;=================================================================
;
; NON-RESIDENT PART
;
; The part that follows now will not remain resident. It will be
; executed only once: at the time the driver is installed by
; DOS' bootprocedures.
;
; This code takes care of (1) hooking our intercepting code to
; int 2f, (2) hooking our small XMS-manager to the already installed
; one - provided there is one, (3) and if not, installing the
; the response-robot that will inform callers that there's no eXt
; memory.
;
;-------------------------------------------------------
; Installation routine. Called once.
assume ds:zwetsUMB, es:rh
inst: push cx ;save em
push dx
push ds
push cs ;and set ds to cs
pop ds
mov ah, 09h
mov dx, offset hello1$ ;say welcome
int 21h
mov dx, offset empty$
int 21h
mov dx, offset hello2$
int 21h
mov dx, offset empty$
int 21h
mov dx, offset hello3$
int 21h
mov dx, offset hello4$
int 21h
mov dx, offset empty$
int 21h
mov dx, offset autho1$
int 21h
mov dx, offset autho2$
int 21h
mov dx, offset empty$
int 21h
mov ax, 4300h ;check if there is an XMShandler
int 2Fh ;already
cmp al, 080h ;is it there?
jne SetVec ; no: go further
mov [isoldx],01h ;signal yourself there is one
mov ax, 4310h ;get its address
int 2Fh
mov [oldxms], bx ;and store it
mov [oldxms+2], es
mov ah, 09h ;tell user
mov dx, offset found$
int 21h
mov dx, offset empty$
int 21h
mov ah, 10h ;check if it services UMBs by
mov dx, 0FFFFh ;trying to allocate FAR TOO much
call dword ptr [oldxms]
cmp bl, 80h ;error: not implemented?
jz SetVec ; then good - continue
mov ah, 09h ;otherwise: get off,
mov dx, offset oops$ ;you're not needed.
int 21h
les bx, dword ptr [hdrptr]
xor ax,ax
mov es:[bx].rh0_brk_ofs, ax
jmp short dexit
SetVec: mov ax, 352Fh ; get vector 2f
int 21h
mov [old2f], bx ;and store it
mov [old2f]+2, es
mov ax, 252Fh ;set it to our own
mov dx, offset handl
int 21h
mov ah, 09h
mov dx, offset instok$ ;say we did it
int 21h
mov ax, offset inst ;upto inst it should stay
les bx, dword ptr [hdrptr] ; resident, which we tell
mov es:[bx].rh0_brk_ofs, ax ; dos via the rqhdr.
xor ax,ax ;0 no errors
dexit: pop ds
pop dx
pop cx
jmp exit
hello1$ db 0Dh,0Ah,'ÕÍÍÍÍÍÍÍÍÍÍÍÍÍ͵ Use!UMBs ÆÍÍÍÍÍÍÍÍÍÍÍÍ͸',0Dh,0Ah,'$'
empty$ db '³ ³',0Dh,0Ah,'$'
hello2$ db '³ Upper Memory Block - Manager ³',0Dh,0Ah,'$'
hello3$ db '³ Works on any PC/XT/AT, either with or ³',0Dh,0Ah,'$'
hello4$ db '³ without Extended or Expanded Memory! ³',0Dh,0Ah,'$'
found$ db '³ * found extended memory manager * ³',0Dh,0Ah,'$'
autho1$ db '³ Author: Marco van Zwetselaar ³',0Dh,0Ah,'$'
autho2$ db "³ dedicated it to the Public Domain 1991 ³",0Dh,0Ah,'$'
instok$ db 'ÔÍ͵ Version 2.0 ÆÍÍÍÍÍÍÍÍÍ͵ Installed! ÆÍ;',0Dh,0Ah,0Ah,'$'
oops$ db 'Ô͵ Not Installed! UMBs Managed Already! Æ;',0Dh,0Ah,0Ah,'$'
zwetsUMB ends
endWhat is happening with Norton Commander is even more confusing because I can't really see what is happening there. The program opens and shows the directory windows as expected, however it's not possible to do any operations in the program. However it's not frozen or anything, I can hear some sounds while pressing keys on the keyboard. Only after further crashing I saw the PC finally halted.
The schematic is here in the root directory so you can see there how I have done this design. If you need me to explain anything please let me know.
Functionally it's the same as a Turbo XT PC, and there is no PC chipset present, it's all done in logic ICs.
The turbo mode should be enabled at POST, which is done by outputting PB2 to high level in my hardware. This also lights up the turbo LED I believe this is somewhat standard because it worked on the phatcode BIOS without any modification.
I have done further testing by including the HD floppy BIOS into my EPROM image, and this now works properly to read, write and format all types of floppy disks. Nice to see that the HD floppy BIOS seems to work better with the GLaBIOS and nice to see the two floppy drives detected message. Switching between the HD and DD floppy BIOS also can be seen in the BIOS messages to change the floppy drive type.
The program TEST!UMB.EXE from the same maker as USE_UMBS.SYS does indicate it finds RAM at "paragraph" D000 until EFFF, only the USE_UMBS.SYS doesn't initialize any UMB blocks anymore.
I have tested by disabling the UMBs by removing the jumpers, this does not change anything with the Norton Commander problem. I have tested with MSD which does not complete the "examining your system" phase.
What I know about the Norton Commander is that it needs at least a V20 CPU to function. Using an 8088, Norton Commander doesn't work.
Turbo switching works properly, I have tested this with a CPU speed test, and I also can see the LED go on and off which definately also shows that the fast CPU clock is switched on and off properly. The default to enable turbo mode is also correct at power on.
The LAN adapter, SCSI disk and CDROM access and windows 3.0 all work properly.
So at the moment I am only experiencing problems with the TOGGLE.COM program, Norton Commander and USE_UMBs.SYS. Also, MSD doesn't seem to complete its examination of the system and keeps flashing the message it's still examining.
I am using the file "GLABIOS_0.2.4_VT.ROM" in my tests.
If you have any questions, please feel free to ask me.
Thanks for offering your help, I appreciate it very much.
Rodney
640-KB
Hi Rodney,
First of all congrats on releasing this - it looks extremely cool and is something I'd definitely like to build. :)
Anyway, I'm the author of GLaBIOS and i387DX on TRW Discord suggested maybe we connect about hardware/BIOS compatibility? I'm always adding hardware support for new projects so would love to be part of this.
Happy to talk here, or are you on Discord?
640KB