[BUG-232261] llSitOnLink() breaks sit targets when targeting an agent while they are teleporting. llAvatarOnSitTarget() continues to return a key with no sitter. Sitting is then blocked.

Information

Rez a cube and save the following script with an experience that you have allowed on your person and over the land you will be testing with:

Sit(key k)
{
    integer i;
    if ((i = llSitOnLink(k,llGetLinkNumber())) == 1)
    {
        llSay(0,"llSitOnLink(" + (string)k + ") = " + (string)i + ", llAvatarOnSitTarget() = " + (string)llAvatarOnSitTarget());
    }
    else
    {
        llSay(0,"llSitOnLink(" + (string)k + ") = " + (string)i + "(" + llList2String([
            "This script is not running as part of an experience.",
            "You are not participating in the experience.",
            "Unable to find an open sit target.",
            "Unable to find you.",
            "Unable to find specified link.",
            "You are not allowed on the parcel.",
            "This is not a valid sit object.",
            "Unknown sit error " + (string)i + " has occurred."],llListFindList([-1,-2,-3,-4,-5,-6,-7],[i])) + "), llAvatarOnSitTarget() = " + (string)llAvatarOnSitTarget());
    }
}
key last_sitter = NULL_KEY;
default
{
    state_entry()
    {
        llSetLinkPrimitiveParamsFast(LINK_SET,[PRIM_SIT_TARGET,TRUE,<0.0,0.0,-0.35>,ZERO_ROTATION]);
    }
    on_rez(integer i)
    {
        llResetScript();
    }
    touch_end(integer i)
    {
        key dk = llDetectedKey(0);
        llSay(0,"touch_end() - llAvatarOnSitTarget() = " + (string)llAvatarOnSitTarget() + ", Sitting " + (string)dk);
        Sit(dk);
    }
    changed(integer i)
    {
        if (i & CHANGED_LINK)
        {
            key ast = llAvatarOnSitTarget();
            if (ast)
            {
                llSay(0,"changed(" + (string)i + ") llAvatarOnSitTarget() = " + (string)ast);
                last_sitter = ast;
            }
            else if (last_sitter)
            {
                float f = llFabs((float)llGetObjectDesc());
                llSleep(f);
                llSay(0,"changed(" + (string)i + ") llAvatarOnSitTarget() = " + (string)ast + ", llSleep() = " + (string)f + ", llGetAgentSize() = " + (string)llGetAgentSize(last_sitter) + ", Sitting " + (string)last_sitter);
                Sit(last_sitter);
            }
        }
    }
}

Have an alt present so they can see the test chat results since you yourself might not.

Click the object. You should be sat. Now, while sitting, teleport to a different region.

Return back to the region you teleported from and click the object. It should tell you that there are no open sit targets. llAvatarOnSitTarget() now returns your key and will continue to do so until the region is restarted even if the script is reset or the sit target is updated/removed.

Alternatively, change sleep value by updating object desc.

Sleeps of 0.5 seconds or greater seem to deter the condition, but it is unknown if that works for everyone, especially those with more attachments.

The following alternative method also repros (put a landmark to a different region in the object's inventory and click):

Sit(key k)
{
    integer i;
    if ((i = llSitOnLink(k,llGetLinkNumber())) == 1)
    {
        llSay(0,"llSitOnLink(" + (string)k + ") = " + (string)i + ", llAvatarOnSitTarget() = " + (string)llAvatarOnSitTarget());
    }
    else
    {
        llSay(0,"llSitOnLink(" + (string)k + ") = " + (string)i + "(" + llList2String([
            "This script is not running as part of an experience.",
            "You are not participating in the experience.",
            "Unable to find an open sit target.",
            "Unable to find you.",
            "Unable to find specified link.",
            "You are not allowed on the parcel.",
            "This is not a valid sit object.",
            "Unknown sit error " + (string)i + " has occurred."],llListFindList([-1,-2,-3,-4,-5,-6,-7],[i])) + "), llAvatarOnSitTarget() = " + (string)llAvatarOnSitTarget());
    }
}
default
{
    state_entry()
    {
        llSetLinkPrimitiveParamsFast(LINK_SET,[PRIM_SIT_TARGET,TRUE,<0.0,0.0,-0.35>,ZERO_ROTATION]);
    }
    on_rez(integer i)
    {
        llResetScript();
    }
    touch_end(integer i)
    {
        key k = llDetectedKey(0);
        if (llGetInventoryNumber(INVENTORY_LANDMARK))
        {
            llSay(0,"llRequestExperiencePermissions(" + (string)k + ")");
            llRequestExperiencePermissions(k,"");
        }
        else
        {
            llSay(0,"No landmarks in inventory...");
        }
    }
    experience_permissions(key k)
    {
        if (llAvatarOnSitTarget())
        {
            llSay(0,"experience_permissions() llAvatarOnSitTarget() = " + (string)llAvatarOnSitTarget());
            return;
        }
        float f = llFabs((float)llGetObjectDesc());
        llSay(0,"experience_permissions() llTeleportAgent(" + (string)k + ")");
        llTeleportAgent(k,llGetInventoryName(INVENTORY_LANDMARK,0),ZERO_VECTOR,ZERO_VECTOR);
        llSleep(f);
        llSay(0,"experience_permissions() llAvatarOnSitTarget() = " + (string)llAvatarOnSitTarget() + ", llSleep() = " + (string)f + ", llGetAgentSize() = " + (string)llGetAgentSize(k) + ", Sitting " + (string)k);
        Sit(k);
    }
    experience_permissions_denied(key k, integer i)
    {
        llSay(0,"experience_permissions_denied(" + (string)k + ") Reason(" + (string)i + "): " + llGetExperienceErrorMessage(i));
    }
}

Links

[ ] https://github.com/secondlife/jira-archive/issues/12233

Original Jira Fields

| Field | Value | | ------------- | ------------- | | Issue | BUG-232261 | | Summary | llSitOnLink() breaks sit targets when targeting an agent while they are teleporting. llAvatarOnSitTarget() continues to return a key with no sitter. Sitting is then blocked. | | Type | Bug | | Priority | Unset | | Status | Accepted | | Resolution | Triaged | | Reporter | Lucia Nightfire (lucia.nightfire) | | Created at | 2022-06-14T04:11:23Z | | Updated at | 2022-06-14T17:00:59Z | ``` { 'Build Id': 'unset', 'Business Unit': ['Platform'], 'Date of First Response': '2022-06-14T11:07:17.673-0500', 'ReOpened Count': 0.0, 'Severity': 'Unset', 'System': 'SL Simulator', 'Target Viewer Version': 'viewer-development', 'What just happened?': 'Rez a cube and save the following script with an experience that you have allowed on your person and over the land you will be testing with:\r\n\r\nScript\r\n\r\nClick the object.\r\nYou should be sat.\r\nNow, while sitting, teleport to a different region.\r\n\r\nReturn back to the region you teleported from and click the object.\r\nIt should tell you that there are no open sit targets.\r\nllAvatarOnSitTarget() now returns your key and will conitue to do so until the region is restarted.', 'What were you doing when it happened?': '?', 'What were you expecting to happen instead?': '?', } ```

secondlife / jira-archive

[BUG-232261] llSitOnLink() breaks sit targets when targeting an agent while they are teleporting. llAvatarOnSitTarget() continues to return a key with no sitter. Sitting is then blocked. #9571

Information

Links

Related