Bug : Date

[b2d3c]

In http://data.performing-arts.ch/r/8e34ed6a-559a-4813-8819-21339e08640b

we can't save modification because of a date bug.

We have already try to delete double Date but the warning is still remaining.

Could you see where it's come from?

Thanks in adance!

[fkraeutli]

There seem to be two record parts where something is off. One of which is http://data.performing-arts.ch/r/7de23c2b-9754-40de-9001-362c6682047f. I'm investigating

[fkraeutli]

The issue is not with the processing date but with the generic date. There are two record parts that have a date entity but where that entity lacks a type. The switch form requires the entities to have a type.

The record parts in question are:

• http://data.performing-arts.ch/x/2bccbc7b-30d5-492c-b591-0d11483c89a0
• http://data.performing-arts.ch/x/f6dddda3-50ff-4756-bf6a-c667c6484b87

  PREFIX spao: <http://ontology.performing-arts.ch/>
  PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
  SELECT * WHERE {
  BIND(<http://data.performing-arts.ch/r/8e34ed6a-559a-4813-8819-21339e08640b> as ?record)
  ?recordPart rico:isOrWasConstituentOf ?record .
  ?recordPart rico:isAssociatedWithDate ?value .
  OPTIONAL {
  ?value a ?type .
  }
  }    

There are some more record parts where this issue appears. You can find them with this query:

PREFIX spao: <http://ontology.performing-arts.ch/>
PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
SELECT * WHERE {
  ?record a rico:Record .
  ?recordPart rico:isOrWasConstituentOf ?record .
  ?recordPart rico:isAssociatedWithDate ?value .
  FILTER NOT EXISTS {
    ?value a ?type .
  }
}

[fkraeutli]

Note that it is visible in the form where the date fields are not loading:

[b2d3c]

Thanks Florian.

Could you add the date type in this Parts and also in the others with the same Issue you have fund?

Thanks in advance

[fkraeutli]

Query:

PREFIX spao: <http://ontology.performing-arts.ch/>
PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
INSERT {
  GRAPH ?g {
    ?value a <https://www.ica.org/standards/RiC/ontology#SingleDate>
  }
} WHERE {
  ?record a rico:Record .
  ?recordPart rico:isOrWasConstituentOf ?record .
  GRAPH ?g {
    ?recordPart rico:isAssociatedWithDate ?value .
  }
  FILTER NOT EXISTS {
    ?value a ?type .
  }
}

[fkraeutli]

Done

[b2d3c]

Thanks !