provide aur pre-release package for arch linux

[shivambegin]

it would be much easier to test and use beta/pre-release it there is a aur pakage for it on arch linux .

[subframe7536]

Apologize for my lack of experience...

PR welcome

[Cyberczy]

I wrote a PKGBUILD, and it works on my Arch WSL. Could you please test it as well? Additionally, for the next pre-release, could you change 7.0-beta25 to 7.0_beta25? The pkgver in PKGBUILD does not allow -, and this would greatly facilitate packaging.

我写了一个PKGBUILD，它可以在我的 Arch WSL 上工作。你能测试一下吗？ 此外，对于下一个预发行版，您能否将7.0-beta25更改为7.0_beta25？ PKGBUILD中的pkgver不允许出现-，这将极大地方便打包。

pkgname=ttf-maple-beta
pkgver="7.0_beta24"
pkgrel=1
pkgdesc="Open source monospace font with round corner, ligatures and Nerd-Font for IDE and command line"
arch=("any")
url="https://github.com/subframe7536/maple-font"
license=("OFL")
source=("$pkgname-$pkgver-MapleMono-TTF.zip::https://github.com/subframe7536/Maple-font/releases/download/v7.0-beta24/MapleMono-TTF.zip"
        "$pkgname-$pkgver-MapleMono-NF.zip::https://github.com/subframe7536/Maple-font/releases/download/v7.0-beta24/MapleMono-NF.zip"
        "$pkgname-$pkgver-MapleMono-NF-CN.zip::https://github.com/subframe7536/Maple-font/releases/download/v7.0-beta24/MapleMono-NF-CN.zip"
        "$pkgname-LICENSE::https://raw.githubusercontent.com/subframe7536/Maple-font/main/OFL.txt")
sha256sums=('1a1891dfd4499cf7406b48f787e99937dcffa7cbfac49cc756b2ac8b539890ee'
            '219d84def6477d861c5995ac1ebfb794a6228fd0fbe32a7be24f0a6c038f05ad'
            'e115e667b9cc5c134c89b6cbb29629cc1802227b523b454f380465615fb07b08'
            'cdb01cb2c0ac2d618ad3fc082275cf3cbe6145a58d558709ec083ce69c702cf0')

package() {
    install -d "${pkgdir}/usr/share/fonts/$pkgname"
    install -d "${pkgdir}/usr/share/licenses/$pkgname/"
    install -Dm0644 "${srcdir}/MapleMono-"*".ttf" "${pkgdir}/usr/share/fonts/$pkgname/"
    install -Dm0644 "$pkgname-LICENSE" "${pkgdir}/usr/share/licenses/$pkgname/"
}

[subframe7536]

@Cyberczy According to the Wiki, you can easily handle - for file path

ps: I originally thought that the version number I published was go with semantic version control, but now that I've looked into the specs, I realized that the pattern should be v7.0.0-beta.24 instead of v7.0-beta24...

[Cyberczy]

我去试试lol

[Cyberczy]

Done.

pkgname=ttf-maple-beta
pkgver="7.0_beta24"
pkgrel=1
pkgdesc="Open source monospace font with round corner, ligatures and Nerd-Font for IDE and command line"
arch=("any")
url="https://github.com/subframe7536/maple-font"
license=("OFL")
conflicts=(ttf-maple)
source=("$pkgname-${pkgver//_/-}-MapleMono-TTF.zip::$url/releases/download/v${pkgver//_/-}/MapleMono-TTF.zip"
        "$pkgname-${pkgver//_/-}-MapleMono-NF.zip::$url/releases/download/v${pkgver//_/-}/MapleMono-NF.zip"
        "$pkgname-${pkgver//_/-}-MapleMono-NF-CN.zip::$url/releases/download/v${pkgver//_/-}/MapleMono-NF-CN.zip"
        "$pkgname-LICENSE::https://raw.githubusercontent.com/subframe7536/maple-font/main/OFL.txt")
sha256sums=('1a1891dfd4499cf7406b48f787e99937dcffa7cbfac49cc756b2ac8b539890ee'
            '219d84def6477d861c5995ac1ebfb794a6228fd0fbe32a7be24f0a6c038f05ad'
            'e115e667b9cc5c134c89b6cbb29629cc1802227b523b454f380465615fb07b08'
            'cdb01cb2c0ac2d618ad3fc082275cf3cbe6145a58d558709ec083ce69c702cf0')

package() {
    install -d "${pkgdir}/usr/share/fonts/$pkgname"
    install -d "${pkgdir}/usr/share/licenses/$pkgname/"
    install -Dm0644 "${srcdir}/MapleMono-"*".ttf" "${pkgdir}/usr/share/fonts/$pkgname/"
    install -Dm0644 "$pkgname-LICENSE" "${pkgdir}/usr/share/licenses/$pkgname/"
}

[Cyberczy]

https://aur.archlinux.org/packages/ttf-maple-beta

[shivambegin]

thanks @Cyberczy @subframe7536