NixOS rebuild fails

[Asten-Valentinus]

When trying to rebuild with kwin-effects-forceblur, it reports an issue with it.

Here is the error result with --show-trace.

My NixOS configuration does not report any errors when I exclude kwin-effects-forceblur.

I am not that experienced with NixOS, so sorry if the solution is something obvious.

[taj-ny]

Are you using flakes?

[Asten-Valentinus]

Yes, and I've made sure to install the package as described in the readme.

[taj-ny]

Post your flake.nix and the file where you're adding the effects to system packages.

[Asten-Valentinus]

Here they are.

[taj-ny]

Add specialArgs = { inherit inputs; }; to outputs.nixosConfigurations.nixos in flake.nix.

{
  description = "My NixOS system flake";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    kwin-effects-forceblur = {
      url = "github:taj-ny/kwin-effects-forceblur";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { self, nixpkgs, home-manager, ... }@inputs: {
    nixosConfigurations = {
      nixos = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        specialArgs = { inherit inputs; };
        modules = [
          ({config, pkgs, ...}: {
            nixpkgs.overlays = [
              (final: prev: { blender = prev.blender.override { cudaSupport = true; }; })
            ];
          })

          home-manager.nixosModules.home-manager
          {
            home-manager = {
              useGlobalPkgs = true;
              useUserPackages = true;
              backupFileExtension = "backup"; # Seems to solve some errors
              users = {
                user1 = import ./home-manager/user1.nix;
                user2 = import ./home-manager/user2.nix;
              };
            };
          }

          ./hardware-configuration.nix
          ./configuration.nix
        ];
      };
    };
  };
}

[Asten-Valentinus]

Alright, thanks! I'll try that out!

[Asten-Valentinus]

Works as expected now. Thanks for the help!