fixes.inc

Community patches for buggy SA:MP functions.

Introduction

SA:MP is beta software written by a small team in their spare time, thus it has bugs (as does all software). Some of these have been known for a long time but are low priority due to their minor effects, others go undiscovered for a long time. Many of these bugs have solutions which can be implemented in PAWN (and this may be simpler than implementing them in the SA:MP source code). This include aims to collect fixes for as many of these bugs as possible from the community (i.e. anyone who has a fix) together in to one easy to use place for everyone's benefit.

Use

This library is a single-file include. The only required part is:

https://raw.githubusercontent.com/pawn-lang/sa-mp-fixes/master/fixes.inc

Save this file as pawno/include/fixes.inc then include it after the default SA:MP functions, but before third party includes:

#include <a_samp>
// Any default re-definitions should go here.
//#undef MAX_PLAYERS
//#define MAX_PLAYERS 10
#include <fixes>

#include <other>

To disable any fix for whatever reason simply do:

#define FIX_<name> 0

For example, to disable all the file.inc fixes if you always correctly check the file handle, do:

#include <a_samp>
#define FIX_file_inc 0
#include <fixes>
#include <other>

All the names of the fixes are single words, and are all listed with their fix descriptions below.

If you only have one script running on your server (i.e. no FilterScripts), you can use this define to improve the fixes.inc code:

#include <a_samp>
#define FIXES_Single 1
#include <fixes>
#include <other>

See below for more configuration settings.

If you use sampctl the inclusion path to go under dependencies is:

"pawn-lang/sa-mp-fixes"

You can also download the entire repo using git, and will get a more complete experience, including better warnings and this documentation.

Fix Options

A few fixes are disabled by default, to enable them all do:

#define FIX_GetPlayerDialog 1
#define FIX_file_inc 1
#define FIX_random 1
#define FIX_HideMenuForPlayer_2 1
#define FIX_GameTextStyles 1
#define FIX_GetPlayerWeather 1
#define FIX_GetWeather 1
#define FIX_GetWorldTime 1

Settings

There are a few settings for improved execution of this script. Define these symbols as 1 before you include fixes.inc to explicitly enable them, 0 to explicitly disable them.

• FIXES_ExplicitSettings: Require settings to be explicitly enabled or disabled, and show a warning for every setting not mentioned. Default 0 for now.
• FIXES_EnableAll: Enable everything, even things that probably shouldn't be enabled. Default 0.
• FIXES_EnableDeprecated: Enable all deprecated fixes (those that are no longer needed because they were fixed in later server revisions). Might causes errors and conflicts with newer SA:MP includes. Default 0.
• FIXES_DefaultDisabled: Disable all fixes by default, and require them to be individually enabled with #define FIX_<name> 1 Default 0.
• FIXES_ExplicitOptions: Require fixes to be explicitly enabled or disabled, and show a warning for every fix not mentioned. Useful in combination with FIXES_DefaultDisabled, so default 1 with that, 0 otherwise.
• FIXES_SilentKick: If this define is set to 1, then players will not be given a message when they are kicked for cheats (mainly invalid vehicles and mods), instead they will just loose connection to the server. Default 0.
• FIXES_Debug: If this define is set to 1, then debug printing is turned on for any functions which may use it. Otherwise, the compiler entirely removes the code to print anything, leaving no run-time overhead. Default 0.
• FIXES_Single: If this define is set to 1, then the old style include is used, with no support for multiple scripts running at the same time on the server. You only have one script that uses fixes.inc running (no other gamemodes or filterscripts). Using this define will vastly simplify the code in that case, as no cross-script communication is required, but will cause bugs if there actually is another script running. Default 1.
• FIXES_NoSingleMsg: Hide a message at mode start if FIXES_Single is set, but this is NOT the only script running fixes.inc. This will entirely disable the check, so should only be used if you are absolutely certain that no other scripts are running at the same time (gamemodes or filterscripts). Default 1.
• FIXES_NoServerVarMsg: If this define is set to 1, then the server will not give a message when GetServerVarAsString and related functions are used without a valid directory redirect. Default 1.
• FIXES_NoGetMaxPlayersMsg: If this define is set to 1, then the server will not give a message when GetMaxPlayers doesn't match MAX_PLAYERS. Default 1.
• FIXES_NoPawndoc: If this define is set to 1, then compiling with -r will attempt to hide as many of the functions and variables in fixes.inc from the output XML as possible. This will vastly simplify the generated documentation (at least the visible parts, this is done by embeddeding XML comments in the output, so all the data still exists, just hidden in the file). Default 0.
• FIXES_CorrectInvalidTimerID: You know that an invalid timer is ID 0, not -1, so exclude the excess code designed to warn about/detect people using -1. Default 0.
• FIXES_NoYSI: fixes.inc doesn't need YSI. YSI doesn't need fixes.inc. However, they are both written to be aware of each other and adapt accordingly. For example, fixes.inc uses a special type of ALS hooking which y_hooks can detect and use to call these callbacks in a better order (so-called "pre-hooks"). But if you don't have y_hooks the other version of ALS is very fractionally better. This define can thus be used to guarantee to fixes.inc that YSI doesn't exist and not to use any of the adapted code. However, if you're wrong the include probably just won't work, the overhead when not using YSI is absolutely tiny, and when using YSI its optimised out. So, if in doubt - don't use this. Default 0.
• FIXES_OneRandomVehicleColour: Most vehicles are created with two explicit colours (say 5, 6) or two random colours (-1, -1). It is allowed, but rare, to create a vehicle with one random colour and one fixed colour (-1, 5, 9, -1 etc). fixes.inc supports this, but it takes a lot more code to fix than the common case of all or nothing. Thus, having only one random colour is only supported with this explicit setting enabled. Default 0.
• FIXES_NoVehicleColourMsg: Hide a message at vehicle creation if FIXES_OneRandomVehicleColour is set, but a vehicle is created with only one random colour. Default 0.
• FIXES_CountFilterscripts: Load several filterscripts until one fails, to determine the number of previously loaded filterscripts. Default 1.
• FIXES_NoFilterscriptsMsg: Hide the message about loading filterscripts and the ignorable errors. Default 0.

Note that options are which fixes to include, and settings are more over-arching customisations.

Tags

Like the enhanced SA:MP includes (https://github.com/pawn-lang/samp-stdlib/tree/consistency-overhaul) fixes.inc upgrades many natives and callbacks to use more tags for better compile-time errors. These can be a little annoying to adapt your code to at first, but in the long run provide far more safety and information. Like the SA:MP includes there are WEAK_TAGS and STRONG_TAGS, but unlike there the default is none, i.e. most tags will simply be _: unless you're using the consistency overhaul includes as well. The one major exception to this is bool:, which has been added by default to many parameters which were previously _: but only accepted 0/1 and thus should have been false/true. This is the bool_tags fix and affects the following natives:

• native SetTimer(const functionName[], interval, bool:repeating);
• native SetTimerEx(const functionName[], interval, bool:repeating, const format[] = "", {Float, _}:...);
• native AddStaticVehicleEx(modelid, Float:spawnX, Float:spawnY, Float:spawnZ, Float:angle, colour1, colour2, respawnDelay, bool:addSiren = false);
• native ShowNameTags(bool:show);
• native EnableTirePopping(bool:enable);
• native AllowInteriorWeapons(bool:allow);
• native AllowAdminTeleport(bool:allow);
• native EnableZoneNames(bool:enable);
• native bool:IsPlayerNPC(playerid);
• native bool:IsPlayerAdmin(playerid);
• native bool:GetServerVarAsBool(const cvar[]);
• native bool:GetConsoleVarAsBool(const cvar[]);
• native bool:IsValidMenu(Menu:menuid);
• native TextDrawUseBox(Text:text, bool:use);
• native TextDrawSetProportional(Text:text, bool:set);
• native TextDrawSetSelectable(Text:text, bool:set);
• native Text3D:Create3DTextLabel(const text[], colour, Float:x, Float:y, Float:z, Float:drawDistance, virtualWorld, bool:testLOS = false);
• native PlayerText3D:CreatePlayer3DTextLabel(playerid, const text[], colour, Float:x, Float:y, Float:z, Float:drawDistance, parentPlayerid = INVALID_PLAYER_ID, parentVehicleid = INVALID_VEHICLE_ID, bool:testLOS = false);
• native CreateVehicle(modelid, Float:x, Float:y, Float:z, Float:rotation, colour1, colour2, respawnDelay, bool:addSiren = false);
• native bool:IsVehicleStreamedIn(vehicleid, playerid);
• native bool:IsTrailerAttachedToVehicle(vehicleid);
• native bool:IsValidVehicle(vehicleid);
• native bool:DB_Close(DB:db);
• native bool:DB_FreeResult(DBResult:result);
• native bool:DB_NextRow(DBResult:result);
• native bool:DB_FieldName(DBResult:result, field, output[], size = sizeof (output));
• native bool:DB_GetField(DBResult:result, field, output[], size = sizeof (output));
• native bool:DB_GetFieldAssoc(DBResult:result, const field[], output[], size = sizeof (output));
• native bool:IsActorStreamedIn(actorid, playerid);
• native ApplyActorAnimation(actorid, const animationLibrary[], const animationName[], Float:delta, bool:loop, bool:lockX, bool:lockY, bool:freeze, time);
• native SetActorInvulnerable(actorid, bool:invulnerable = true);
• native bool:IsActorInvulnerable(actorid);
• native bool:IsValidActor(actorid);
• native AttachObjectToObject(objectid, parentid, Float:offsetX, Float:offsetY, Float:offsetZ, Float:rotX, Float:rotY, Float:rotZ, bool:syncRotation = true);
• native bool:IsValidObject(objectid);
• native bool:IsObjectMoving(objectid);
• native bool:IsValidPlayerObject(playerid, objectid);
• native bool:IsPlayerObjectMoving(playerid, objectid);
• native SetObjectMaterialText(objectid, const text[], materialIndex = 0, OBJECT_MATERIAL_SIZE:materialSize = OBJECT_MATERIAL_SIZE_256x128, const fontFace[] = "Arial", fontSize = 24, bool:bold = true, fontColour = 0xFFFFFFFF, backgroundColour = 0, OBJECT_MATERIAL_TEXT_ALIGN:textalignment = OBJECT_MATERIAL_TEXT_ALIGN_LEFT);
• native SetPlayerObjectMaterialText(playerid, objectid, const text[], materialIndex = 0, OBJECT_MATERIAL_SIZE:materialSize = OBJECT_MATERIAL_SIZE_256x128, const fontFace[] = "Arial", fontSize = 24, bool:bold = true, fontColour = 0xFFFFFFFF, backgroundColour = 0, OBJECT_MATERIAL_TEXT_ALIGN:textalignment = OBJECT_MATERIAL_TEXT_ALIGN_LEFT);
• native SetObjectsDefaultCameraCol(bool:disable);
• native bool:IsPlayerInRangeOfPoint(playerid, Float:range, Float:x, Float:y, Float:z);
• native bool:IsPlayerStreamedIn(targetid, playerid);
• native TogglePlayerClock(playerid, bool:toggle);
• native PlayAudioStreamForPlayer(playerid, const url[], Float:posX = 0.0, Float:posY = 0.0, Float:posZ = 0.0, Float:distance = 50.0, bool:usepos = false);
• native bool:IsPlayerAttachedSlotUsed(playerid, index);
• native PlayerTextDrawUseBox(playerid, PlayerText:text, bool:use);
• native PlayerTextDrawSetProportional(playerid, PlayerText:text, bool:set);
• native PlayerTextDrawSetSelectable(playerid, PlayerText:text, bool:set);
• native TogglePlayerControllable(playerid, bool:toggle);
• native ApplyAnimation(playerid, const animationLibrary[], const animationName[], Float:delta, bool:loop, bool:lockX, bool:lockY, bool:freeze, time, FORCE_SYNC:forceSync = _FIXES_FORCE_SYNC_NONE);
• native DisableRemoteVehCollisions(playerid, bool:disable);
• native ShowPlayerNameTagForPlayer(playerid, targetid, bool:show);
• native AllowPlayerTeleport(playerid, bool:allow);
• native EnablePlayerCameraTarget(playerid, bool:enable);
• native bool:IsPlayerConnected(playerid);
• native bool:IsPlayerInVehicle(playerid, vehicleid);
• native bool:IsPlayerInAnyVehicle(playerid);
• native bool:IsPlayerInCheckpoint(playerid);
• native bool:IsPlayerInRaceCheckpoint(playerid);
• native EnableStuntBonusForPlayer(playerid, bool:enable);
• native EnableStuntBonusForAll(bool:enable);
• native TogglePlayerSpectating(playerid, bool:toggle);

You can also see several additional tags in those definitions, such as OBJECT_MATERIAL_SIZE: but as stated they are optional.

If you are using WEAK_TAGS or STRONG_TAGS there is a minor problem - callbacks give an error:

forward OnPlayerStateChange(playerid, PLAYER_STATE:newstate, PLAYER_STATE:oldstate);

public OnPlayerStateChange(playerid, newstate, oldstate)
{
}

This gives an error, when it should be fine. Fixing it in a mode is easy - just use the correct tags on the variables in the callbacks. Fixing it in a generic library needs a few extra lines to define a default tag when one isn't found (i.e. the user isn't using the improved includes):

#if !defined PLAYER_STATE
    // Use the default tag (none, `_:`) when the improved includes aren't found.
    #define PLAYER_STATE: _:
#endif
public OnPlayerStateChange(playerid, PLAYER_STATE:newstate, PLAYER_STATE:oldstate)
{
    return Hooked_OnPlayerStateChange(playerid, newstate, oldstate);
}

// Don't forget to use ALS as normal.
forward Hooked_OnPlayerStateChange(playerid, PLAYER_STATE:newstate, PLAYER_STATE:oldstate);

Keys And Actions

"Keys" have been renamed "Actions" because they aren't keys and the name constantly confused everyone. You can't detect "F" you can only detect "JUMP". You can't make any assumptions about which keys are bound to which actions. You can't ask players to press a specific key (except when using "~k~" in strings, which maps actions back to keys). You can't detect specific keys. No matter how many times this is explained the follow-up questions are invariably, "OK, but how do I detect this key?" You can't, and never could. Thus GetPlayerKeys has been replaced by GetPlayerActions, OnPlayerKeyStateChange has been replaced by OnPlayerActionStateChange, newkeys and oldkeys have been replaced by newactions and oldactions, and KEY has been replaced by ACTION (leading to the interestingly named macro ACTION_ACTION from KEY_ACTION):

// The `ACTION` tags are optional.
public OnPlayerActionStateChange(playerid, ACTION:newactions, ACTION:oldactions)
{
    new
        ACTION:actions,
        ACTION:updown,
        ACTION:leftright;
    GetPlayerActions(playerid, actions, updown, leftright);
    return 1;
}

API

fixes.inc includes a lot of data and processing that is required for it to function, but could be useful for other scripts - things like vehicle meta-data, current status of players, and more. While new functions are not the primary goal of this include, it seems silly to keep this information hidden when it can be used, forcing people to duplicate functionality just to do things like get a player's current dialog ID for example. The general rule is still not to add new functions, there are many other libraries for that; but if the data already exists thanks to the code being required for a fix, then it might as well be exposed.

Most of these additional functions are controlled by FIX_API, and can be tested for with FIXES_API, but some older ones have their own FIX_ definition (which now defaults to FIX_API).

GetDefaultPlayerColour(playerid)

Gets the default colour assigned to a player when they first connect. There are only 100 unique colours, which are repeated:

new colour = GetDefaultPlayerColour(playerid);
printf("The player's colour is %x", colour);

Note that you can also use the alias GetDefaultPlayerColor.

GetVehicleSeats(modelid)

Get the number of seats in the given vehicle type (model).

new seats = GetVehicleSeats(400);
printf("The landstalker has %d seats", seats);

bool:VehicleCanHaveComponent(modelid, componentid)

Returns true if the given vehicle type (model) can use the given component (mod) type.

if (VehicleCanHaveComponent(536, 1005))
{
    printf("The Blade can have the fury scoop");
}
else
{
    printf("The Blade cannot have the fury scoop");
}

bool:IsValidAnimationLibrary(const snimlib[])

Returns true if the named animation library exists.

if (IsValidAnimationLibrary("parkour")
{
    printf("`parkour` is a valid animation library");
}
else
{
    printf("`parkour` is not a valid animation library");
}

bool:GetRandomCarColPair(modelid, &colour1, &colour2, &colour3 = 0, &colour4 = 0)

Gets a random pair of colours for a vehicle (three vehicles have four colours), according to the predefined colour options in carcols.dat. These are the colours selected from when -1 is used as the colour of a vehicle (but the colours chosen are not synced by default).

new c1, c2;
GetRandomCarColPair(495, c1, c2);
printf("Colours chosen for the Sandking: %d, %d", c1, c2);

Note that the values returned are the COLOUR INDEXES, those passed to say CreateVehicle, they are not the HEX codes for the given colours.

GetPlayerDialog(playerid)

Get's the currently displayed dialog ID for a player.

new dialogid = GetPlayerDialog(playerid);
printf("Player %d is viewing dialog %d", playerid, dialogid);

GetPlayerWeather(playerid)

Get's the current weather ID for a player.

new weatherid = GetPlayerWeather(playerid);
printf("Player %d currently has weather %d", playerid, weatherid);

GetWeather()

Get's the current server global weather.

new weatherid = GetWeather();
printf("The server currently has weather %d", weatherid);

GetWorldTime()

Get's the current server global weather.

new time = GetWorldTime();
printf("The time on the server is currently %02d:00", time);

ClearPlayerWorldBounds(playerid)

Resets the world boundaries to their maximum, after using SetPlayerWorldBounds.

ClearPlayerWorldBounds(playerid);

GetPlayerWorldBounds(playerid, &Float:x_max, &Float:x_min, &Float:y_max, &Float:y_min)

Gets the world boundaries for a player, set by SetPlayerWorldBounds.

new
    Float:x_max,
    Float:x_min,
    Float:y_max,
    Float:y_min;
GetPlayerWorldBounds(playerid, x_max, x_min, y_max, y_min);
printf("Player %d's world boundaries are at (%.2f, %.2f) - (%.2f, %.2f)", x_min, y_min, x_max, y_max);

HideGameTextForAll(style)

Hide this type of gametext for all players.

HideGameTextForAll(3);

HideGameTextForPlayer(playerid, style)

Hide this type of gametext for one player.

HideGameTextForPlayer(playerid, 3);

bool:PlayerHasClockEnabled(playerid)

Does this player have auto-incrementing time enabled?

if (PlayerHasClockEnabled(playerid))
{
    printf("Time might have changed.");
}

bool:IsMenuValid(Menu:menuid)

Is the given menu ID valid?

if (IsMenuValid(menuid))
{
    printf("The menu was created at some point.");
}

CarColIndexToColour(index, alpha = 0xFF)

Convert from a vehicle colour index to an RGBA colour (with the specified alpha).

new c1, c2;
GetRandomCarColPair(495, c1, c2);
printf("Colours chosen for the Sandking: %08x, %08x", CarColIndexToColour(c1), CarColIndexToColour(c2));

Note that you can also use the alias CarColIndexToColor.

Tests

Other code and includes can test for certain fixes.inc symbols, to see what is defined and what isn't. These all use basic #if defined checks, with no need to test the value:

• FIXES_EXISTS: The include is used.
• FIXES_API: The additional API functions (see above) were defined and can be used.
• FIXES_USES_STATE_HOOKS: fixes.inc uses advanced state-based ALS hooks, not just regular ones.
• FIXES_CONST_CORRECT: The include is fully const-correct (and backwards-compatible).
• FIXES_TAG_CORRECT: The include is fully tag-correct (and backwards-compatible), i.e. optionally uses additional tags in callbacks such as OnPlayerStateChange.
• FIXES_PAWNDOC: The include has methods of hiding unwanted pawndoc declarations.
• FIXES_ID: The include defines the pubic variable @_, which is a unique ID for the current script. This is also defined by YSI if it isn't defined here.

Other Fixes

There are a few other includes which aim to fix issues too large to be included here:

• Timerfix - udan11 (Dan..) 's fixes to make "SetTimer" and "SetTimerEx" vastly more accurate in their delays.
• SQLitei - Slice 's fixes and improvements for many SQLite functions.

New Features

fixes.inc is not intended to add new features; however, it does add a few and detractors think it is funny to point to those as a good reason why the library is bad. The reason why is simple - they were added before the exact scope and definition of "fix" was determined. New features are not added any more, but existing features that were already added (most notably the new game text styles) are left in because removing them is more breaking than having them. Yes, they exist; no, they probably shouldn't; no, they wouldn't be added today; no, they won't be removed.

Bugs

Originally Posted by Y_Less :

[This] is beta software written by a small team in their spare time, thus it has bugs (as does all software). This software is explicitly designed to solve bugs, not cause them, but there may still be bugs.

The most likely cause of bugs is certain combinations of disabled fixes. Some fixes are inter-mixed and while they SHOULD work when the fixes they are combined with are disabled, not every combination has been tested. There are literally billions of possible combinations - if you find one that doesn't compile or work, please tell us.

Expansion

The file is fairly well documented, with a list of the currently (hopefully) fixed bugs at the top. If you know of others, or have solutions for others, it would be greatly appreciated if you could post them as issues on this repository. The fixes also need extensive testing to find bugs in the fixes themselves.

Again, this is a community project, merely managed by Y_Less and others - if anyone has comments, contributions, criticisms etc. please again post them as issues on the repository. This includes additions to source code, documentation, presentation, translations (mainly of this documentation - multiple versions of the include should be avoided to reduce fragmentation), or any other related area you can think of.

Style Rules

• All globals should be static stock whenever possible (so they can only be accessed from this one file).
• Statics must start with FIXES_gs, and all other globals with FIXES_g.
• All functions not overriding existing functions must start with FIXES_.
• Macros must be upper case, use underscores, and start FIXES_: FIXES_LIKE_THIS.
• Functions should be upper camel case (as the original functions are) FIXES_LikeThis.
• Globals (after the prefix) should be upper camel case LikeThis, and locals lower camel case likeThis.
• ALS should be used to hook functions and callbacks. See this topic for more details: https://sampforum.blast.hk/showthread.php?tid=570910
• The ALS prefix for chaining is FIXES_.
• When redefining a native, add a BAD_ external name declaration with the _ALS_ definition so that others may use the original native if they so desire (with the caveat that it may break all fixes). Note the BAD_ name is meant to indicate the possibility of breaking the fix, not a comment on the original native function.
• The ALS hook defines used here are a little different to the normal ones as this file assumes that it is always first. The pattern is:

/**
 * <remarks>Information about fix here</remarks>
 * <fixes>NameOfFixHere</fixes>
 */

// No other ALS hook of this function much exist before here.
#if _FIXES_SAMP && defined _ALS_NameOfFixHere
    #error _ALS_NameOfFixHere defined
#endif
native BAD_NameOfFixHere(params) = NameOfFixHere;

/**
 * <remarks>Information about fix here</remarks>
 * <fixes>NameOfFixHere</fixes>
 */

#if FIX_NameOfFixHere
    stock FIXES_NameOfFixHere(params)
    {
        return 0;
    }

    // The trailing `(` is VERY important to keep future `native X() = Y;`s working.
    #if _FIXES_SAMP
        #define _ALS_NameOfFixHere
        #define NameOfFixHere( FIXES_NameOfFixHere(
    #endif

    // This is not normal ALS, because fixes.inc must come first.
    #define _ALS_NameOfFixHere__
    #define NameOfFixHere__( FIXES_NameOfFixHere(
#endif

A copyable version of this pattern is at the end of the file.

• Enums start with E_ or e_ depending on type, then follow rules for macros.
• NO libraries should be included - not even the default SA:MP ones. Let the user do it.
• Due to the above rule, you cannot assume any third party libraries AT ALL, so do not use them. This can lead to some code duplication, but also means that the version of the code used here can be tailored for optimisations.
• Certain terms may be shortened when dealing with long callback names to avoid compile truncation warnings (max symbol length is 31). Current list:
• Checkpoint: CP
• Update: Upd
• TextDraw: TD
• Object: Obj
• Player: P
• Document all fixes at the top of the file, and highlight code.
• 4 space TABS - do not edit this file in PAWNO unless you know how to correct the indentation.
• All rules have exceptions, but they must be justifiable. For example IS_FILTERSCRIPT is a global variable, but is not called FIXES_gIsFilterscript to better match the FILTERSCRIPT macro it replaces. Now a macro for _FIXES_gIsFilterscript.
• Variables which need to be fully global (i.e. not static), but should not actually be used by other people (e.g. appear inside a macro) should be prefixed with _FIXES instead of FIXES to indicate their private use.
• No comments beyond the end of column 80 (where the line in PAWNO is).
• If a bug is fixed in some version of the server it can be conditionally included here. This is done by checking for the existance of a native function introduced in the same server version. For example TogglePlayerControllable was fixed in 0.3eRC6, the same time as the SetObjectMaterial native was introduced, thus the inclusion becomes:

/**
 * <fix name="NameOfFixHere" disabled="true" fixed="version">
 *     <problem>
 *         A description of the problem.
 *     </problem>
 *     <solution>
 *         A description of the solution.
 *     </solution>
 *     <see>FIXES_FunctionWithFixIn</see>
 *     <author href="https://github.com/pawn-lang/sa-mp-fixes/blob/master/github.com/account">Name</author>
 *     <post href="https://github.com/pawn-lang/sa-mp-fixes/blob/master/burgershot.gg/post" />
 * </fix>
 */

#if !defined FIX_NameOfFixHere
    #if defined NativeInFixRelease
        #if FIXES_EnableDeprecated
            static _FIXES_STOCK FIX_NameOfFixHere = FIXES_EnableDeprecated;
        #else
            _FIXES_CONST_PAWNDOC(FIX_NameOfFixHere);
        #endif
        #define FIX_NameOfFixHere                FIXES_EnableDeprecated
    #else
        static _FIXES_STOCK FIX_NameOfFixHere = _FIXES_DEFAULT;
        #define FIX_NameOfFixHere                _FIXES_DEFAULT
    #endif
#elseif _FIXES_IS_UNSET(FIX_NameOfFixHere)
    #undef FIX_NameOfFixHere
    static stock FIX_NameOfFixHere = 2;
    #define FIX_NameOfFixHere                    (2)
#elseif FIX_NameOfFixHere
    #undef FIX_NameOfFixHere
    static stock FIX_NameOfFixHere = 1;
    #define FIX_NameOfFixHere                    (1)
#else
    #undef FIX_NameOfFixHere
    static stock FIX_NameOfFixHere = 0;
    #define FIX_NameOfFixHere                    (0)
#endif

This only includes this fix if that native doesn't exist. A copyable version of this pattern is at the end of the file.

• To reduce general memory consumption, strings in this include are stored globally in constant arrays and referenced. This is EXACTLY as fast as using the string constants directly, but means that strings are not stored in the assembly multiple times (unless the string is only used once, in which case it's more work for no gain). See this post for more details: http://forum.sa-mp.com/showpost.php?p=1795601
• DO NOT EDIT THIS FILE IN PAWNO OR ON GITHUB. Both mess up the spacing - GitHub in an almost irreversible way (except for the fact that nothing is irreversible in source control. Pawno spacing is less tricky to solve, and can be worked around if you know when it uses spaces and tabs - in short, always write code first THEN indent and you won't have a problem (in that editor at least, that is normally a bad way to write code).

Documentation Explanation

The fixes.inc code itself now contains all of the documentation in its header, formatted using the compiler's natively supported pawn-doc, plus some custom XSL. Previously README.md and the header had to be kept in sync manually. Now you can just compile a script with -r and get a large amount of XML documentation, including all of this header in a <library></library> pair. The repository comes with a file called markdown.xsl that, when saved as pawno/xml/pawndoc.xsl, will transform that XML to markdown to keep README.md fully up-to-data almost automatically.

The descriptions of the fixes all look like:

<fix name="Short Name" disabled="true" fixed="Optional server version of official fix where applicable">
    <problem>
    Description of problem.
        </problem>
    <solution>
        Description of solution.
    </solution>
    <see>Relevant functions.</see>
    <author href="https://github.com/pawn-lang/sa-mp-fixes/blob/master/Optional address of their profile">Person who wrote the fix</author>
    <post href="https://github.com/pawn-lang/sa-mp-fixes/blob/master/Optional link to the original post where applicable." />
</fix>

Thanks

A huge thanks to all the community members that have reported and fixed bugs, this include would not be anywhere near the level of quality it is right now without all of you. Fix writers are all listed above by their contributions. Fix reporters can be seen by browsing the github issues. A special thanks also to @ziggi for hosting this repo for a long time.